Discussion :

[ClaudiusCesar]

Bonjour à tous,

N'étant pas un programmateur assidu, Je cherche un script Bat pour créer des dossiers comme ci-dessous.

Pour commencer, lorsque aucun dossiers n'est créés, il faudrait créer 2 années 2023 et 2024 et ses sous dossiers semainiers.
Quand l'année 2023 est passée et que l'on relance le script en 2023, il doit nous dire que l'année 2023 et ses sous dossiers semainiers sont déjà créés. et que l'année 2024 est aussi créé avec ses sous dossiers.

Maintenant nous sommes en 2024.
Lorsque nous relançons le script, ce dernier doit nous indiquer que l'année 2024 et ses sous dossiers semainiers sont déjà créés. Et il doit créer l'année suivante puisque quelle n'existe pas encore.
Voilà un peu le sujet. En espérant que je suis assez clair.

---------------------
Set Annee=%DATE:~6,4%
Echo %Annee%
:CreeRep
Mkdir "Semaine 01"
Mkdir "SEmaine 02"
:
:
:
:
Mkdir "Semaine 52"

::Annee+1
Set Annee=%DATE:~6,4%+1
Goto CreeRep

----------------------

Merci à vous pour votre aide,
Claudius

[ericlm128]

Un script simple

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
@echo off
cls
title Create rep
 
SETLOCAL ENABLEDELAYEDEXPANSION
 
set /a "current_year=%date:~6%"
call :CreeRep "%current_year%"
 
set /a current_year+=1
call :CreeRep "%current_year%"
 
goto fin
 
:CreeRep
set /a "year=%~1"
if exist "%~dp0%year%" echo Le dossier %year% existe deja&&goto :EOF
 
echo Creation du dossier %year%
md "%~dp0%year%"
FOR /L %%a IN (1,1,52) DO (
	set "sem=0%%~a"
	md "%~dp0%year%\Semaine !sem:~-2!"
)
 
goto :EOF
 
 
:fin
echo.
echo Fin
pause>nul

[ClaudiusCesar]

Re bonjour

J'ai ajouté la ligne suivante avant le goto :EOF

--------------
:: Ce qui me permet de voir les dossiers
dir "%~dp0%year%" /s /b

goto :EOF


:fin
echo.
echo Fin
pause>nul
--------------

Cela fonctionne bien, et je vous en remercie beaucoup.