Discussion :

[marie_de_paris]

Bonjour à tous,

bonjour

Voici le fichier Excel à partir duquel je dois réaliser un code VBA qui fera l'action suivante :

Copier la colonne C2 de la feuil1 et venir l'insérer dans la feuil2 à la suite des colonnes déjà présentes. l'entête de cette nouvelle colonne doit prendre le nom de catégorie_mois_année.

Pour résumer, chaque mois je vais devoir faire cette action et je veux créer une nouvelle colonne avec une entête (catégorie_mois_année) à chaque nouveau moi en y collant les données de la feuil1.

Merci d'avance pour votre aide!
Mariefichier_pour_exemple.xlsxfichier_pour_exemple.xlsxfichier_pour_exemple.xlsxfichier_pour_exemple.xlsx

[Franc]

Bonjour, je ne vois pas trop l'intérêt de développer une macro vba, après tout il s'agit juste de copier/coller une colonne non ? Ou alors quelque chose m'échappe

[marie_de_paris]

Bonjour Franc,

Je suis assez d'accord, cependant c'est ce qu'on me demande de faire
Je sais que c'est possible en VBA mais je suis trop novice pour le faire!

[Franc]

Voici une macro qui fait le job. A copier dans un nouveau module de ton classeur et lancer via l'onglet Développeur --> Macro.
Quand la macro s'exécute, elle prend automatiquement en compte le mois en cours, donc si tu exécutes plusieurs fois sur le même mois tu auras plusieurs colonnes avec le même mois.
La macro cherche la première colonne vide disponible, donc si tu remplis ta feuille d'avance avec les entêtes des prochains mois, la colonne sera copiée après, à ne pas faire donc.
Si nécessaire, changer le nom des feuilles.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Sub CopierColonne()
 
    Dim ws1 As Worksheet
    Dim ws2 As Worksheet
    Dim lastRow As Long
    Dim lastColumn As Long
    Dim monthYear As String
 
    ' Définir les feuilles de calcul
    Set ws1 = ThisWorkbook.Sheets("Feuil1")
    Set ws2 = ThisWorkbook.Sheets("Feuil2")
 
    ' Obtenir le dernier numéro de ligne de la colonne C dans Feuil1
    lastRow = ws1.Cells(ws1.Rows.Count, "C").End(xlUp).Row
 
    ' Obtenir le dernier numéro de colonne dans Feuil2
    lastColumn = ws2.Cells(1, ws2.Columns.Count).End(xlToLeft).Column
 
    ' Obtenir le mois et l'année en cours
    monthYear = Format(Date, "mmmm") & "_" & Format(Date, "yyyy")
 
    ' Copier les valeurs de la colonne C de Feuil1 vers Feuil2
    ws1.Range("C2:C" & lastRow).Copy
 
    ' Coller les valeurs dans la première colonne vide de Feuil2 à partir de la ligne 2
    ws2.Cells(2, lastColumn + 1).PasteSpecial Paste:=xlPasteValues
 
    ' Renommer l'entête de la nouvelle colonne dans Feuil2
    ws2.Cells(1, lastColumn + 1).Value = "Catégorie_" & monthYear
 
    ' Centrer l'entête en hauteur et en largeur
    ws2.Cells(1, lastColumn + 1).HorizontalAlignment = xlCenter
    ws2.Cells(1, lastColumn + 1).VerticalAlignment = xlCenter
 
    ' Ajuster la largeur de colonne à la largeur de l'entête
    ws2.Columns(lastColumn + 1).AutoFit
 
End Sub

[marie_de_paris]

Mille mercis Franc pour le temps que tu as passé à m'aider!
Excellente journée