Discussion :

[Phil333250]

Bonjour à toutes et tous

Je cherche a utiliser la MsgBox("" , _ vbYesNoCancel

le test vbYes Then fonctionne
le test vbNo Then fonctionne
Je n'arrive pas à faire le 3ème test Cancel.

Voici mon code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub Ouverture_Planning()
 
Application.ScreenUpdating = False
 
If MsgBox("Voulez vous identifier du Présentiel ?", _
       vbYesNoCancel + vbQuestion + vbDefaultButton2) = vbYes Then
 
    Sheets("Planning Stagiaire").Visible = True 'OK
    Sheets("Planning Stagiaire").Activate
    Range("A1").Activate
 
Else
 
    If MsgBox("Voulez vous identifier du Présentiel ?", _
       vbYesNoCancel + vbQuestion + vbDefaultButton2) = vbNo Then
 
        Application.Run "Impression_Planning_Stag"
    Else
        Range("A1").Activate
 
    End If
 
End If
 
End Sub

J'ai trouvé ce code qui fait le boulot

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub Gestion_Présentiel()
' Adaptation de la macro de pijaku / https://www.developpez.net/forums/d2103564/logiciels/microsoft-office/excel/macros-vba-excel/msgbox-choix-multiples/
' Cette macro fonctionne et fait le boulot.
 
Dim Lignes(2) As String, reponse As Integer
    Lignes(0) = "          Oui = Ouverture planning"
    Lignes(1) = "                Non = Impression directe"
    Lignes(2) = "                      Annuler = Ferme le message"
    reponse = MsgBox(Join(Lignes, vbCrLf), vbYesNoCancel, "Voulez vous identifier du Présentiel ?")
    Select Case reponse
        Case vbYes
            Sheets("Planning Stagiaire").Visible = True 'OK
            Sheets("Planning Stagiaire").Activate
            Range("A1").Activate
 
        Case vbNo
            Application.Run "Impression_Planning_Stag"  'lance la Sub Impression_Planning_Stag()
 
        Case vbCancel
            Range("A1").Activate
    End Select
 
End Sub

Mais, pour ne pas mourir idiot, comment corriger mon code ?
Merci pour votre aide
Philippe

[DaddyTousucre]

Salut,
Tu peux assigner la réponse de ta boite de dialogue à une variable puis faire tes tests sur cette variable :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub Ouverture_Planning()
 
Application.ScreenUpdating = False
 
Reponse = MsgBox("Voulez vous identifier du Présentiel ?", _
        vbYesNoCancel + vbQuestion + vbDefaultButton2)
 
If Reponse = vbYes Then
 
    Sheets("Planning Stagiaire").Visible = True 'OK
    Sheets("Planning Stagiaire").Activate
    Range("A1").Activate
 
Else
 
    If Reponse = vbNo Then
 
        Application.Run "Impression_Planning_Stag"
    Else
        Range("A1").Activate
 
    End If
 
End If

En l'état, ton code lui demande d'afficher la boite à chaque "if".
Voilà je sais pas si je suis clair et j'espère que ça répond à ta question.

[Phil333250]

Bonjour Daddy,

Merci pour ton aide.
Le code fonctionne parfaitement.
Cdt
Philippe

[Valtrase]

Salut
Ou directement avec un Select Case

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
    Select Case MsgBox("Voulez-vous identifier du présentiel ?" & vbCrLf _
                       & "" & vbCrLf _
                       & "Oui pour Ouverture planning" & vbCrLf _
                       & "Non pour l'impression directe" & vbCrLf _
                       & "Annuler pour quitter", vbYesNoCancel Or vbQuestion, "")
 
 
        Case vbYes
            Sheets("Planning Stagiaire").Visible = True
            Sheets("Planning Stagiaire").Activate
            Range("A1").Activate
 
        Case vbNo
 
            Application.Run "Impression_Planning_Stag"
 
        Case vbCancel
                    Range("A1").Activate
    End Select

[Phil333250]

Bonjour Valtrase,

Merci pour cette proposition que je vais tester.
Cdt
Philippe