Discussion :

[jireu]

Bonjour à tous,

je cherche à réaliser le projet suivant :

j'ai sur ma feuille 1 un listing d'environ 1500 lignes qui se compose de la manière suivante

colonne A, le nom d'une ville
colonne B, le nom d'un batiment
colonne C, le numéro d'un appartement
colonne D, le type d'un équipement de cuisine
colonne C, sa marque
colonne D, son état

Il y a une ligne par équipement.

je souhaiterai transferer ces donnée sur une deuxieme feuille en ayant une seule ligne par appartement et pour chaque équipement de cet apparement : une colonne avec le type, une colonne regroupant la marque et l'état

je ne suis pas certain de comment devoir procéder et je souhaiterai donc profiter de vos lumières

Je joins un fichier exemple dans lequel j'ai fait 2 petits tableau "à la main" pour indiquer ce que je souhaite réaliser.

merci à vous.
fichier_exemple _tableau.xlsx

[78chris]

Bonjour

Renommer Tableau4 en Equipements

Créer une requête PowerQuery à partir de ce tableau

Ce qui donne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
let
    Source = Excel.CurrentWorkbook(){[Name="Equipements"]}[Content],
    #"Type modifié" = Table.TransformColumnTypes(Source,{{"Ville", type text}, {"Batiment", type text}, {"appartement no", Int64.Type}, {"équipement", type text}, {"marque", type text}, {"état", type text}}),
    #"Lignes groupées" = Table.Group(#"Type modifié", {"Ville", "Batiment", "appartement no"}, {{"Tabl", each _, type table [Ville=nullable text, Batiment=nullable text, appartement no=nullable number, équipement=nullable text, marque=nullable text, état=nullable text]}}),
    #"Personnalisée ajoutée" = Table.AddColumn(#"Lignes groupées", "Personnalisé", each Table.AddIndexColumn([Tabl],"Idx",1)),
    #"Personnalisé développé" = Table.ExpandTableColumn(#"Personnalisée ajoutée", "Personnalisé", {"équipement", "marque", "état", "Idx"}, {"équipement", "marque", "état", "Idx"}),
    #"Colonnes fusionnées" = Table.CombineColumns(#"Personnalisé développé",{"marque", "état"},Combiner.CombineTextByDelimiter(" - ", QuoteStyle.None),"Marque - Etat"),
    #"Colonnes supprimées" = Table.RemoveColumns(#"Colonnes fusionnées",{"Tabl"}),
    #"Supprimer le tableau croisé dynamique des autres colonnes" = Table.UnpivotOtherColumns(#"Colonnes supprimées", {"Ville", "Batiment", "appartement no", "Idx"}, "Attribut", "Valeur"),
    #"Majuscule à chaque mot" = Table.TransformColumns(#"Supprimer le tableau croisé dynamique des autres colonnes",{{"Attribut", Text.Proper, type text}}),
    #"Colonnes fusionnées1" = Table.CombineColumns(Table.TransformColumnTypes(#"Majuscule à chaque mot", {{"Idx", type text}}, "fr-FR"),{"Attribut", "Idx"},Combiner.CombineTextByDelimiter(" ", QuoteStyle.None),"Type"),
    #"Colonne dynamique" = Table.Pivot(#"Colonnes fusionnées1", List.Distinct(#"Colonnes fusionnées1"[Type]), "Type", "Valeur"),
    #"Lignes triées" = Table.Sort(#"Colonne dynamique",{{"Ville", Order.Ascending}, {"Batiment", Order.Ascending}, {"appartement no", Order.Ascending}})
in
    #"Lignes triées"

[jireu]

Bonjour et merci pour la réponse.

je ne conaissais pas PowerQuery. j'ai testé et ça me semble parfait !

Sais tu si il est possible de faire en powerquery un tableau à partir de 2 tableaux dans lesquelles une colonne reprend les même valeur?

Bonne journée

[78chris]

Bonjour

On peut faire tellement de choses avec PowerQuery... Mais pas sûr de comprendre d'où tu pars et où tu veux aller

Précise en donnant un exemple

[jireu]

Voici en PJ un fichier avec 2 tableaux.
Je me demande comment on peut fusionner ces 2 tableaux dans un 3ème à l'aide de PQ (l'acronyme est malheureux)
Le tableau final devra reprendre les colonnes des deux autres tableaux sans faire de doublon

merci et bonne soirée
exemple fusion.xlsx

[78chris]

Bonjour

Il semble que l'ID des équipements reprenne celui du propriétaire, donc une simple relation de la table Propriétaire avec la table Equipement sur ce champ suffit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
let
    Source = Excel.CurrentWorkbook(){[Name="proprietaire"]}[Content],
    #"Type modifié" = Table.TransformColumnTypes(Source,{{"id", Int64.Type}, {"batiment", type text}, {"appartement", Int64.Type}, {"porpriétaire", type text}, {"age", Int64.Type}}),
    #"Requêtes fusionnées" = Table.NestedJoin(#"Type modifié", {"id"}, equipement, {"id"}, "equipement", JoinKind.LeftOuter),
    #"equipement développé" = Table.ExpandTableColumn(#"Requêtes fusionnées", "equipement", {"equipement"}, {"equipement.1"})
in
    #"equipement développé"

Sinon on pourrait utiliser les 2 champs Batiment et Appartement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
let
    Source = Excel.CurrentWorkbook(){[Name="proprietaire"]}[Content],
    #"Type modifié" = Table.TransformColumnTypes(Source,{{"id", Int64.Type}, {"batiment", type text}, {"appartement", Int64.Type}, {"porpriétaire", type text}, {"age", Int64.Type}}),
    #"Requêtes fusionnées" = Table.NestedJoin(#"Type modifié", {"batiment", "appartement"}, equipement, {"batiment", "appartement"}, "equipement", JoinKind.LeftOuter),
    #"equipement développé" = Table.ExpandTableColumn(#"Requêtes fusionnées", "equipement", {"id", "equipement"}, {"id equip", "equipement"})
in
    #"equipement développé"