Discussion :

[Angelus1753]

Bonjour à tous,

Je reviens vers vous pour de nouvelle question.
Le script ci-dessous a été créé par Hackoofr que je remercie son script fonctionne à merveille comme d’habitude
Cela dit j’ai 2 questions.
La première est-il possible d’activer un VBs ou un batch au lieu d’un mp3
La deuxième est-il possible que ce VBs s’exécutent sans avoir besoins d’autorisation de Windows merci à vous et bonne fête

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Option Explicit
'Run as Admin
If Not WScript.Arguments.Named.Exists("elevate") Then
   CreateObject("Shell.Application").ShellExecute DblQuote(WScript.FullName) _
   , DblQuote(WScript.ScriptFullName) & " /elevate", "", "runas", 1
    WScript.Quit
End If
 
Dim FilePath,TaskName,Repeat_Task,Sound
FilePath = WScript.ScriptFullName
TaskName = "PlayMusic"
Repeat_Task = 120 REM Pour répeter la tâche chaque 2 heures=120 min
Call Create_Schedule_Task(Repeat_Task,TaskName,FilePath)
 
Set Sound = CreateObject("WMPlayer.OCX.7")
Sound.URL = "E:\hubiC\Sauvegarde\DownloadPrgBar\IbizaMix.mp3"
Sound.Controls.play
Do while Sound.currentmedia.duration = 0
    wscript.sleep 100
Loop
wscript.sleep (int(Sound.currentmedia.duration)+1)*1000
'----------------------------------------------------------------
REM Fonction pour ajouter des guillemets doubles dans une variable
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'-----------------------------------------------------------------
Sub Create_Schedule_Task(Repeat_Task,TaskName,FilePath)
Dim Ws,Task,Result
Set Ws = CreateObject("WScript.Shell")
Task = "CMD /C Schtasks /Create /SC DAILY /ST 08:00 /F /RI "&_
Repeat_Task &" /DU 24:00 /TN "& TaskName &" /TR "& FilePath &""
Result = Ws.run(Task,0,True)
End Sub
'-----------------------------------------------------------------

[ProgElecT]

Salut

en réponse à ta première question:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Dim Ws,Result,ChemNomExec
Set Ws = CreateObject("WScript.Shell")
 
ChemNomExec = """C:\MesProgs\En VBScript et HTA\Attente\Attente.vbs"""
' lancement du fichier VBS Attente.vbs se trouvant sur le disque à l'emplacement C:\MesProgs\En VBScript et HTA\Attente
'le 3ém parametre permet d'attendre la fin de l'exécution du programme lancé avant de continuer
Result = Ws.run(ChemNomExec,4,true)
 
'sous le même principe lancement du .BAT après exécution du programme précédant, n'attend pas la fin,
' passe à la suite du présent VBS
ChemNomExec = """C:\MesProgs\En VBScript et HTA\UnBatch.bat"""
Result = Ws.run(ChemNomExec,4,false)
MsgBox "A que coucou"

pour la deuxième ? pas vraiment compris.

[Angelus1753]

Bonjour ProgElecT,

Merci Beaucoup, pour votre réponse toujours aussi rapide et toujours aussi efficace.
J’ai trouvé et sa fonctionne parfaitement
Je le partage avec le forum
Bonne fête à tous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Dim minutes
Dim wshShell
Dim boucle
 
Set wshShell = CreateObject("WScript.Shell")
boucle=1
 
While boucle > 0 'boucle infinie
	For minutes=0 to 72 '72 car 72*20=1440mn = 24h
		wshShell.Run "C:\Users\Angelus\Downloads\reveil_1.vbs", 0, True
		WScript.Sleep(5000)'en milisecondes 20min=60*20=1200s=1200000ms
	Next
	WScript.Echo "Nouvelle journée"
Wend