Discussion :

[psikhopat]

Salut,

Je débute (vraiment) en VBA et je bloque sur un problème :

J'ai plusieurs classeurs Excel dans un dossier, un premier classeur principal qui sert de référence appelé disons "référence", puis d'autres classeurs secondaires appelés pour le moment "classeur1" , "classeur2", etc...

J'aimerais que les "classeur1", "classeurs2", etc....soient renommés automatiquement en fonction du contenus de diverses cellules du classeur "référence".

En clair j'aimerais que quand j'ouvre mon classeur "référence" et que je tape "machin" dans la cellule 1, cela renomme immédiatement le "classeur1" en "machin", et ainsi de suite avec les autres cellules.

C'est possible je suppose mais je n'y arrive pas...
Quelqu'un a une idée ?

[EricDgn]

Bonjour,

Une façon de faire, le code étant placé dans la feuille de départ:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Option Explicit
 
Dim sOldName As String
Dim sNewName As String
 
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim kR As Long, sOldPath As String, sNewPath As String
    If Target.Count > 1 Then Exit Sub
    If Target.Column <> 1 Then Exit Sub
    If Target = "" Then Exit Sub
    kR = Target.Row
    sNewName = Target
    If sOldName = "" Then
        sOldName = "Classeur" & kR
    End If
    sOldPath = ThisWorkbook.Path & "\" & sOldName & ".xlsx"
    If Dir(sOldPath) = "" Then
        MsgBox "Annulé: pas trouvé de fichier nommé " & sOldPath, vbExclamation, "Anomalie"
        Application.EnableEvents = False
        Target = sOldName
    Else
        sNewPath = ThisWorkbook.Path & "\" & sNewName & ".xlsx"
        If MsgBox("Changer le nom de ce fichier" & vbLf & _
                  "de " & sOldPath & vbLf & _
                  "en " & sNewPath, _
                  vbYesNo, "Oui/Non") = vbYes Then
            Name sOldPath As sNewPath
        Else
            Application.EnableEvents = False
            Target = sOldName
        End If
    End If
    Application.EnableEvents = True
End Sub
 
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Target.Column = 1 Then
        sOldName = Target
    End If
End Sub

Cordialement.

[psikhopat]

Salut et merci pour ce code,

Comme je vous disais je débute vraiment donc je suppose que je n'ai pas dû le placer où il faut car il ne fait strictement rien chez moi 😋

Je l'ai placé dans le fichier "référence" mais j'ai eu des doutes au moment de choisir à gauche de la fenetre vba entre thisworkbook et feuil1, et ensuite si je devais choisir general ou workbook dans le menu deroulant...

Donc je continue a creuser, je teste mais en tout cas je commence a mieux piger comment vba fonctionne, merci 😉

[psikhopat]

Tant que j'y suis, pouvez vous me préciser où apparaissent dans ce code les cellule dans lesquelle il va chercher les nouveaux noms a donner aux fichiers ? Car du coup je ne sais pas dans quelles cellules du ficier référence je dois mettre les noms (j'ai essayé la 1ere ou d'autres mais ca 'ne change rien)

[EricDgn]

Le code est à placer dans "Feuil1". Les noms des fichiers sont ensuite à entrer dans les cellules A1 (classeur1), A2 (classeur2), A3 (classeur3), ... de cette Feuil1 (cela sans mentionner l'extension .xlsx).

Cordialement.

[psikhopat]

Super, merci

Je teste ça en debauchant 👍