Discussion :

[disel]

Bonjour,

A l'instant je rencontre un problème sur une macro, je ne peux pas poster les classeurs qui sont confidentiels mais le problème me paraît assez simple à décrire.

J'ai un tableau dans une feuille X remplis grâce à des formules. Je souhaite copier et coller ce tableau d'une feuille à une autre située dans le même classeur en conservant les formules à l'identique.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
If Not wsExtractNomcl.Columns(numero_colonne_extract_nomcl_audric).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av)) Is Nothing Then
                Ligne_Affaire_Extract_Nomcl = wsExtractNomcl.Columns(numero_colonne_extract_nomcl_audric).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av)).Row
                wsExtractNomcl.Range("B" & Ligne_Affaire_Extract_Nomcl & ":" & "H" & Ligne_Affaire_Extract_Nomcl + 16).Copy
                wsSuivi.Range("B" & indice_feuille_suivi).PasteSpecial (xlPasteAll)
ElseIf Not wsExtractNomcl.Columns(numero_colonne_extract_nomcl_vincent).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av)) Is Nothing Then
                Ligne_Affaire_Extract_Nomcl = wsExtractNomcl.Columns(numero_colonne_extract_nomcl_vincent).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av)).Row
                wsExtractNomcl.Range("J" & Ligne_Affaire_Extract_Nomcl & ":" & "P" & Ligne_Affaire_Extract_Nomcl + 16).Copy
                wsSuivi.Range("B" & indice_feuille_suivi).PasteSpecial (xlPasteAll)
End If

La macro me le copie bien cependant les indices dans la formule se décalent. Typiquement la première formule est écrite à la ligne 6 de la feuille X et cette formule est :
='Feuille X'!$D4

Dans la formule copiée et collée dans l'autre feuille la formule est écrite à la ligne 3 et devient :
='Feuille X'!$D1

Je souhaiterais que Excel ne recalcule pas l'indice contenu dans la formule, qu'elle soit simplement copiée-collée tel quelle. Donc je souhaite que la formule copiée est collée dans l'autre feuille écrite à la ligne 3 soit :
='Feuille X'!$D4

Merci de votre aide

[jurassic pork]

Hello,
si tu veux que la formule soit la même il faut mettre les références dans la formule en Absolue exemple :

='Feuille X'!$D$4

Ami calmant, J.P

[disel]

Hello,
si tu veux que la formule soit la même il faut mettre les références dans la formule en Absolue exemple :


Ami calmant, J.P

Ah super ça marche nickel, en plus de ça ce n'était pas mon seul problème et vous avez résolu l'autre problème en même temps. Merci bien !

[disel]

J'en profite pour demander autre chose :

Comment je met toute une plage de cellules en référence absolue ?
Je peux le faire cellule par cellule mais il y a 5000 lignes et j'ai pas vraiment envie de passer 10h à le faire ligne par ligne

[Tête de chat]

Bonjour

autre approche : au lieu de faire une copie, tu fais une assignation de la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

wsSuivi.Range("B" & indice_feuille_suivi).Formula =  wsExtractNomcl.Range("B" & Ligne_Affaire_Extract_Nomcl & ":" & "H" & Ligne_Affaire_Extract_Nomcl + 16).Formula

Avec FormulaR1C1 c'est équivalent à une copie, avec Formula c'est forcément en absolu (c'est =A1" qui est copié)

[disel]

Bonjour

autre approche : au lieu de faire une copie, tu fais une assignation de la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

wsSuivi.Range("B" & indice_feuille_suivi).Formula =  wsExtractNomcl.Range("B" & Ligne_Affaire_Extract_Nomcl & ":" & "H" & Ligne_Affaire_Extract_Nomcl + 16).Formula

Avec FormulaR1C1 c'est équivalent à une copie, avec Formula c'est forcément en absolu (c'est =A1" qui est copié)

Merci de ta réponse je viens de tester et ta solution marche aussi. Cependant j'ai encore un problème qui est que les données de départ ne sont pas bonnes quand elles sont en colonnes absolues (c'est à dire type $D1).

J'ai testé de les mettre en références absolues (c'est-à-dire type $D$1) et là les données sont bonnes.

Le problème étant que j'ai 5000 lignes que je dois mettre en référence absolue et avant de coder une macro pour pas me les taper à la mano je voulais savoir s'il était possible de le faire avec une fonction excel déjà toute faite

[Tête de chat]

Rien compris...

Que la cellule de départ, disons A1, contienne =D1, =$D1, =D$1 ou =$D$1, et que tu fais par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

range("A2").formula = Range("A1").formula

, tu va te rerouver en A2 avec la même formule =D1, =$D1, =D$1 ou =$D$1...
... qui est ce que tu avais demandé ou du moin ce que je croyais que tu avais demandé !

[jurassic pork]

Le problème étant que j'ai 5000 lignes que je dois mettre en référence absolue et avant de coder une macro pour pas me les taper à la mano je voulais savoir s'il était possible de le faire avec une fonction excel déjà toute faite

Tu peux essayer ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub ConvertRelativeToAbsolute()
Dim cell As Range, strFormulaOld$, strFormulaNew$
For Each cell In Cells.SpecialCells(3)
strFormulaOld = cell.Formula
strFormulaNew = _
Application.ConvertFormula _
(Formula:=strFormulaOld, fromReferenceStyle:=xlA1, _
toReferenceStyle:=xlA1, toAbsolute:=xlAbsolute)
cell.Formula = strFormulaNew
Next cell
End Sub

[deedolith]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
If Not wsExtractNomcl.Columns(numero_colonne_extract_nomcl_audric).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av)) Is Nothing Then
                Ligne_Affaire_Extract_Nomcl = wsExtractNomcl.Columns(numero_colonne_extract_nomcl_audric).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av)).Row
                wsExtractNomcl.Range("B" & Ligne_Affaire_Extract_Nomcl & ":" & "H" & Ligne_Affaire_Extract_Nomcl + 16).Copy
                wsSuivi.Range("B" & indice_feuille_suivi).PasteSpecial (xlPasteAll)
ElseIf Not wsExtractNomcl.Columns(numero_colonne_extract_nomcl_vincent).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av)) Is Nothing Then
                Ligne_Affaire_Extract_Nomcl = wsExtractNomcl.Columns(numero_colonne_extract_nomcl_vincent).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av)).Row
                wsExtractNomcl.Range("J" & Ligne_Affaire_Extract_Nomcl & ":" & "P" & Ligne_Affaire_Extract_Nomcl + 16).Copy
                wsSuivi.Range("B" & indice_feuille_suivi).PasteSpecial (xlPasteAll)
End If

Heu ... tu arrives à te relire ?

Tu peux factoriser et simplifier tout cela, ca faciliteras la maintenance:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
    Dim FoundAudric As Excel.Range
    Set FoundAudric = wsExtractNomcl.Columns(numero_colonne_extract_nomcl_audric).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av))
 
    Dim FoundVincent As Excel.Range
    Set FoundVincent = wsExtractNomcl.Columns(numero_colonne_extract_nomcl_vincent).Find(wsListeProjetsAR.Cells(indice_affaire_voulue, numero_colonne_av))
 
    Dim Source As String
    Dim Target As String
    Dim DoCopy As Boolean
    If Not (FoundAudric Is Nothing) Then
        Ligne_Affaire_Extract_Nomcl = FoundAudric.Row
        Source = "B" & Ligne_Affaire_Extract_Nomcl & ":" & "H" & Ligne_Affaire_Extract_Nomcl + 16
        Target = "B" & indice_feuille_suivi
        DoCopy = True
    ElseIf Not (FoundVincent Is Nothing) Then
        Ligne_Affaire_Extract_Nomcl = FoundVincent.Row
        Source = "J" & Ligne_Affaire_Extract_Nomcl & ":" & "P" & Ligne_Affaire_Extract_Nomcl + 16
        Target = "B" & indice_feuille_suivi
        DoCopy = True
    End If
 
    If (DoCopy) Then
        wsExtractNomcl.Range(Source).Copy
        wsSuivi.Range(Target).PasteSpecial xlPasteAll
    End If

Il y a peut être moyen de faire mieux, mais c'est déja plus claire.

[disel]

Rien compris...

Que la cellule de départ, disons A1, contienne =D1, =$D1, =D$1 ou =$D$1, et que tu fais par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

range("A2").formula = Range("A1").formula

, tu va te rerouver en A2 avec la même formule =D1, =$D1, =D$1 ou =$D$1...
... qui est ce que tu avais demandé ou du moin ce que je croyais que tu avais demandé !

Oui tu as totalement répondu à ma première question et je t'en remercie.
Ma deuxième portait sur totalement autre chose mais jurassic pork m'a donné la réponse, donc c'est bon