Discussion :

[gui_li_aume]

Bonjour,

alors voilà: un module1 qui contient la function suivante (pour permettre le choix du dossier de destination):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Public Function choisirdestination() As String
 
Dim boitedialogue As FileDialog
Dim Destination As String
 
Set boitedialogue = Application.FileDialog(msoFileDialogFolderPicker)
boitedialogue.AllowMultiSelect = False
boitedialogue.Title = "choisir un dossier"
boitedialogue.Show
If boitedialogue.SelectedItems(1) = "" Then
    MsgBox "Selectionner un dossier"
    Else
    Destination = boitedialogue.SelectedItems(1)
End If
 
End Function

Elle fonctionne; mais je veux l'utiliser dans un objet de classe (sur un état, j'ai un bouton export pour générer un pdf); le code suivant ne fonctionne pas:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub commExportPdf_Click()
 
Dim NomFichier As String
Dim Dmaj As String
Dim Site As String
Dim Cible As String
 
Dmaj = Replace(DT_Maj, "/", "")
Site = Replace([Nom Site], "/", "%")
NomFichier = "Fiche Technique" & "_" & Site & "_" & Dmaj & ".pdf"
 
Cible = choisirdestination()
 
MsgBox Cible
MsgBox NomFichier
DoCmd.OutputTo acOutputReport, , acFormatPDF, Cible & "/" & NomFichier, True
 
End Sub

Je comprends que la Private Sub commExportPdf_Click(), exécute la function choisirdestination mais ne conserve pas la variable destination de cette function (MsgBox de ligne 14 reste vide). Remplacer Dim par Static? Qu'est-ce qui est approprié dans mon module1 ? Sub? Function? (pour moi il me faut une valeur, donc c'est function)...

Auriez vous une piste?

[gui_li_aume]

Changement de la variable destination dans la function choisirdestination

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Public Destination As String
...
Public Function choisirdestination() As String
 
Dim boitedialogue As FileDialog
 
Set boitedialogue = Application.FileDialog(msoFileDialogFolderPicker)
boitedialogue.AllowMultiSelect = False
boitedialogue.Title = "choisir un dossier"
boitedialogue.Show
If boitedialogue.SelectedItems(1) = "" Then
    MsgBox "Selectionner un dossier"
    Else
    Destination = boitedialogue.SelectedItems(1)
End If
 
End Function

puis ajustement de la privatesub commexportpdf_click() de la façon suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub commExportPdf_Click()
 
Dim NomFichier As String
Dim Dmaj As String
Dim Site As String
Dim Cible As String
 
Dmaj = Replace(DT_Maj, "/", "")
Site = Replace([Nom Site], "/", "%")
NomFichier = "Fiche Technique" & "_" & Site & "_" & Dmaj & ".pdf"
 
Call choisirdestination
 
MsgBox Destination
MsgBox NomFichier
DoCmd.OutputTo acOutputReport, , acFormatPDF, Destination & "/" & NomFichier, True
 
End Sub

Là ça fonctionne. Mais je crains qu'il y ait un risque poru la suite si j'utilise cette function dans d'autres sub... De plus, ne faudrait-il pas penser dès le début un module avec toutes mes variables public?

[Robert1957]

Bonjour gui_li_aume,

Le post # 1 est la bonne manière de fonctionner, cependant il y a une erreur dans la fonction. En aucun temps dans votre fonction vous ne lui donner une valeur. Voici le code qui fonctionnera (ajout de la ligne 15):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Public Function choisirdestination() As String
 
Dim boitedialogue As FileDialog
Dim Destination As String
 
Set boitedialogue = Application.FileDialog(msoFileDialogFolderPicker)
boitedialogue.AllowMultiSelect = False
boitedialogue.Title = "choisir un dossier"
boitedialogue.Show
If boitedialogue.SelectedItems(1) = "" Then
    MsgBox "Selectionner un dossier"
    Else
    Destination = boitedialogue.SelectedItems(1)
End If
choisirdestination = Destination
End Function

Bonne journée

[Robert1957]

Bonjour gui_li_aume,

Complément d'information, les variables publiques sont a utilisées avec grande modération.

Bonne journée

[gui_li_aume]

Merci Robert1957,

Je me disais bien que mettre trop de variables publiques n'était pas très sain...

Sur mon post#1, j'étais induit en erreur car avant mon end If j'avais testé msgbox destination. Je pige que au final ma variable destination n'existait plus au delà de end if

[Robert1957]

Bonjour gui_li_aume,

En fait la variable existe à l'intérieur de la fonction. C'est la fonction qui est publique et qui retourne une valeur, dans votre cas une chaine de caractères (string) qui ne peut être "null".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Public Function choisirdestination() As String
 
Dim boitedialogue As FileDialog
Dim Destination As String  '*** à partir d'ici la variable existe***
 
Set boitedialogue = Application.FileDialog(msoFileDialogFolderPicker)
boitedialogue.AllowMultiSelect = False
boitedialogue.Title = "choisir un dossier"
boitedialogue.Show
If boitedialogue.SelectedItems(1) = "" Then
    MsgBox "Selectionner un dossier"
    Else
    Destination = boitedialogue.SelectedItems(1)
End If
 
End Function  '***elle est détruite ici***

Bonne journée

[Thumb down]

Bonjour,
pourquoi utiliser une fonction qui retourne rien et une variable public alors que la fonction pourrait retourner la valeur utile!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Public Function choisirdestination() As Variant
With Application.FileDialog(msoFileDialogFolderPicker)
    .AllowMultiSelect = False
    .Title = "choisir un dossier"
    .Show
   If CBool(.SelectedItems.Count) Then choisirdestination = .SelectedItems(1) Else choisirdestination = False
End With
End Function

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub commExportPdf_Click()
Dim NomFichier As String
Dim Dmaj As String
Dim Site As String
Dim Cible As Variant
 
Dmaj = Replace(DT_Maj, "/", "")
Site = Replace([Nom Site], "/", "%")
NomFichier = "Fiche Technique" & "_" & Site & "_" & Dmaj & ".pdf"
 
Cible = choisirdestination()
 
If TypeName(Cible) = "Boolean" Then
    MsgBox "Vous n'avez pas Selectionner un dossier"
Else
    MsgBox NomFichier
    DoCmd.OutputTo acOutputReport, , acFormatPDF, Cible & "\" & NomFichier, True
End If
End Sub

[gui_li_aume]

Bonjour thumbdown,

Parce que ta proposition fonctionne. Merci. Je n'avais pas testé la proposition de robert1957, mais elle me paraissait limpide. Donc c'est ton code qui marche. Merci à vous deux