Discussion :

[ESVBA]

Bonjour,

je galère : mon code n'affiche plus les lignes filtrées.
Oui, oui, mon code affichait les bonnes lignes et j'ai modifié plusieurs choses.
Maintenant, il n'affiche plus les lignes filtrées sur la feuille Excel.
Je ne comprends plus. J'ai testé différentes déclarations de plage filtrée mais rien n'y fait.

Je fais appel à vous.

ESVBA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub testremplissage()
    Dim Tmp          As String
    Dim Plage        As Range
    Dim PlageFiltree As Range
    Dim i As Long                   'N° ligne dans la listbox
    Dim K As Integer                ' K colonne du tableau et de la listbox
    Dim Cel As Range                'Cellule filtrée de la première colonne
 
    Set Plage = Worksheets("Dates Annuelles Générées").Range("A2", Range("A65536").End(xlUp)).Resize(, 1)
    Set PlageFiltree = Plage.SpecialCells(xlCellTypeVisible)
 
    i = 0
    For Each Cel In PlageFiltree
        Me.LstHoraire.AddItem Format(i + 1, "000")         'Me.LstHoraire.List(i, 0) = Format(i, "000")
        For K = 1 To 9
            Select Case K
                Case 7, 8
                    Tmp = Format(Cel.Offset(i, K - 1).Value, "hh:mm")
                Case Else
                    Tmp = Cel.Offset(i, K - 1).Value
            End Select
 
            Me.LstHoraire.List(i, K) = Tmp
        Next K
        i = i + 1
    Next Cel
End Sub

Merci de votre aide.

[ESVBA]

Je viens de constater :

le filtre est fait sur une date, la feuille de calcul m'affiche correctement les dates correspondantes.

L'erreur de remplissage de la Listbox est uniquement sur la colonne de dates (les dates proviennent bien de la base) mais ne correspondent pas toutes à la date filtrée !

Toutes les autres colonnes sont correctement remplies avec les bonnes valeurs.

J'ai déjà essayer de modifier le format de remplissage dans la listbox rien n'y fait.

Dans la feuille, les dates sont au format "Lun 03/10/2022" et je souhaite simplement un format "03/10/2022" (3 octobre).

H'ai ajouté

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
                Case 1
                MsgBox "<" & Cel.Offset(i, K - 1).Value & ">"
                    Tmp = Format(Cel.Offset(i, K - 1).Value, "dd/mm/yyyy")

mais rien n'y fait.

Les dates affichées par la MSGBOX ne sont pas les bonnes.

[hyperion13]

Salut
Je ne vois pas à partir de L9 de votre macro Post#1 la fonction AutoFilter !
Quelle est alors l'utilité en L10 de SpecialCells(xlCellTypeVisible) ?

Et êtes-vous dans un tableau structuré (intitulé de votre Post#1) ou dans un tableau "normal" ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets(1).Range(Cells(1, 1), Cells(Range("A" & Rows.Count).End(xlUp).Row, Cells(1, Columns.Count).End(xlToLeft).Column)).AutoFilter Field:=2, Criteria1:="Product A"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets(1).ListObjects("Tableau1").Range.AutoFilter Field:=2, Criteria1:="Product A"

[ESVBA]

Merci de te pencher sur mon problème.

Il s'agit d'un tableau structuré de type "Listobject".

Oui, je n'ai pas mis le code du filtre ; il n'était pas fini, cette fois c'est fait.
Je le joins mais sans rapport avec mon problème de balayer toutes les valeurs visibles (filtrées).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
    '--- Efface la "Listbox" car on a un nouveau choix de date
    LstHoraire.Clear
 
    '--- Filtrage
    ' Efface le filtre si existant
    If Feuil14.FilterMode Then
        Feuil14.ListObjects("TabHoraireHebdo").Range.AutoFilter
    End If
 
    'Filtre avec la date au format US provenant du bouton cliqué
    Dim DatClic As String
    DatClic = Mid(Controls("LblJour" & IndexBoutonClic).Caption, 1 + InStr(Controls("LblJour" & IndexBoutonClic).Caption, Chr(10)))
 
    'Filtre pour les différentes périodes : dates de certaines périodes
    Dim PremierLundiAnnuel As Date
    PremierLundiAnnuel = DateSerial(Range("_Annee").Value, 9, 1) - Weekday(DateSerial(Range("_Annee").Value, 9, 1), vbMonday) + 1
    NoSemaineAnnuelle = (CDate(DatClic) - PremierLundiAnnuel) \ 7
    Dim Period() As String
    ReDim Period(1 To 3)
    Period(1) = "ab"                                                                  'Toutes les semaines
    Period(2) = "12"                                                                  'Tous les semestres
    Period(3) = IIf(NoSemaineAnnuelle Mod 2 = 0, "a", "b")         'semaine a si N°Pair sinon
    If CDate(DatClic) > Range("Semestre2").Value Then              'Test si on est au second semestre
        ReDim Preserve Period(1 To 4)                                          'Si on est 2e semestre alors oui ajoute le code "2"
        Period(4) = "2"
    End If
 
    'ATTENTION +15 A SUPPRIME PAR LA SUITE
    Worksheets("Dates Annuelles Générées").ListObjects("TabHoraireHebdo").Range.AutoFilter Field:=1, Operator:=xlFilterValues, Criteria1:=Array(CDate(Datclic) + 15)
    ActiveSheet.ListObjects("TabHoraireHebdo").Range.AutoFilter Field:=4, Criteria1:=Array(Period()), Operator:=xlFilterValues
 
    '--- Rempli un tableau des valeurs filtrées
    Call testremplissage

Mon Code de remplissage de la "Listbox" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub testremplissage()
    Dim Tmp          As String
    Dim Plage        As Range
    Dim PlageFiltree As Range
    Dim i As Long                   'N° ligne dans la listbox
    Dim K As Integer                ' K colonne du tableau et de la listbox
    Dim Cel As Range                'Cellule filtrée de la première colonne
 
    'Set Plage = Worksheets("Dates Annuelles Générées").Range("A2", Range("i65536").End(xlUp)).Resize(, 1) .Rows
    Set Plage = Worksheets("Dates Annuelles Générées").Range("A2", Range("A65536").End(xlUp))  
    'A FAIRE : ICi gérer plage vide
    Set PlageFiltree = Plage.SpecialCells(xlCellTypeVisible)
 
   'Même réponse avec la ligne suivante
   'Set PlageFiltree = Worksheets("Dates Annuelles Générées").ListObjects("TabHoraireHebdo").ListColumns("Dates").DataBodyRange.SpecialCells(xlCellTypeVisible)
 
    i = 0
    For Each Cel In PlageFiltree.Rows
        'MsgBox Cel.Cells(1).Value             'Offset(i, 2).Value
        Me.LstHoraire.AddItem Format(i + 1, "000")         'Me.LstHoraire.List(i, 0) = Format(i, "000")
        For K = 1 To 9
            Select Case K
                Case 1
                    Tmp = Format(Cel.Offset(i, K - 1).Value2, "dd/mm/yyyy")
                Case 7, 8
                    Tmp = Format(Cel.Offset(i, K - 1).Value, "hh:mm")
                Case Else
                    Tmp = Cel.Offset(i, K - 1).Value
            End Select
 
            Me.LstHoraire.List(i, K) = Tmp
        Next K
        i = i + 1
    Next Cel
End Sub

Voici ce que j'obtiens :oui, il y a un décalage de 15 jours entre le bouton cliqué et la valeur du filtre. C'est normal, c'est pour avoir des valeurs.


LES DATES NE CORRESPONDENT PAS MAIS LES AUTRES COLONNES OUI. LA SELECTION EST BONNE, C'EST L'INTERPRETATION DES DATES ?
J'ai utilisé ".Value" et ".Value2" (spécifique aux dates)

Merci de ton aide.

[laurent_ott]

Bonjour,
Cela vient peut-être de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Cel.Offset(i, K - 1)

Pour rester sur la même ligne il faut faire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Cel.Offset(0, K - 1)

[ESVBA]

bonjour laurent_ott,

et si je disais "BIEN VU".

Merci laurent_ott, c'est la solution.


Quant on ne veut pas voir, on ne voit pas.

Merci à toi.

RESOLU