Discussion :

[Fabrice7627]

Bonjour à tous,

Je reviens à la charge.

Le temps d'exécution pour ces boucles imbriquées est de 46 secondes pour 5 000 lignes.

Une idée de code pour améliorer cette vitesse ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
Sub Exemple()
 
t = Timer
 
Dim tableau0
Dim tableau1
Dim tableau2(1 To 200, 1 To 100)
Dim derniereLigne As Integer
Dim I As Integer
 
 
With Sheets("Exercice")
 
derniereLigne = .Cells(Rows.Count, 1).End(xlUp).Row
 
tableau0 = .Range("A1:B" & derniereLigne).Value
 
tableau1 = tableau0
 
ReDim Preserve tableau1(1 To UBound(tableau0), 1 To 202)
 
For K = 2 To 200
For j = K - 1 To UBound(tableau1)
Somme = 0
For I = j + 2 - K To j
Somme = Somme + tableau1(I, 1)
tableau1(j, K + 2) = Somme / K
Next
Next
Next
 
For K = 1 To 200
For L = 1 To 100
 
For I = 2 To UBound(tableau1)
For j = K To K
If tableau1(I, j + 2) > tableau1(I - 1, j + 2) And tableau1(I, 2) > L Then
tableau1(I, 3) = 1
End If
a = 0
If tableau1(I, 3) = 1 Then
a = a + tableau1(I, 3)
End If
Next
Next
 
tableau2(K, L) = a
 
 
Next
Next
 
 
.Range("S1").Resize(UBound(tableau2, 1), UBound(tableau2, 2)).Value = tableau2
 
End With
 
MsgBox Timer - t
 
End Sub

[curt]

Bonsoir Fabrice7627,

sur la deuxième ligne ajoute :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

application.screenupdating = false

et sur avant-dernière le Msgbox :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

application.screenupdating = true

En recherchant dans la FAQ Excel, tu y trouveras toutes les infos pour améliorer les temps d'exécution des macros

[Fabrice7627]

Non curt, ni le "Application.ScreenUpdating", ni le "Application.Calculation" n'apportent de gain de temps.

[EricDgn]

Bonjour,

Je n'ai pas compris (et pas vraiment essayé) ce que cela veut faire , mais il me semble que ceci pourrait un peu réduire le temps de calcul:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Option Explicit
 
Sub Exemple()
    Dim t As Date
    t = Timer
    Dim tableau0
    Dim tableau1
    Dim tableau2(1 To 200, 1 To 100)
    Dim derniereLigne As Long               '--- Long
    Dim Somme As Single
    Dim i As Long, j As Long, k As Long, ub1 As Long, a As Long
    With Sheets("Exercice")
        derniereLigne = .Cells(Rows.Count, 1).End(xlUp).Row
        tableau0 = .Range("A1:B" & derniereLigne).Value
        tableau1 = tableau0
        ub1 = UBound(tableau1)
        ReDim Preserve tableau1(1 To UBound(tableau0), 1 To 202)
        For k = 2 To 200
            For j = k - 1 To ub1
                Somme = 0
                For i = j + 2 - k To j
                    Somme = Somme + tableau1(i, 1)
                    tableau1(j, k + 2) = Somme / k
                Next
            Next
        Next
        For k = 1 To 200
            For j = 1 To 100
                For i = 2 To ub1
                    If tableau1(i, 2) > j Then
                        If tableau1(i, k + 2) > tableau1(i - 1, k + 2) Then
                            tableau1(i, 3) = 1
                        End If
                    End If
                    If tableau1(i, 3) = 1 Then
                        a = 1
                    Else
                        a = 0
                    End If
                Next
                tableau2(k, j) = a
            Next
        Next
        .Range("S1").Resize(UBound(tableau2, 1), UBound(tableau2, 2)).Value = tableau2
    End With
    MsgBox Timer - t
End Sub

Cordialement.

[Fabrice7627]

Bonjour EricDgn,

Merci pour votre proposition.

Le temps d'exécution est de 20 secondes. Beau gain.

Il est 5h00 du matin, je regarde plus en détail votre code demain après-midi et je vous recontacte.

Cordialement.

[Fabrice7627]

Bonjour EricDgn,

Vous avez supprimé une boucle, à juste titre, ce qui me fait gagner 10 secondes.

Vous avez modifié ma définition de "a", qui se voulait une addition de colonne ; soit. Cela fait gagner 4 secondes.

Étonnamment, pour moi, la déclaration de toutes les variables semble faire gagner 2 secondes.
Vous confirmez que le fait de déclarer les variables fait gagner du temps d'exécution ?


Mais ce qui m'a le plus surpris, c'est qu'en remplaçant mon "And" par un "IF Then", cela fait gagner 10 secondes.

Doit-on toujours donner la priorité à un "If Then" et bannir le "And" pour optimiser le temps d'exécution d'une macro ?

En tout cas, merci pour votre analyse et votre réécriture.

Cordialement.

[jurassic pork]

Hello,

Mais ce qui m'a le plus surpris, c'est qu'en remplaçant mon "And" par un "IF Then", cela fait gagner 10 secondes.
Doit-on toujours donner la priorité à un "If Then" et bannir le "And" pour optimiser le temps d'exécution d'une macro ?

VBA n'utilise pas d'évaluation booléenne de court-circuit (short-circuit en Angliche).
Les instructions VBA And et Or évaluent toujours les deux expressions de l'instruction. Avec 2 If imbriqués la deuxième expression ne sera pas évaluée si la première expression échoue donc on peut gagner du temps.
Ami calmant, J.P

[EricDgn]

Bonjour,

Les boucles sur i, j, k sont parcourues 100 * 200 * 5000 = 100.000.000 fois, donc chaque microseconde gagnée a de l'effet.

Le fait de placer If tableau1(i, 2) > j permet de vérifier en premier la condition la plus simple, et inutile d'aller s'occuper de la seconde si elle n'est pas vérifiée. Le If tableau1(i, k + 2) > tableau1(i - 1, k + 2) prendra toujours plus de temps à vérifier vu qu'elle contient beaucoup plus de calculs indirects que l'autre.
Il est d'ailleurs possible que

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
                    If tableau1(i, 2) > j And tableau1(i, k + 2) > tableau1(i - 1, k + 2) Then
                        tableau1(i, 3) = 1
                    End If

donne le même bon résultat, la contrainte la plus simple à vérifier étant testée en premier.

Enfin je me demande si les lignes 35 à 39 ne pourraient pas être supprimées, avec la ligne 41 devenant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

                tableau2(k, j) = IIf(tableau1(ub1, 3) = 1, 1, 0)

Cordialement.