Discussion :

[steever38]

Bonjour,
Je suis entrain de créer un jeu en batch.
J'aimerai introduire un système de récompense journalière : une fois par jour, on peut récupérer 25 de score gratuit.
Mais comment faire en sorte qu'on puisse la récupérer qu'une fois par jour ?

Merci

[ericlm128]

Tu dois stocker l'information, le jour me parait assez pertinent.
Le plus simple est de créer un fichier (le nom suffira pour le moment), exemple :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
@echo off
cls
 
set "FileRecompense=%~dp0%date:/=_%.flag"
 
REM Création du flag de la récompense journalière
echo. >"%FileRecompense%"
 
REM Vérification de la récompense aujourd'hui
IF EXIST "%FileRecompense%" (echo DEJA gagne aujourd hui) else (echo PAS encore gagne aujourd hui)
 
pause

[steever38]

Bonsoir,
A chaque fois, la console me renvoit : "DEJA gagne aujourd hui" alors que c'est la première fois que je lance le .bat
Si je supprimer le fichier .flag et que je relance le .bat toujours le message : "DEJA gagne aujourd hui"...

[ericlm128]

Hum .... je vois

Voici le code légèrement modifié.
Tu as maintenant les pièces de Lego de base à toi de les assembler comme il faut pour créer ce que tu veux.

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
@echo off
cls
 
set "FileRecompense=%~dp0%date:/=_%.flag"
 
REM Vérification de la récompense aujourd'hui
IF EXIST "%FileRecompense%" (echo DEJA gagne aujourd hui) else (echo PAS encore gagne aujourd hui)
 
REM Création du flag de la récompense journalière
echo. >"%FileRecompense%"
 
pause

[steever38]

Merci,
On ne peut pas supprimer les flags des jours précédents ?

[ericlm128]

on le peux

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
@echo off
cls
 
set "FileRecompense=%~dp0%date:/=_%.flag"
 
REM Suppression des anciens fichiers flag
for /F "tokens=*" %%a in ('dir "%~dp0??_??_????.flag" /A /B') do if /I NOT "%FileRecompense%" == "%%~dpnxa" del /F /Q /A "%%~dpnxa"
 
REM Vérification de la récompense aujourd'hui
REM IF EXIST "%FileRecompense%" (echo DEJA gagne aujourd hui) else (echo PAS encore gagne aujourd hui)
 
REM Création du flag de la récompense journalière
REM echo. >"%FileRecompense%"
 
pause

[steever38]

Merci, ça fonctionne parfaitement !

[steever38]

J'ai une autre question,
j'ai créer différents comptes utilisateurs pour mon jeu, donc la récompense journalière doit être récupérer qu'une seul fois pour chaque comptes.
J'ai réussi mais le problème est que je n'arrive pas a supprimer les anciens flags...

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
cls
 
set "FileRecompense=.\library\users\%username%\recompense\%date:/=_%.flag" >nul
 
for /F "tokens=*" %%a in ('dir "%~dp0??_??_????.flag" /A /B') do if /I NOT "%FileRecompense%" == "%%~dpnxa" del /F /Q /A "%%~dpnxa"
echo %FileRecompense%
 
IF EXIST "%FileRecompense%" (echo DEJA gagne aujourd hui) else (echo PAS encore gagne aujourd hui)
pause

Merci

[ericlm128]

Le "." représente bien pour toi le dossier ou est situé le batch ?

Si oui

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
cls
 
set "FileRecompense=%~dp0library\users\%username%\recompense\%date:/=_%.flag" >nul
 
for /F "tokens=*" %%a in ('dir "%~dp0library\users\%username%\recompense\??_??_????.flag" /A /B') do if /I NOT "%FileRecompense%" == "%%~dpnxa" del /F /Q /A "%%~dpnxa"
echo %FileRecompense%
 
IF EXIST "%FileRecompense%" (echo DEJA gagne aujourd hui) else (echo PAS encore gagne aujourd hui)
pause

[steever38]

Je ne peux toujours pas supprimer les anciens flags
Et ou le "." représente les dossiers précédents

Je reçois ces messages dans la fenêtre dos :

Impossible de trouver C:\Users\steever38\Desktop\pierre papier ciseaux\03_03_2022.flag
Impossible de trouver C:\Users\steever38\Desktop\pierre papier ciseaux\04_03_2022.flag
DEJA gagne aujourd hui
Appuyez sur une touche pour continuer...

mon batch ce trouve dans mon "C:\Users\steever38\Desktop\pierre papier ciseaux"

voici le code complet de la récompense :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
cls
 
set "FileRecompense=%~dp0library\users\%username%\recompense\%date:/=_%.flag" >nul
 
for /F "tokens=*" %%a in ('dir "%~dp0library\users\%username%\recompense\??_??_????.flag" /A /B') do if /I NOT "%FileRecompense%" == "%%~dpnxa" del /F /Q /A "%%~dpnxa"
 
IF EXIST "%FileRecompense%" (echo DEJA gagne aujourd hui) else (echo PAS encore gagne aujourd hui)
 
echo. >"%FileRecompense%"
pause

[ericlm128]

Je ne comprend pas bien ton organisation.

Je comprend que le batch est ici : C:\Users\steever38\Desktop\pierre papier ciseaux
Mais ou doivent se trouver les récompenses ?

[ericlm128]

Changons un peu la structure en imaginant que tes récompenses sont ici : C:\library\users\%username%\recompense
Je pense qu'avec ce code tu peux faire aussi des chemins relatifs

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
cls
@echo off
 
set "folder_R=C:\library\users\%username%\recompense"
set "file_R=%date:/=_%.flag"
 
set "FileRecompense=%folder_R%\%file_R%"
 
for /F "tokens=*" %%a in ('dir "%folder_R%\??_??_????.flag" /A /B 2^>nul') do if /I NOT "%file_R%" == "%%~nxa" del /F /Q /A "%folder_R%\%%~nxa"
echo %FileRecompense%
 
IF EXIST "%FileRecompense%" (echo DEJA gagne aujourd hui) else (echo PAS encore gagne aujourd hui)
pause

[steever38]

Merci, c'est exactement que je voulais.

Voici le code final que j'ai mis :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
set "folder_R=.\library\users\%username%\recompense"
set "file_R=%date:/=_%.flag"
 
set "FileRecompense=%folder_R%\%file_R%"
 
for /F "tokens=*" %%a in ('dir "%folder_R%\??_??_????.flag" /A /B 2^>nul') do if /I NOT "%file_R%" == "%%~nxa" del /F /Q /A "%folder_R%\%%~nxa"
IF EXIST "%FileRecompense%" (goto :Oui) else (goto :Non)