Changer la langue d'édition Excel avec du code VBA.

**November-Oscar** · 14/02/2022, 14h31

Bonjour
Excel n'est pas comme Word car on ne peut pas voir les fautes de frappe ou autre soulignées en vert ou en rouge.
J'ai trouvé ce bout de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub ColorMispelledCells()
    Dim cl As Range
    For Each cl In ActiveSheet.UsedRange
        If Not Application.CheckSpelling(Word:=cl.Text) Then _
          cl.Font.Color = -16776961
    Next cl
End Sub

Ce code met l'écriture de toute la cellule en rouge si la vérification d'orthographe d'Excel remonte quelque chose.
Maintenant mon problème est que parfois/souvent mes feuilles excel sont soit en Français soit en Anglais.

Donc ma question est : est-il possible de changer la langue la langue d'édition (qui doit servir pour la vérification orthographique) par du code VBA.

Excel est réglé en Français chez moi et c'est très bien.
Donc lorsque je veux faire un tel contrôle, il faudrait que :
1- j'enregistre la langue réglée
2- je demande quelle langue de contrôle je veux utiliser
3- je modifie ma langue réglée si c'est différent et c'est là que j'ai besoin de vous
4- je lance la procédure ci-dessus
5- je remets la langue de départ si elle a été modifiée pour le besoin de contrôle.

Voilà tout. Merci pour votre aide.

**Jean-Philippe André** · 14/02/2022, 14h39

Salut,

la notion de langue sous Excel est accessible via

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.LanguageSettings.LanguageID(msoLanguageIDUI)

qui te retournera par exemple 1036 pour le français.

Malheureusement (ou plutôt heureusement), cette propriété est en lecture seule (imagine une macro qui te change l'interface en thai ou russe...

La seule piste que je verrai qui t'amènerai plus proche de ton objectif est de trouver une API Windows.

**November-Oscar** · 14/02/2022, 15h56

Je me doutais d'un truc du type 'lecture seule' ; car rien sur le net.

pas grave au final : le code remontera simplement la langue réglée et dira à l'opérateur d'aller la modifier au besoin... toujours mieux que rien.

Pour l'histoire d'API Windows, je n'y connais absolument rien. donc pas compris.

merci encore

**laurent_ott** · 14/02/2022, 15h59

Bonjour.
Dans la documentation de MicroSoft, le 4e argument de la fonction permet de déterminer la langue :
CheckSpelling (CustomDictionary, IgnoreUppercase, AlwaysSuggest, SpellLang) (voir https://docs.microsoft.com/fr-fr/off....checkspelling).

SpellLang = Langue du dictionnaire utilisé. Peut être l’une des valeurs MsoLanguageID (voir https://docs.microsoft.com/fr-fr/off....msolanguageid).

J'ai mis "hello word" en A1 et j'ai testé :
Debug.Print Range("A1").CheckSpelling(, , , msoLanguageIDFrench) => trouve une erreur.
Debug.Print Range("A1").CheckSpelling(, , , msoLanguageIDEnglishUK) => pas d'erreur.

Puis "hello everibodi"
Debug.Print Range("A1").CheckSpelling(, , , msoLanguageIDEnglishUK) => trouve une erreur et propose "everybody".

Donc ça semble bien marcher avec ma configuration : Version Excel 2016 / Window 10.
A vérifier le résultat sur votre PC.

Cordialement.

**November-Oscar** · 14/02/2022, 16h23

Merci pour cette idée qui me fait poser la question suivante :

est-il possible d'intercepter l'action sur la touche F7 ? --> au lieu de de lancer la vérification orthographique selon une langue réglée dont l'utilisateur n'a pas conscience, on pourrait intercepter l'action et faire qqch avant, non ?

**laurent_ott** · 14/02/2022, 16h33

Envoyé par November-Oscar

est-il possible d'intercepter l'action sur la touche F7 ? --> au lieu de de lancer la vérification orthographique selon une langue réglée dont l'utilisateur n'a pas conscience, on pourrait intercepter l'action et faire qqch avant, non ?

Oui, c'est possible de rediriger F7 vers une autre fonction, par exemple MaCorrection qui fera votre correction orthographique :
A placer (généralement) à l'ouverture du classeur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.OnKey "{F7}", "MaCorrection"

puis pour restaurer la fonction normale:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Application.OnKey "{F7}", ""

Cordialement.

**November-Oscar** · 14/02/2022, 17h39

Merci pour cette réponse du 4e argument...

Ci-dessous le code que je vous avais mis dans mon tout premier message. Code qui fonctionne très bien selon la langue déjà renseignée dans les options.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub ColorMispelledCells()
    Dim cl As Range
    For Each cl In ActiveSheet.UsedRange
        If Not Application.CheckSpelling(Word:=cl.Text) Then _
          cl.Font.Color = -16776961
    Next cl
End Sub

Comment intégrer cette notion de 4e argument dans ce code ? J'ai tenté cela (voir ci-dessous) mais ça plante "Erreur de compilation - Erreur de syntaxe" en pointant sur la 2e virgule ajoutée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub ColorMispelledCells()
    Dim cl As Range
    For Each cl In ActiveSheet.UsedRange
        If Not Application.CheckSpelling(Word:=cl.Text,,,msoLanguageIDEnglisUS) Then _
          cl.Font.Color = -16776961
    Next cl
End Sub

Merci. Si ça pouvait fonctionner, je n'aurais plus qu'un choix de la langue de contrôle à choisir au début du programme.

**Jean-Philippe André** · 14/02/2022, 17h43

Envoyé par laurent_ott

Bonjour.
Dans la documentation de MicroSoft, le 4e argument de la fonction permet de déterminer la langue :
CheckSpelling (CustomDictionary, IgnoreUppercase, AlwaysSuggest, SpellLang) (voir https://docs.microsoft.com/fr-fr/off....checkspelling).

...

A faire apparaitre dans la

**November-Oscar** · 14/02/2022, 18h25

Que dois-je faire apparaître dans la foire aux questions ? (je ne suis pas un habitué du forum)

Je voulais juste terminer par votre avis sur cette ligne de code qui plante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Not Application.CheckSpelling(Word:=cl.Text,,,msoLanguageIDEnglisUS) Then cl.Font.Color = -16776961

**laurent_ott** · 14/02/2022, 21h45

La fonction renvoie True ou False donc le test est du genre :
If ... = False Then ...

**November-Oscar** · 15/02/2022, 09h38

Petit à petit j'avance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub ColorMispelledCells()
    Dim cl As Range
    For Each cl In ActiveSheet.UsedRange
        If Not Application.CheckSpelling(Word:=cl.Text) Then
            If cl.CheckSpelling(, , , msoLanguageIDEnglishUS) Then
                cl.Font.Color = -16776961
            End If
        End If
    Next cl
End Sub

Ce code fonctionne très bien. Juste toujours à fixer en début un choix de la langue de contrôle. Fonctionne très bien...
sauf qu'à chaque occurrence, la boîte de dialogue 'Orthographe' s'ouvre. Je suis sûr qu'il doit y avoir un moyen d'annihiler l'ouverture de boîtes de dialogue en début de dialogue au début et de le rétablir à la fin du programme.
Avez-vous une telle ligne de code ?

Merci.

**laurent_ott** · 15/02/2022, 09h44

Les lignes 4 et 8 ne servent à rien.
Pour l'affichage de la boîte de dialogue c'est le 3e argument à mettre à False.
Cordialement.

**November-Oscar** · 15/02/2022, 11h19

Merci Laurent. J'ai fait les modifications (voir code joint) mais ça m'ouvre toujours la boîte de dialogue 'Orthographe'.
Il faudrait peut-être au début un truc du type 'Application.displayalerts = false' et le rétablir à la fin mais ce n'est pas ça bien sûr et je n'ai pas la commande.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub ColorMispelledCells()
    Dim cl As Range
    For Each cl In ActiveSheet.UsedRange
        'If Not Application.CheckSpelling(Word:=cl.Text) Then
            If cl.CheckSpelling(, , False, msoLanguageIDEnglishUS) Then
                cl.Font.Color = -16776961
            End If
        'End If
    Next cl
End Sub

**laurent_ott** · 15/02/2022, 12h35

Envoyé par November-Oscar

ça m'ouvre toujours la boîte de dialogue 'Orthographe'.

Effectivement, mais il y a une astuce : utiliser Application.CheckSpelling(Word, CustomDictionary, IgnoreUppercase) au lieu de Range.CheckSpelling(CustomDictionary, IgnoreUppercase, AlwaysSuggest, SpellLang).

Application.CheckSpelling renvoi TRUE si le mot passé dans "Word" est correct ou FALSE s'il y a une faute d'orthographe par rapport au dictionnaire actif.
il faut donc boucler sur les mots et passer dans Word le texte à analyser, c'est-à-dire le texte de la cellule, et non pas la cellule.

Mais Application.CheckSpelling ne permet pas de définir le dictionnaire actif (il lui manque l'argument SpellLang). Alors il faut utiliser Range.CheckSpelling une fois pour définir le dictionnaire.
Ici je passe un range qui a un texte vide (par exemple sur la feuille 3), c'est juste pour définir le dictionnaire actif.

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub ColorMispelledCells()
 
    Dim cl As Range
    Call Sheets("Feuil3").Range("A1").CheckSpelling(, , , msoLanguageIDEnglishUS) ' ou msoLanguageIDFrench
 
    For Each cl In ActiveSheet.UsedRange
        If Application.CheckSpelling(cl.Text) = False Then cl.Font.Color = -16776961
    Next cl
 
End Sub

A tester.

**November-Oscar** · 15/02/2022, 13h10

Génial. Merci

**laurent_ott** · 15/02/2022, 13h50

Si ça marche on peut en faire une fonction un peu plus générique :

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
'---------------------------------------------------------------------------------------
Function ControleOrthographe(RngAnalyse As Range, _
                             Dictionnaire As MsoLanguageID, _
                             CouleurSiErreur As Long, _
                             ActionSiErreur As Byte) As Boolean
'---------------------------------------------------------------------------------------
' Controle l'orthographe d'une plage.
'---------------------------------------------------------------------------------------
' RngAnalyse : la plage à analyser.
' Dictionnaire : dictionnaire à utiliser de l'énumération MsoLanguageID.
'                exemples : msoLanguageIDFrench français, msoLanguageIDEnglishUS anglais.
' CouleurSiErreur : si <> 0 met le texte en erreur de la couleur demandée.
' ActionSiErreur : action à faire en cas d'erreur d'orthographe.
'                  0 = continue l'analyse.
'                  1 = sélectionne la cellule et quitte la fonction.
'                  2 = sélectionne la cellule et ouvre le dictionnaire pour corriger le texte
'                      puis continue l'analyse.
'---------------------------------------------------------------------------------------
' Renvoie : True si aucune faute ou False dans le cas contraire.
'---------------------------------------------------------------------------------------
' Exemple d'appel de la fonction:
' Debug.Print ControleOrthographe(RngAnalyse:=ActiveSheet.UsedRange, _
'                                 Dictionnaire:=msoLanguageIDFrench, _
'                                 CouleurSiErreur:=0, _
'                                 ActionSiErreur:=2)
'---------------------------------------------------------------------------------------
Dim cl As Range
ControleOrthographe = True
 
' Gestion des erreurs:
On Error GoTo Gest_Err
Err.Clear
 
' Trouve une cellule vide dans la feuille pour définir le dictionnaire à utiliser:
For Each cl In ActiveSheet.Cells
    If cl.Value = "" Then
        Call cl.CheckSpelling(, , , Dictionnaire)
        Exit For
    End If
Next cl
 
' Boucle sur les cellules pour vérifier l'orthographe:
For Each cl In RngAnalyse
    ' En cas d'erreur:
    If Application.CheckSpelling(cl.Value) = False Then
        ' La fonction renverra False:
        ControleOrthographe = False
        ' S'il faut changer la couleur du texte:
        If CouleurSiErreur <> 0 Then cl.Font.Color = CouleurSiErreur
        ' Action demandée:
        If ActionSiErreur = 1 Then
            cl.Select
            Exit For
        End If
        If ActionSiErreur = 2 Then
            cl.Select
            Call cl.CheckSpelling(, , , Dictionnaire)
        End If
    End If
Next cl
 
' Gestion des erreurs:
Gest_Err:
If Err.Number <> 0 Then
    ControleOrthographe = False
    MsgBox Err.Number & " : " & Err.Description, vbCritical, "Contrôle de l'orthographe"
    Err.Clear
End If
 
End Function
'---------------------------------------------------------------------------------------

**November-Oscar** · 15/02/2022, 16h27

Merci.
A ton avis, plutôt que de mettre en rouge toute la cellule, y aurait-t-il moyen de ne mettre en rouge que le mot concerné de la cellule ?

**laurent_ott** · 15/02/2022, 16h35

Envoyé par November-Oscar

Merci.
A ton avis, plutôt que de mettre en rouge toute la cellule, y aurait-t-il moyen de ne mettre en rouge que le mot concerné de la cellule ?

Oui, c'est faisable.
Il suffit de mettre le texte dans un tableau avec séparateur espace et de tester chaque mot.
Puis de mettre en rouge ce mot. S'il est trop petit il risque d'être mal vu.
On peut en VBA changer la police à l'intérieur d'un texte, l'enregistreur de macro donnera une idée du code.
Cordialement.

Changer la langue d'édition Excel avec du code VBA. [XL-2010]

Macros et VBA Excel

Discussions similaires

Partager

Partager