Discussion :

[Denis_67]

Bonjour,

Il y a de nombreux posts sur l'activation/desactivation du filtre automatique.

Cependant la séquence que j'utilise ne semble pas fonctionner.
En effet en fin de procédure aléatoirement, lorsque la macro me rend la main, le filtre est toujours actif.

Pouvez vous me conseiller une procédure plus fiable et si possible éprouvée.
Précision qui a peut-etre son importance : les données sont dans un tableau structuré

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
' on enlève les filtres de la feuille FNC
    Sheets("FNC").Activate
If ThisWorkbook.Worksheets("FNC").FilterMode = True Then ThisWorkbook.Worksheets("FNC").ShowAllData

merci
Denis

[laurent_ott]

Bonjour.
De mémoire, pour que la fonction FilterMode fonctionne il faut impérativement que la cellule active soit une cellule visible du tableau.
A vérifier dans votre cas.

Pour information, voici comment je procède (ça peut vous donner des idées):

Je mémorise le tableau structuré dans une variable (par exemple TD)
Je me place sur la première ligne de ce tableau car pour savoir si le tableau contient un filtre avec la fonction ActiveSheet.FilterMode il faut impérativement que la cellule active soit une cellule visible du tableau.
S'il y a un filtre je mémorise les conditions du filtre, puis j'efface le filtre.
je fais mes traitements.
S'il y avait un filtre je le restaure avec ses conditions.

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
' Mémorise le tableau structuré "MonTableau" de la feuille "Feuil1":
Dim TD As Range
Set TD = Sheets("Feui1").Range("MonTableau")
 
' La cellule active doit être une cellule visible du tableau
' pour que la fonction ActiveSheet.FilterMode puisse fonctionner:
 Cells(TD.Row - 1, TD.Column).Select
 
' Si le filtre automatique n'existe pas cela renvoie une erreur:
Dim Filtre As Boolean
Filtre = ActiveSheet.FilterMode
 
' Si au moins un filtre est actif alors mémoriser tous les filtres et les vider:
If Filtre = True Then
    Filters_Memorize
    TD.AutoFilter
End If
 
' Mes traitements sont ici ...
 
' Restaure les filtres:
If Filtre = True Then
    TD.AutoFilter
    Filters_Restore
End If
 
'------------------------------------------------------------------------------------------------------

Code VBA :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Dim FilterArray()
 
'-----------------------------------------------------------------------------------------------
Sub Filters_Memorize()
'-----------------------------------------------------------------------------------------------
' Mémorise les filtres de la feuille active.
'-----------------------------------------------------------------------------------------------
Dim f As Integer
 
With ActiveSheet.AutoFilter.Filters
    ReDim FilterArray(1 To .Count, 1 To 3)
    For f = 1 To .Count
        With .Item(f)
            If .On Then
                FilterArray(f, 1) = .Criteria1
                If .Operator Then
                    FilterArray(f, 2) = .Operator
                    FilterArray(f, 3) = .Criteria2
                End If
            End If
        End With
    Next
End With
 
End Sub
 
'-----------------------------------------------------------------------------------------------
Sub Filters_Restore()
'-----------------------------------------------------------------------------------------------
' Restore les filtres de la feuille active préalablement mémorisés.
'-----------------------------------------------------------------------------------------------
Dim f As Integer
 
For f = 1 To UBound(FilterArray(), 1)
    If Not IsEmpty(FilterArray(f, 1)) Then
        If FilterArray(f, 2) Then
            ActiveSheet.Range(ActiveSheet.AutoFilter.Range.Address).AutoFilter Field:=f, _
                Criteria1:=FilterArray(f, 1), _
                Operator:=FilterArray(f, 2), _
                Criteria2:=FilterArray(f, 3)
        Else
            ActiveSheet.Range(ActiveSheet.AutoFilter.Range.Address).AutoFilter Field:=f, Criteria1:=FilterArray(f, 1)
        End If
    End If
Next
End Sub
'-----------------------------------------------------------------------------------------------

Cordialement.

[Denis_67]

Merci Laurent,

je crois bien que la formule magique réside dans ton explication

De mémoire, pour que la fonction FilterMode fonctionne il faut impérativement que la cellule active soit une cellule visible du tableau.

En effet depuis que je m'assure que je suis positionné sur la ligne d'entête avant d'enlever le filtre cela semble fonctionner !

Merci pour cette évidence, que je n'avais point vue sur les posts sur le sujet, sûrement que c'est trop évident !

Denis