Jour de semaine

**Angelus1753** · 07/11/2021, 09h57

Bonjour à tous, je reviens vers vous pour une nouvelle question. qui me semble pour ma part compliqué. pour d'autre semblera un jeux d'enfant.

ma question et donc est il possible de connaître le jour de la semaine en le vocalisant par le biais d'un ( HTA )

j'ai trouver un code qui est en vbs

mes je voudrai faire de même en ( HTA )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
dim d 'date à traiter 
dim stJs ' chaine jour de la semaine..
d = now ' date actuelle
stJS = WeekDayName(WeekDay(d))
Wscript.Echo " Nous sommes un : " & stJs

**hackoofr** · 07/11/2021, 10h54

Dans un HTA il faut utiliser MsgBox au lieu de Wscript.echo car les objets WScript ne sont pas supportées dans un HTA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
dim d 'date à traiter 
dim stJs ' chaine jour de la semaine..
d = now ' date actuelle
stJS = WeekDayName(WeekDay(d))
MsgBox " Nous sommes un : " & stJs

**ProgElecT** · 07/11/2021, 10h56

Salut

J'ai çà dans mes archives

Code html :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
<HTML>
	<HEAD>
	<TITLE> heure universelle actuelle (UTC) </TITLE>
		<HTA:APPLICATION
         ApplicationName = "DateHeureUTC"
         Id="DateHeureUTC"
		>
	</HEAD>
	<SCRIPT language="VBScript" type="text/VBScript" >
'------------------------------------------------------------------------------------------------------------------
            dim MonTimer
'------------------------------------------------------------------------------------------------------------------
                Sub Window_Onload()
                        BoiteVisuHeure.innerText = FormatDateTime(UTCTimeDemo(s),vbLongTime) 
                        BoiteVisuDate.innerText = FormatDateTime(UTCDateDemo(s),vbLongDate)
                        BoiteHeureSystem.innerText = FormatDateTime(Time,vbLongTime)
                        StartTimer
                End Sub
'------------------------------------------------------------------------------------------------------------------
                Sub Window_onUnLoad()
                        If GoActu.Value = "Arreter" then StopTimer
                        Set MonTimer = Nothing
                End Sub
'------------------------------------------------------------------------------------------------------------------
                Sub StartTimer
                        MonTimer = window.setInterval ("Actualis", 1000, "VBScript") 'Appel de Actualis toutes les secondes
                End sub
'------------------------------------------------------------------------------------------------------------------
                Sub StopTimer
                        window.ClearInterval MonTimer
                end sub
'------------------------------------------------------------------------------------------------------------------
                Sub Actualis()
                        BoiteVisuHeure.innerText = FormatDateTime(UTCTimeDemo(s),vbLongTime) 
                        BoiteVisuDate.innerText = FormatDateTime(UTCDateDemo(s),vbLongDate)
                        BoiteHeureSystem.innerText = FormatDateTime(Time,vbLongTime)
                End Sub
'------------------------------------------------------------------------------------------------------------------
                Sub GoActu_onClick
                        If GoActu.Value = "Reprendre" then
                                GoActu.Value = "Arreter"
                                StartTimer
                                Else
                                StopTimer
                                GoActu.Value = "Reprendre"
                        End if
                End sub
'------------------------------------------------------------------------------------------------------------------
                Sub GoParler_onClick
                        Dim Voix
                        Set Voix = CreateObject("SAPI.SpVoice")
                        Voix.Speak BoiteVisuDate.innerText
                        Set Voix = NotHing ' Nettoyage
                End sub
'------------------------------------------------------------------------------------------------------------------
        </SCRIPT>
	<SCRIPT language="javaScript" type="text/javaScript" >
function UTCDateDemo()
{
   var d, s;
   d = new Date();
   s = d.getUTCDate() + "/";
   s += (d.getUTCMonth() + 1) + "/";
   s += d.getUTCFullYear();
   return(s);
}
function UTCTimeDemo()
{
   var d, s;
   var c = ":";
   d = new Date();
   s = d.getUTCHours() + c;
   s += d.getUTCMinutes() + c;
   s += d.getUTCSeconds();
   return(s);
}
        </SCRIPT>
	<Body>
		<Div STYLE="color:#000000; position:absolute; left:10px; top:10px; height:13px; width:140px"> Date et heure UTC </Div>
		<INPUT Type="button" name="GoActu" value="Arreter" STYLE="color:#000095; position:absolute; left:160px; top:6px; height:26px; width:80px">
		<Div STYLE="color:#000000; position:absolute; left:10px; top:40px; height:13px; width:37px"> Il est </Div>
		<Div Id="BoiteVisuHeure" STYLE="color:#000095; position:absolute; left:60px; top:40px; height:13px; width:60px"> </Div>
		<Div STYLE="color:#000000; position:absolute; left:132px; top:40px; height:13px; width:120px"> nous sommes le </Div>
		<Div Id="BoiteVisuDate" STYLE="color:#000095; position:absolute; left:256px; top:40px; height:13px; width:200px"> </Div>
		<Div STYLE="color:#000000; position:absolute; left:10px; top:70px; height:13px; width:140px"> Heure système </Div>
		<Div Id="BoiteHeureSystem" STYLE="color:#000095; position:absolute; left:60px; top:100px; height:13px; width:60px"> 21:04:50 </Div>
		<INPUT Type="button" name="GoParler" value="Lire" STYLE="color:#000095; position:absolute; left:10px; top:160px; height:26px; width:80px">
	</Body>
</HTML>

Cela devrait t'occuper un moment

, tu dis si tu ne comprend pas quelque chose.

**Angelus1753** · 07/11/2021, 13h00

Bonjour à Vous, Hackoofr
merci d'avoir répondue aussi vite

Bonjour à Vous, ProgElect
c'est exactement ce que je cherche. l'idée était que si on clique sa nous donne la date du jour sa ok! avec la possiblité de pouvoir lui faire dire bon dimanche excellent lundi...

d'ou ma question es ce que c'est possible

mes déja avec vous ProgElect ce qui semble compliqué, ce transforme immédiatement en quelque chose de très simple. encore merci pour vos réponse

**ProgElecT** · 07/11/2021, 14h31

Re

petite modification dans la sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub GoParler_onClick
      Dim Voix, NumJour, MotDuJour(7)
      MotDuJour(0) = "Grace matinée? "                'dimanche
      MotDuJour(1) = "Du courage pour ce "            'lundi
      MotDuJour(2) = "Bon "                           'mardi
      MotDuJour(3) = "Milieu de semaine ce "         'mercredi
      MotDuJour(4) = "Dernière ligne droite, "        'jeudi
      MotDuJour(5) = "Demain la quille, "             'vendredi
      MotDuJour(6) = "Ouf  "                          'samedi
      NumJour = Weekday(date) - 1
 
      Set Voix = CreateObject("SAPI.SpVoice")
       Voix.Speak MotDuJour(NumJOur) + BoiteVisuDate.innerText
       Set Voix = NotHing ' Nettoyage
End sub

**Angelus1753** · 07/11/2021, 14h52

cette exactement ce que je voulais, merci infiniment ProgElect

pour moi le problème est résolu

j'aurai une dérnière petite question peut ton reduire la taille de la fenêtre? et faire en sorte que la fenêtre ce ferme toute sele une fois la date donnée?

Un Grand merci à vous.

**ProgElecT** · 07/11/2021, 15h25

Re

Pour dimensionner et positionner la fenêtre HTA, au début de la sub Window_Onload().

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
		ResizeTo 500, 250 ' dimensionnement de la fenêtre HTA (largeur, hauteur)
		MoveTo (Screen.availWidth-500)/2, (Screen.availHeight - 250) / 2 ' Centrage de la fenêtre HTA sur le bureau

et pour fermer le HTA Window.Close(), après la commande Set Voix = NotHing ' Nettoyage de la sub GoParler_onClick

**Angelus1753** · 07/11/2021, 15h45

Magnifique tout est parfait merci à vous ProgElect

problème Résolu

Jour de semaine

VBScript

Discussions similaires

Partager

Partager