script batch ouverture page internet plein écran

**jojo8266** · 02/07/2021, 12h33

j'aimerai crée un script qui ouvre une page internet en plein écran

cmd /C start http://www.google.com

mais j'aimerai qu'il s'ouvre en grand écran

**barnabe0057** · 02/07/2021, 12h54

Bonjour,

Essaie comme cela :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

start /max http://www.google.com

**hackoofr** · 02/07/2021, 14h01

Code BATCH :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
@echo off
REM Start Google Chrome with Kiosk Mode
@Start "Chrome" "%programfiles%\Google\Chrome\Application\chrome.exe" --kiosk https://www.google.com
REM Start Internet Explorer with Kiosk Mode
@Start "iexplore" iexplore -K "https://www.yahoo.com"

Pour Firefox je n'ai pas trouvé un switch pour le mode Kiosk, mais j'ai essayé avec ceci :

Code BATCH :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
@echo off
>nul CHCP 65001
Title Ouvrir une page internet en plein écran avec le Navigateur de Firefox
Mode 100,3 & color 0A
Set "URL=http://www.google.com"
echo(
echo   La page "%URL%" va s'ouvir en plein écran
Timeout /T 4 /NoBreak>nul
Start "" Firefox "%URL%"
Call :FullScreen
Exit
::****************************************************************
:FullScreen
(
    echo Set WS = CreateObject("Wscript.Shell"^)
    echo wscript.sleep 3000
    echo WS.SendKeys "{F11}"
)>"%tmp%\%~n0.vbs"
Wscript "%tmp%\%~n0.vbs"
Exit /b
::****************************************************************

**kaitlyn** · 02/07/2021, 16h41

Envoyé par hackoofr

Pour Firefox je n'ai pas trouvé un switch pour le mode Kiosk

Salut,

ceci fonctionne bien : start "" firefox -kiosk https://duckduckgo.com
en tout cas avec la version ESR de Firefox (Firefox Extended Support Release)

**hackoofr** · 02/07/2021, 18h59

Envoyé par kaitlyn

Salut,
ceci fonctionne bien : start "" firefox -kiosk https://duckduckgo.comen tout cas avec la version ESR de Firefox (Firefox Extended Support Release)

Oui je crois qu'il faut faire quelque chose comme ça : Testé sur mon Windows 10 (32 bits)

Code BATCH :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
@echo off
Taskkill /F /T /IM "Firefox.exe"
@Start "FireFox" "%programfiles%\Mozilla Firefox\firefox.exe" --kiosk "https://www.reddit.com/r/Batch/comments/oc8qyf/how_to_run_firefox_in_kisok_mode/"