Discussion :

[zeralium]

Bonjour,

J'utilise le code suivant pour separer les expressions d'une meme cellule contenant des retours ligne et les mettres dans des cellules differente:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim a As Variant
a = Split(Cells(1, 1).Value, Chr(10))
Cells(1, 3) = a(0)
Cells(1, 4) = a(1)
Cells(1, 5) = a(2)
Cells(1, 6) = a(3

J'ai 2 soucis que je n'arrive pas résoudre:
1 - Comment detecter le nombre retour ligne dans cette cellule "source"???
2 - Je souhaiterai conserver la mise en forme de chaque expressions, possible???

Ci-dessous un exemple de ce que je souhaiterai


D'avance merci

[Invité]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
Sub Test()
 
Dim A As Variant
Dim Matrice() As Variant
Dim I As Integer, LongueurChaine As Integer
 
    A = Split(ActiveCell, Chr(10))
    LongueurChaine = 1
    For I = LBound(A) To UBound(A)
        ReDim Preserve Matrice(2, I)
        Matrice(0, I) = A(I)
        Matrice(1, I) = ActiveCell.Characters(LongueurChaine, Len(A(I))).Font.Color
        Matrice(2, I) = ActiveCell.Characters(LongueurChaine, Len(A(I))).Font.Strikethrough
        LongueurChaine = LongueurChaine + Len(A(I)) + 1
    Next I
 
    For I = LBound(Matrice, 2) To UBound(Matrice, 2)
        With ActiveCell.Offset(0, 2 + I)
             .Value = Matrice(0, I)
             .Font.Color = Matrice(1, I)
             .Font.Strikethrough = Matrice(2, I)
        End With
    Next I
 
 
End Sub

[zeralium]

Bonjour Eric,

Merci beaucoup pour ton aide, ca marche super.
Maintenant il me reste plus qu'a comprendre et a appliquer à mon fichier.