Discussion :

[Hessef]

Bonjour,

Je suis novice en script et ne suis pas informaticien alors soyez indulgents !
Je vais pour mon travail sur plusieurs sites, doit me connecter au réseau manuellement (pas de DHCP), vérifier des équipements sur le réseau ...
J'ai vite compris qu'il suffisait d'envoyer un ping (et pas courir le bâtiment pour regarder si c'est allumé) mais ca reste long à la longue.
Je voudrais faire un script (un par site) qui me change mon adresse (+proxy), envoie un ping sur chaque équipement et me donne en réponse dans une petite fenêtre comme windows sait faire ok ou echec
Je n'y connais rien mais j'aimerais comprendre si possible.
J'ai essayé ca mais ca ne semble pas fonctionner dès le départ

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
@echo off
netsh interface ipv4 set address name="Ethernet" static 10.6.148.170 255.255.255.0 10.6.148.1
 
ping 10.6.148.200
ping 10.6.148.201
ping 10.6.148.202
ping 10.6.148.203 ...

En réponse je veux juste

10.6.148.200 OK ...

Si j'ai compris, il faut passer par un fichier ?

Merci de votre patience et aide

[barnabe0057]

Bonjour,

Voilà une ébauche qui devrait s'approcher du but recherché :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
@echo off
mode con cols=42 lines=30
title %~nx0
setlocal enableextensions enabledelayedexpansion
ver | find "10.0." >nul && chcp 65001 >nul || chcp 28591 >nul
 
:: --------------------------------------------------------------------------------------
:: on vérifie si le script est bien lancé en tant qu'administrateur
:: --------------------------------------------------------------------------------------
 
attrib %windir%\system32 -h | findstr /i "system32" >nul && exit /b 1
 
:: --------------------------------------------------------------------------------------
:: on définit les paramètres
:: --------------------------------------------------------------------------------------
 
set action="00000001"
set proxy="http=127.0.0.1:8888;https=127.0.0.1:8888;ftp=127.0.0.1:8888;socks=127.0.0.1:8888"
 
set adresse_debut="10.6.148.200"
set adresse_fin="10.6.148.220"
 
for /f "tokens=4 delims=. " %%A in (%adresse_debut%) do set "debut=%%A"
for /f "tokens=4 delims=. " %%A in (%adresse_fin%) do set "fin=%%A"
for /f "tokens=1-3 delims=." %%A in (%adresse_debut%) do set "reseau=%%A.%%B.%%C"
 
:: --------------------------------------------------------------------------------------
:: on modifie l'adressage de la carte réseau filaire
:: --------------------------------------------------------------------------------------
 
netsh interface ipv4 set address "Ethernet" static 10.6.148.170 255.255.255.0 10.6.148.1 1
 
:: --------------------------------------------------------------------------------------
:: on active le proxy
:: --------------------------------------------------------------------------------------
 
rem Décommenter la ligne ci-dessous pour basculer automatiquement entre l'état "activé" et "désactivé"
rem for /f "tokens=3" %%A in ('reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /V "ProxyEnable"') do if "%%A"=="0x0" (set action="00000001") else (set action="00000000")
 
>nul reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /V "ProxyServer" /T REG_SZ /D %proxy% /F
>nul reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /V "ProxyEnable" /T REG_DWORD /D %action% /F
 
cls & echo. & if %action%=="00000001" (echo ########## Proxy activé ##########) else (echo ########## Proxy désactivé ##########)
 
:: --------------------------------------------------------------------------------------
:: on teste la connectivité
:: --------------------------------------------------------------------------------------
 
for /L %%E in (%debut%,1,%fin%) do (
 
	for /f "delims=" %%A in ('ping %reseau%.%%E -n 3') do set "result=%%A"
 
	set "status=FAILED"
	echo !result! | find "0%" | find /v "100%" >nul && set "status=OK"
	echo !result! | find "33%" >nul && set "status=OK"
	echo. & echo ^>^>^> %reseau%.%%E !status!
)
 
echo. & pause
exit

Ces 3 variables sont à adapter pour chaque site :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
set proxy="http=127.0.0.1:8888;https=127.0.0.1:8888;ftp=127.0.0.1:8888;socks=127.0.0.1:8888"
 
set adresse_debut="10.6.148.200"
set adresse_fin="10.6.148.220"

ps : ne pas oublier de lancer le script avec le clic-droit puis "exécuter en tant qu'administrateur"