Discussion :

[gregelec]

Bonjour à tous , je suis électronicien et je débute dans l'arduino .
Mon projet est basé sur un ATtiny85 Digispark .
J'ai réussi à le programmer donc l'IDE fonctionne !
Maintenant je ne sais pas comment générer 2 impulsions de 15 secondes sur la sortie (P3) si sur l'entrée ( P2) j'ai un front montant qui est plus long que les sorties.
voir chronogramme joint

PS c'est mon premier post soyez indulgents et pédagogues

[Jay M]

Salut

si sur l'entrée ( P2) j'ai un front montant qui est plus long que les sorties

je ne comprends pas, c'est pas possible... au moment du front vous ne pouvez pas savoir si le signal sur P2 va être plus long ou pas que votre sortie..

au mieux vous pourrez générer les 2 impulsions "au bout d'un certain temps" et éventuellement si P2 est toujours HIGH... mais les fronts ne peuvent pas être simultanés à moins que vous ne considériez que c'est OK d'interrompre un des fronts de sortie si P2 tombe.

[gregelec]

Je sais que ce qui arrive sur P2 dure 1 minute.
il faut que P3 tombe 15 sec monte 15 secondes et retombe 15 secondes puis remonte c'est pour modifier le fonctionnement d'un appareil existant donc les durées sont imposées

[Jay M]

Si vous êtes dans ce dernier cas, le code se résume à une simple machine à états qu'on pourrait décrire comme cela (code absolument non testé, tapé ici)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
const byte pin2 = 2;
const byte pin3 = 3;
 
enum : byte {waitingp2Low, p2LOW, p3Pulse1, p3Pulse2, p3Pulse3} etat = waitingp2Low;
unsigned long chrono;
 
void gestionEtat() {
  switch (etat) {
 
    case waitingp2Low: // attente repos
      if (digitalRead(pin2) == LOW) etat = p2LOW; break;
 
    case p2LOW: // attente du front montant
      if (digitalRead(pin2) == HIGH) {
        digitalWrite(pin3, LOW); // lancement du front
        chrono = millis();
        etat = p3Pulse1;
      }
      break;
 
    case p3Pulse1: // si pin2 tombe on arrête, sinon on attend 15s
      if (digitalRead(pin2) == LOW) {
        digitalWrite(pin3, HIGH);
        etat = p2LOW;
      } else if (millis() - chrono >= 15000) { // on a atteint 15s
        digitalWrite(pin3, HIGH);
        chrono = millis();
        etat = p3Pulse2;
      }
      break;
 
    case p3Pulse2: // si pin2 tombe on arrête, sinon on attend 15s
      if (digitalRead(pin2) == LOW) {
        digitalWrite(pin3, HIGH);
        etat = p2LOW;
      } else if (millis() - chrono >= 15000) {
        digitalWrite(pin3, LOW);
        chrono = millis();
        etat = p3Pulse3;
      }
      break;
 
    case p3Pulse3: // si pin2 tombe on arrête, sinon on attend 15s
      if (digitalRead(pin2) == LOW) {
        digitalWrite(pin3, HIGH);
        etat = p2LOW;
      } else if (millis() - chrono >= 15000) {
        digitalWrite(pin3, HIGH);
        etat = waitingp2Low;
      }
      break;
  }
}
 
void setup() {
  pinMode(pin2, INPUT);
  pinMode(pin3, OUTPUT);
  digitalWrite(pin3, HIGH);
}
 
void loop() {
  gestionEtat();
}

(ici pour simplifier et rendre plus lisible, j'ai mis 3 états pour les 2 impulsions de la pin 3, on pourrait traiter cela avec une variable qui compte le nombre d'impulsion)

On aura les 2 impulsions de 15s si le signal P2 dure plus de 30 secondes, mais on ne sait pas s'il va durer 60s. S'il fait 35 secondes on aura eu les impulsions.
Si P2 fait 20 secondes on aura eu la première impulsion de 15 secondes et on interrompt

[Jay M]

PS/ et bien sûr si vous voulez rester synchrone, il suffit d'utiliser delay(15000); pour attendre 15 secondes et "fabriquer" le signal de sortie.

[Vincent PETIT]

Bonjour,
Une autre solution consisterait à user des interruptions du Attiny85.

La broche PB2 est interruptible sur changement d'état, voir datasheet PCINT2: Pin Change Interrupt 0, Source 2 ça veut dire qu'on peut créer une fonction d'interruption lorsqu'il y a un changement d'état de PB2 (un front montant ou descendant).

Dans cette fonction d'interruption on peut régler le Timer interne 1, car il est connecté à PB3 voir datasheet OC1B: Complementary Timer/Counter1 Compare Match B Output pour qu'il créait des impulsions précises de 15s comme sur ton schéma.

A+