Discussion :

[mfranchi]

Bonjour,

Sur mon fichier excel, à chaque fois que la valeur de la colonne C est différente de celle qui la précède, une ligne est insérée.
Sur la ligne insérée, en colonne D, je souhaite sommer la colonne D de toutes les cellules ayant la même valeur en C.?
C'est la première fois que je travailles avec VBA donc je suis un peu perdue sur cette partie.

Pour l'instant j'ai ce qui suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Insérer_Lignes()
 
Dim Lg As Long, i As Long
    Lg = Range("A65536").End(xlUp).Row
    Application.CutCopyMode = False
        For i = Lg To 2 Step -1
            If Range("c" & i - 1) <> Range("c" & i) Then
                Range(Range("c" & i), Range("c" & i + 0)).EntireRow.Insert
                Range(Range("c" & i), Range("c" & i + 0)).EntireRow.Interior.Color = RGB(225, 225, 225)
                'Sur case D du row inséré, sommer les valeurs de D du range sus dit
        Next i
    Rows("2:2").Select
    Selection.RowHeight = 12
    Rows("1:1").Select
    Selection.RowHeight = 80
 
End Sub

Si quelqu'un pouvait m'aider. ca serait super Sachant que je ne suis pas douée en informatique.

[ARTURO83]

Bonjour,

Voici
Pièce jointe 593318

Le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub Insérer_Lignes()
    Dim Lg As Long, i As Long, DerLig_Total As Range
    Application.ScreenUpdating = False
    Lg = Range("A" & Rows.Count).End(xlUp).Row
    Set DerLig_Total = Columns("C").Find("Total", lookat:=xlWhole)
    If Not DerLig_Total Is Nothing Then
        MsgBox "Les totaux ont déjà été traités"
        Exit Sub
    End If
    Cells(Lg + 1, "C") = "Total"
    For i = Lg To 2 Step -1
        If Range("c" & i - 1) <> Range("c" & i) Then
            Rows(i).EntireRow.Insert
            Range(Cells(i, "A"), Cells(i, "F")).Interior.Color = RGB(225, 225, 225)
            Set DerLig_Total = Columns("C").Find("Total", lookat:=xlWhole)
            If Not DerLig_Total Is Nothing And DerLig_Total.Row > i Then
                Range(Cells(i, "D"), Cells(i, "F")).FormulaR1C1 = "=SUM(R" & i + 1 & "C:R" & DerLig_Total.Row - 1 & "C)"
                Cells(i, "C") = "Total"
                With Range(Cells(i, "A"), Cells(i, "F")).Font
                    .Bold = True
                    .Size = 20
                End With
                Rows(i).RowHeight = 42.75
            End If
        End If
    Next i
 
    Range("C" & Rows.Count).End(xlUp).ClearContents
    Set DerLig_Total = Nothing
End Sub
 
Sub Supprimer_Totaux()
    Dim DerLig As Long, i As Long
    Application.ScreenUpdating = False
    DerLig = Range("A" & Rows.Count).End(xlUp).Row
    For i = DerLig To 2 Step -1
        If Cells(i, "C") = "Total" Then Rows(i).Delete
    Next i
End Sub

Cdlt

[mfranchi]

Merci beaucoup Arturo.
J'ai réussi à l'adapter parfaitement à mon fichier final.