Discussion :

[jaquot14]

Bonjour à tous,

je viens vers vous car je n'arrive pas à créer un code vba pour remplacer la formule de calcul du tableau feuille Tirage pour mon fichier mis en pièce jointe.
Dans le tableau de la feuille Tirage il y a une formule qui permet de copier les valeurs d'un tableau en feuille Base
si la valeur de la cellule K4 ou K25 ou K46 ect de la feuille Base est égale à la valeur de la cellule H3 de la feuille Inscrip.
Merci pour vos réponses.
essai tri.xlsm

[EricDgn]

Bonjour,

Si j'ai bien compris, vous voulez recopier l'un des tableaux de la feuille Base dans la feuille Tirage, tableau sélectionné en fonction du nombre d'inscrits indiqué dans la cellule H3. Si c'est bien cela, ceci le fait:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Option Explicit
 
Sub CopierBase()
    Dim fBase As Worksheet, fTirage As Worksheet, fInscrip As Worksheet
    Dim n As Integer, k As Long
    Set fBase = ThisWorkbook.Worksheets("Base")
    Set fTirage = ThisWorkbook.Worksheets("Tirage")
    Set fInscrip = ThisWorkbook.Worksheets("Inscrip")
    fTirage.Cells.Clear     '--- vide la feuille Tirage
    n = fInscrip.Range("H3").Value  '--- nombre de participants
    If n < 8 Then
        MsgBox "Le nombre de participants doit être de 8 au minimum", , "Annulé"
        Exit Sub
    End If
    k = 4 + 21 * (n - 8)    '--- k = position de la première ligne du tableau à recopier
    fBase.Range("B" & k & ":Y" & k + 18).Copy fTirage.Range("B4")
    fTirage.Select
    Range("A1").Select
    Set fBase = Nothing
    Set fTirage = Nothing
    Set fInscrip = Nothing
End Sub

Cordialement.

[jaquot14]

Bonsoir le forum et bonsoir EricDgn,

Je reviens seulement aujourd'hui, car je n'avais pas eu le temps avant.
Un grand merci à vous EricDgn car j'ai testé votre code fonctionne parfaitement comme je le souhaitais, je l'ai adapté à mon fichier définitif.
Forum super
Encore Merci