Discussion :

[TheHugoGua]

Bonjour,

Je débute actuellement le VBA et je rencontre un souci de pratique...

Je voudrais dans un cadre professionnel développer une macro me permettant de faire des synthèses de différents fichiers.

Pour ce faire, je sais qu'il est possible de sélectionner plusieurs fichiers un par un pour ensuite en extraire mes données souhaitées. Mais dans un souci de simplicité, j'aurais voulu savoir s'il était directement possible de demander à ma macro d'ouvrir directement un répertoire / dossier où sont entreposés tous mes fichiers.

Exemple : En gros au lieu d'ouvrir les fichiers "Semaine 1/2/3" je voudrais que ma macro questionne directement le dossier "Janvier.

Auriez-vous des tips, des cas similaires ou des connaissances à m'apporter svp.

Merci énormément d'avance.

Bien cordialement,

Hugo.

[pijaku]

Bonjour,

Un exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub BoucleDir()
Dim Chemin As String, Fichier As String, Extens As String
 
    '********** A ADAPTER
    Chemin = "C:\Users\" & Environ("UserName") & "\Desktop\"
    Extens = "*.xls*"
    '*******************************************************
 
    Fichier = Dir(Chemin & Extens)
    If Fichier <> vbNullString Then
        Do
            MsgBox Chemin & Fichier
            Fichier = Dir
        Loop While Fichier <> vbNullString
    End If
End Sub

[TheHugoGua]

En effet, ce bout de code me permet d'arriver à mes fins, mais pas par le moyen voulu ...

Car le code cible un dossier bien précis, mais personnellement ma macro devra fonctionner sur différents dossiers pouvant eux-mêmes de nom.

Pour l'instant, j'ai uniquement travaillé avec des "getopenfilename" et j'ai l'impression que ça revient à la même que votre code.

Petite précision théoriquement, j’aurais aimé que ma macro soit sur un fichier excel de ce genre : feuille 1 = bouton de commande qui fait tourner ma macro / feuille 2 = Synthèse collée suite au passage de ma macro

Pour l'instant, j'ai réussi à créer mon fichier / bouton de commande / extraire des données vers la feuille 2 classiquement

Les 2 problèmes que j’encours sont : Le fait de faire questionner à ma macro un dossier / répertoire et non un ficher excel puis gérer une inconnue de nombre de fichiers excel dans mon dossier mais ça ça devrait aller en créant une suite je pense.

Du coup, je ne sais pas si vous auriez plus d'infos sur le fameux dossier svp

Merci d'avance pour votre réponse !! <3

[pijaku]

Par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
 
Sub SelectionRepertoireEtAction()
'https://www.developpez.net/forums/d107034/logiciels/microsoft-office/general-vba/vba-selectionner-repertoire/#post701479
Dim Repertoire As FileDialog
    Set Repertoire = Application.FileDialog(msoFileDialogFolderPicker)
    Repertoire.Show
    If Repertoire.SelectedItems.Count > 0 Then
        Call BoucleDir(Repertoire.SelectedItems(1), "*.xls*")
    End If
End Sub
 
Private Sub BoucleDir(Chemin As String, Extension As String)
Dim Fichier As String
    If Right(Chemin, 1) <> Application.PathSeparator Then Chemin = Chemin & Application.PathSeparator
    Fichier = Dir(Chemin & Extension)
    If Fichier <> vbNullString Then
        Do
            MsgBox Chemin & Fichier
            Fichier = Dir
        Loop While Fichier <> vbNullString
    End If
End Sub

[TheHugoGua]

Muchas gracias c'est exactement ce qu'il me fait !

C'est vraiment sympathique de votre part de m'avoir consacré du temps.

Pourrais-je me retourner vers vous si j'encontre d'autres problèmes svp ??

[pijaku]

Bonjour,

De rien!

Pourrais-je me retourner vers vous si j'encontre d'autres problèmes svp ??

Le forum est là pour cela.
1- chercher parmi les milliers de discussions si ton problème n'a pas déjà été traité,
2- si non, poster ta demande comme tu l'as fait hier...

A++