Discussion :

[manufer]

Bonjour à toutes et à tous,

Voilà j'ai un onglet ( Feuil1) dans lequel se trouve des données (un tableau ≠ tableau de variable)

Je souhaite intégrer ces données dans un tableau de variable par une boucle.

J'ai donc fait:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 
Sub tab_varA()
 
'Définition du tableau
Dim tab_exemple()
 
'Déclaration
Dim dern_ligne As Variant
Dim dern_col As Variant
Dim i As Variant
 
'définition des limites du tableau
dern_ligne = Feuil1.Cells(Rows.Count, 1).End(xlUp).Row
dern_col = Feuil1.Cells(1, Columns.Count).End(xlToLeft).Column
 
'Enregistrement des valeurs dans le tableau
For i = 0 To dern_ligne
    For j = 0 To dern_col
        tab_exemple(i, j) = Feuil1.Cells(i + 1, j + 1)
    Next
Next
 
End Sub

Mais ça ne marche pas, j'ai un message d'erreur "l'indice n'appartient pas à la sélection",

Si quelqu'un a une idée de l'erreur à corriger, je suis preneur.

Merci à tous.

[Invité]

Bonjour,

Si vous voulez utiliser la matrice en dehors de la procédure tab_varA, il faut au moins la déclarer Private (ou Dim) en tête de module, voire Public si utilisée dans un autre module.
Attention, dans l'exemple, les colonnes et lignes sont inversées car j'utilise Preserve dans le redimensionnement de la matrice.

A tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
 
Option Explicit
 
Public tab_exemple() As Variant
 
Sub Testtab_varA()
 
Dim I As Long
 
    tab_varA
 
     For I = LBound(tab_exemple, 2) To UBound(tab_exemple, 2)
        Debug.Print tab_exemple(0, I) & ", " & tab_exemple(1, I)
     Next I
 
 
End Sub
 
Sub tab_varA()
 
'Déclaration
Dim Dern_ligne As Long, Dern_col As Long, I As Long, J As Long
 
    Erase tab_exemple
 
    'définition des limites du tableau
    With Feuil1
         Dern_ligne = .Cells(.Rows.Count, 1).End(xlUp).Row
         Dern_col = .Cells(1, .Columns.Count).End(xlToLeft).Column
 
         'Enregistrement des valeurs dans le tableau
         For I = 0 To Dern_ligne - 1
             ReDim Preserve tab_exemple(Dern_col - 1, I)
             For J = 0 To Dern_col - 1
                 tab_exemple(J, I) = .Cells(I + 1, J + 1)
             Next J
         Next I
 
    End With
 
 
End Sub

[manufer]

Je crois avoir trouvé une piste:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Sub tab_varA()
 
'Définition du tableau
Dim tab_exemple()
 
'Déclaration
Dim dern_ligne As Variant
Dim dern_col As Variant
Dim i As Variant
Dim j As Variant
 
 
 
'définition des limites du tableau
dern_ligne = Feuil1.Cells(Rows.Count, 1).End(xlUp).Row
dern_col = Feuil1.Cells(1, Columns.Count).End(xlToLeft).Column
 
ReDim tab_exemple(dern_ligne, dern_col)
 
'Enregistrement des valeurs dans le tableau
For i = 0 To dern_ligne
    For j = 0 To dern_col
        tab_exemple(i, j) = Feuil1.Cells(i + 1, j + 1)
        MsgBox tab_exemple(i, j)
 
    Next
Next
 
End Sub

Mais j'ai encore un petit problème sur la dernière colonne sur laquelle je boucle.

[manufer]

Merci Eric KERGRESSE,

Je vais essayer.

[pijaku]

Bonjour,

1- pourquoi une boucle?

2- Remplacer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
ReDim tab_exemple(dern_ligne, dern_col)
For i = 0 To dern_ligne
    For j = 0 To dern_col

par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
ReDim tab_exemple(0 To dern_ligne - 1, 0 To dern_col - 1)
For i = 0 To dern_ligne - 1
    For j = 0 To dern_col - 1

En effet, si, dans l'exemple, dern_ligne = 10, tu va boucler de la ligne 1 à la 10.
Et tu vas donc mettre ces valeurs dans ta variable tableau, aux indices : de 0 à 9...

[anasecu]

Bonjour,

Pourquoi une boucle quand VBA le fait en une ligne ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

tab_exemple = Feuil1.Cells(1, 1).Resize(dern_ligne, dern_col).Value

[manufer]

Ah cool,

Il est vrai que si je peux faire en une ligne de code ce que je faisais avec 4 ou 5 lignes c'est meilleur.

Ce que vous m'avez transmit fonctionne très bien merci.