Discussion :

[masala]

Salut,
J’ai une petite préoccupation concernant les tableaux en VBA. En effet, j’essaie un peu de m’exercer en remplissant un tableau de 2x5000 éléments (entiers) qui proviennent de colonnes F et L.
L’objectif est de faire la soustraction pour obtenir une différence entre les éléments de F et L et ensuite, les remplacer dans la colonne F.

Avec ce bout de code que j’ai essayé, ça marche:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub enreg_tab()
Dim tab_exemple(4999, 1)
 
For i = 0 To 4999
'Enregistrement des valeurs dans le tableau
   tab_exemple(i, 0) = Range("F" & i + 2)
   tab_exemple(i, 1) = Range("L" & i + 2)
'Soustraction et remplacement
   Range("F" & i + 2) = tab_exemple(i, 0) - tab_exemple(i, 1)
 
 Next
End Sub

Sauf que ça me prend environ 20 minutes pour finaliser l’opération. Alors, étant débutant, je me tourne vers vous pour enfin, essayer de trouver une alternative plus rapide.
Cordialement !

[Invité]

Bonjour,

Environ 0,05 seconde. Le principe est de copier la formule sur une colonne non utilisée et de copier en "spécial valeur" le résultat dans la colonne F.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
 
Sub RecalculColonneF()
 
Dim DerniereColonne As Integer
Dim HeureDebut2, HeureFin2, TempsTotal2
 
    With Application
         .ScreenUpdating = False
         .Calculation = xlCalculationManual
    End With
 
    HeureDebut2 = Timer
    With ActiveSheet
         DerniereColonne = .Cells(1, .Columns.Count).End(xlToLeft).Column + 1
         With .Range(.Cells(2, DerniereColonne), .Cells(5002, DerniereColonne))
              .Formula = "=F2-L2"
              .Calculate
              .Copy
         End With
         .Range("F2").PasteSpecial xlPasteValues
         .Range(.Cells(2, DerniereColonne), .Cells(5002, DerniereColonne)).Clear
    End With
 
    With Application
         .ScreenUpdating = True
         .Calculation = xlCalculationAutomatic
    End With
 
    HeureFin2 = Timer
    TempsTotal2 = HeureFin2 - HeureDebut2
    Debug.Print "Temps total  : " & Round(TempsTotal2, 2) & " seconde(s)"
 
 
End Sub

[Patrice740]

Bonjour,

Avec des tableaux :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub enreg_tab()
Dim tabF, tabL, i As Long
Dim t As Single
t = Timer
  tabF = Range("F2:F5001").Value
  tabL = Range("L2:L5001").Value
  For i = 1 To 5000
    tabF(i, 1) = tabF(i, 1) - tabL(i, 1)
  Next i
  Range("F2:F5001").Value = tabF
Debug.Print Timer - t & " seconde"
End Sub

Moins de 0.05 seconde

[masala]

Merci beaucoup à vous tous pour de l'aide. Vos codes ont résolu mon problème.
Vous êtes vraiment sympas!