Discussion :

[Devnbi]

Bonjour à tous,

J'ai fait un script batch qui sauvegarde certaines données de chaque profil utilisateur local sur un disque dur secondaire, à 2 conditions : que le profil ne figure pas dans une liste d'exclusion et qu'il ait bien un dossier nominatif sur le disque dur secondaire.

Pour chaque profil en cours de sauvegarde (répondant aux conditions évoquées ci-dessus), je voudrais afficher sa position actuelle parmi les profils restants à sauvegarder.

Par exemple: "Sauvegarde du profil (1 / 10) : Thomas"

Je n'ai aucune idée de comment je peux faire cela, mes connaissances étant assez limitées.

Voici mon code :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set BackupDest=D:\backup
 
for /f "tokens=*" %%I in ('dir /a:d-h /b "%HomeDrive%\users\*" ^| findstr /b /e /i /l /v /g:"%~dp0exclude_users.txt"') do if exist "%BackupDest%\%%~nI\" (
 
echo -----------------------------------------
echo      Sauvegarde du profil : %%~nXI
echo -----------------------------------------
echo
 
xcopy "%%~nXI\Desktop" "%BackupDest%\%%~nXI\Desktop\" /e /i /y
xcopy "%%~nXI\Documents" "%BackupDest%\%%~nXI\Documents\" /e /i /y
 
)
 
pause
exit

Toute aide m'aiderait énormément.

Merci !

[barnabe0057]

Bonjour,

Pour assigner un chiffre à chaque profil, il suffit d'incrémenter une variable à chaque tour de boucle, avec la commande set /a
Pour obtenir le nombre maximal de profils à traiter il faut une deuxième boucle for comme celle que tu as fait.

Ca devrait donner ça :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set BackupDest=D:\backup
 
set profil_max=0
for /f "tokens=*" %%I in ('dir /a:d-h /b "%HomeDrive%\users\*" ^| findstr /b /e /i /l /v /g:"%~dp0exclude_users.txt"') do if exist "%BackupDest%\%%~nI\" (set /a profil_max+=1)
 
set index=0
for /f "tokens=*" %%I in ('dir /a:d-h /b "%HomeDrive%\users\*" ^| findstr /b /e /i /l /v /g:"%~dp0exclude_users.txt"') do if exist "%BackupDest%\%%~nI\" (
 
set /a index+=1
 
echo -----------------------------------------
echo      Sauvegarde du profil (!index! / !profil_max!) : %%~nxI
echo -----------------------------------------
echo
 
xcopy "%%~nxI\Desktop" "%BackupDest%\%%~nxI\Desktop\" /e /i /y
xcopy "%%~nxI\Documents" "%BackupDest%\%%~nxI\Documents\" /e /i /y
 
)
 
pause
exit

[Devnbi]

Merci. Mais cela me donne l'erreur ": était innatendu" pour la ligne set index=0.

[barnabe0057]

L'erreur provient des parenthèses que tu veux utiliser dans cette ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

echo      Sauvegarde du profil (!index! / !profil_max!) : %%~nxI

Soit tu les remplaces par autre chose, soit tu peux les échapper comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

echo      Sauvegarde du profil ^(!index! / !profil_max!^) : %%~nxI

[Devnbi]

Merci beaucoup ! Tout fonctionne !