Script de déplacement de fichier et archivage

**GADENSEB** · 06/03/2020, 10h04

Bonjour le Forum,
J'ai une question toute bête

J'ai un dossier "A" qui a comme sous-dossiers :
-"a1"
-"a2"
-"a3"
- "Ok Archivé"

je voudrais copiés les fichiers nouvellement arrivés dans ce dossier A et ses-sous dossiers (sauf "OK Archivé") vers un autre dossier appelé B

puis replacer ces fichiers copiés dans les mm sous-dossiers "A1"..... dans "ok archivé" qui est l'archive de sauvegarde de "A"

Je ne sais pas si j'ai étais clair

**barnabe0057** · 08/03/2020, 10h41

Bonjour,

Voilà un exemple :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
@echo off
setlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\Dossier A"
set "destination=Q:\Dossier B"
set "archivage=%source%\Ok archivé"
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
for /r %%A in (*.*) do (
 
	echo.
	xcopy /Y "%%~A" "%destination%" && call :fonction "%%~A"
 
)
 
pause
exit /b 0
 
:fonction
 
set "fichier=%~dp1"
 
echo.!fichier! | find "%archivage%" >nul || (
	set "archive=!fichier:%source%=%archivage%!"
	echo.
	xcopy /Y %1 "!archive!"
)
 
goto :eof

N'oublie pas de modifier la variable source et la variable destination en début de script.

**GADENSEB** · 09/03/2020, 10h19

Hello
Merci à toi.
Je teste cela ce soir

**GADENSEB** · 10/03/2020, 10h24

Bonjour,
Bon j'ai du me planter quelque part…….
L'adresse source : D:\PHOTOS\ADO- SAUVEGARDE TELEPHONE
L'adresse destination : D:\PHOTOS\SGA - A TRIER

Il me signale une erreur sur la première ligne

Où je me suis planté ?

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
@echo off
setlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
set "archivage=%source%\Ok archivé"
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
for /r %%A in (*.*) do (
 
 echo.
 xcopy /Y "%%~A" "%destination%" && call :fonction "%%~A"
 
)
 
pause
exit /b 0
 
:fonction
 
set "fichier=%~dp1"
 
echo.!fichier! | find "%archivage%" >nul || (
 set "archive=!fichier:%source%=%archivage%!"
 echo.
 xcopy /Y %1 "!archive!"
)
 
goto :eof

**enki31** · 13/03/2020, 09h27

Bonjour,

Question : avec quoi tu lances ce script?

Bonne journée.

**GADENSEB** · 13/03/2020, 09h49

Hello
J'ai fais un .VBS

**enki31** · 13/03/2020, 10h05

Envoyé par GADENSEB

Hello
J'ai fais un .VBS

je ne suis pas expert, mais il me semble que ce script est un .BAT

**GADENSEB** · 13/03/2020, 10h07

Ok
Je teste ce soir.
Merci à toi

**GADENSEB** · 22/03/2020, 14h23

Hello
J'ai testé le script et cela semble fonctionné.
Par contre j'ai eu un beug a cause des accent "ok archivé" et cela à resync ce dossier en faisant un dossier "ok achiv@"
Du coup j'ai transformé le dossier en "OK ARCHIVE"
voici la copie d'écran du dossier concerné
Nom : Capture.PNG
Affichages : 1337
Taille : 13,7 Ko

Nom : Capture.PNG
Affichages : 1337
Taille : 13,7 Ko

Est-ce que ton code fonctionne sur ce schéma ?

Est-ce possible de rajouter un critère de transformation dans le dossier de destination ?
--> Créer un dossier avec la date par regroupement de fichiers, a 99% des photos.

--> Si j'ai un des photos qui contient, par titre, de fichiers 20200321 cela créer un dossier avec ts les fichiers avec cette date/nom de fichier vers un dossier "2020 03 21"

Merci à toi, j’espère que tu vas bien dans cette période compliquée.

**barnabe0057** · 22/03/2020, 15h53

Salut tout va bien pour moi merci.

Pas de problème mon code est compatible avec ton arborescence.

Pour le critère avec la date des fichiers, il faudrait que je sache comment sont nommées les photos actuellement.
Est-ce qu'elles sont toutes nommées de la même façon ?

**GADENSEB** · 23/03/2020, 13h56

Bonjour
Merci de ton aide
voici le format des différents fichiers. je pense qu'il ne faut tenir compte que de 2019011 au centre du nom de fichier par exemple

Nom : Capture.PNG
Affichages : 1306
Taille : 2,8 Ko

Nom : Capture.PNG
Affichages : 1306
Taille : 2,8 Ko

Concernant l'atterrissage dans un dossier de type "2019 09 11", pourrait on dire que si le dossier existe déjà, les nouvelles photos seront importées dans ce mm dossier sans en créer un nouveau ?
Merci à toi

**GADENSEB** · 28/03/2020, 14h21

Hello
As-tu une idée pour ce petit programme ? :-)

**barnabe0057** · 28/03/2020, 15h17

Slt oui j'ai une idée, je te recontacte rapidement, j'étais occupé sur un projet ces derniers jours.

**GADENSEB** · 28/03/2020, 15h25

Hello pas de soucis !
Bonne am à toi

**barnabe0057** · 28/03/2020, 23h32

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
@echo off
setlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
set "archivage=%source%\OK ARCHIVE"
 
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
for /r %%A in (*.*) do (
	for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
 		echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (
			set "dossier=%%E"
			set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"
			if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!")
			echo.
			xcopy /Y "%%~A" "%destination%\!dossier!" && call :fonction "%%~A"
		)
	) 
)
 
pause
exit /b 0
 
:fonction
 
set "fichier=%~dp1"
 
echo.!fichier! | find "%archivage%" >nul || (
	set "archive=!fichier:%source%=%archivage%!"
	echo.
	xcopy /Y %1 "!archive!"
)
 
goto :eof

**GADENSEB** · 30/03/2020, 13h43

Hello
Je te remercie.
Je regarde cela dés ce soir !

**GADENSEB** · 30/03/2020, 23h54

Hello
Cela semble fonctionner parfaitement.
j'ai juste fait une modif dans le dossier d'archivage.
Je l'ai déplacé du dossier source

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
@echo offsetlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\A  TRIER"
set "archivage=D:\PHOTOS\ADO - ARCHIVAGE"
 
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
if not exist "%archivage%" (mkdir "%archivage%")
 
for /r %%A in (*.*) do (
    for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
         echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (
            set "dossier=%%E"
            set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"
            if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!")
            echo.
            xcopy /Y "%%~A" "%destination%\!dossier!" && call :fonction "%%~A"
        )
    ) 
)
 
pause
exit /b 0
 
:fonction
 
set "fichier=%~dp1"
 
echo.!fichier! | find "%archivage%" >nul || (
    set "archive=!fichier:%source%=%archivage%!"
    echo.
    xcopy /Y %1 "!archive!"
)
 
goto :eof

Question en plus :
Je serais intéressé de reprendre le mm code mais sans la notion d'archivage....
quelles lignes dois-je supprimer ?
autant dans un code VBA excel, je vois, mais la je suis débutant
Je dirais

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
@echo offsetlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
 
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
 
 
for /r %%A in (*.*) do (
    for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
         echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (
            set "dossier=%%E"
            set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"
            if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!")
            echo.
            xcopy /Y "%%~A" "%destination%\!dossier!"        )
    ) 
)
 
pause
exit /b 0
  goto :eof

C'est bien cela ?

Autre complément les fichiers ne semblent pas avoir été supprimés de la source après déplacement/création de dossier/archivage.
ya til un code à rajouter ? aussi pour le code en Version sans archivage ?

**barnabe0057** · 31/03/2020, 13h41

Salut, merci bonne journée également.

Voilà le code sans l'archivage et avec le déplacement des fichiers au lieu de la copie :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
@echo off
setlocal enabledelayedexpansion
chcp 28591 >nul
 
set "source=D:\PHOTOS\ADO - SAUVEGARDE TELEPHONE"
set "destination=D:\PHOTOS\SGA  -  A  TRIER"
 
cd /d %source% || exit /b 1
 
if not exist "%destination%" (mkdir "%destination%")
 
for /r %%A in (*.*) do (
	for /f "tokens=2 delims=_-" %%E in ("%%~nA") do (
 		echo.%%E | findstr /R "[0-9][0-9][0-9][0-9][0-9][0-9]" >nul && (
			set "dossier=%%E"
			set "dossier=!dossier:~0,4! !dossier:~4,2! !dossier:~6,2!"
			if not exist "%destination%\!dossier!" (mkdir "%destination%\!dossier!")
			echo.
			move /Y "%%~A" "%destination%\!dossier!"
		)
	) 
)
 
pause
exit /b 0

**GADENSEB** · 31/03/2020, 14h03

hello
Merci à toi
Je regarde dans la journée

**GADENSEB** · 01/04/2020, 09h30

Hello
J'ai testé hier soir et ca marche super bien !!!
good job

Dans le code avec l'archivage, est-ce que l'on pourrait inclure le déplacement (suppression) des fichiers après archivage ?
Pour résumer dans ce code :
- On copie
- On archive
- on supprime

J e n'ai peut être pas les bons mots !

Merci à toi

Script de déplacement de fichier et archivage [Batch]

Scripts/Batch

Discussions similaires

Partager

Partager