Créer un script bat pour télécharger et installation automatique

**xunil2003** · 19/01/2017, 12h37

Bonjour,

J'ai besoin de réaliser un script bat pour Windows 7, afin d'effectuer une installation automatique de python.
Le script doit télécharger et installer python 2.7.6.
Pouvez-vous me donner un exemple.

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
@Echo off
 
Echo Création d'un dossier provisoire pour le téléchargement 
c:/
md Téléchargement
 
Echo Téléchargement de python 2.7.6
......
 
Echo Installation de python 2.7.6
c:\Téléchargement\fichier-python-2-7-6.exe (?????)
 
Echo Suppression du dossier Téléchargement
rd c:/Téléchargement

Je ne sais pas :
- Quel commande utiliser pour télécharger le fichier depuis une url .
- Comment exécuter le fichier

Merci.

**hackoofr** · 20/01/2017, 02h59

Est-ce-que votre URL est : https://www.python.org/ftp/python/2.7.6/python-2.7.6.msi
pour la version 2.7.6

ou bien pour la version 2.7.8 ==> https://www.python.org/ftp/python/2....thon-2.7.8.msi

Vous pouvez aussi voir ceci pour avoir d'autres idées

**xunil2003** · 20/01/2017, 13h18

Bonjour,

L'url est ceci :
Est-ce-que votre URL est : https://www.python.org/ftp/python/2....thon-2.7.6.msi
pour la version 2.7.6

Mais comment lui dire de télécharger le fichier à l'url ?

Merci

**hackoofr** · 21/01/2017, 09h59

Tester ce

Code BAT :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
@echo off
Title Downloading python-2.7.6.msi ...
Mode con cols=80 lines=3 & color 9E
Set "URL=https://www.python.org/ftp/python/2.7.6/python-2.7.6.msi"
Rem on crée un dossier "MyDownload" dans le dossier temporaire
set "MyDownload_Folder=%temp%\MyDownload"
If Not Exist "%MyDownload_Folder%" MD "%MyDownload_Folder%"
Set "Setup_File=%MyDownload_Folder%\python-2.7.6.msi"
Set "Log=%~dp0Log_Setup_Python-2.7.6.log"
echo(
echo     Please wait a while ! downloading "python-2.7.6.msi" is in progress ...
Rem Téléchargement du produit python-2.7.6.msi dans le dossier temporaire
Call :Download "%URL%" "%Setup_File%"
cls
Color 9A 
Title Installing "python-2.7.6.msi" is in progress ...
echo(
echo                 Installing "python-2.7.6.msi" is in progress ...
Rem Installation silencieuse de notre produit python-2.7.6.msi avec un fichier Log d'installation
Call :Install_Silently %Setup_File% %Log%
Rem On supprime totalement notre dossier du téléchargement
Call :Clean %MyDownload_Folder%
Exit
::*********************************************************************************
:Download <url> <File>
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::*********************************************************************************
:Install_Silently <Setup_File> <Log>
msiexec.exe /i "%~1" /qn /L "%~2"
exit /b
::*********************************************************************************
:Clean <Folder_Setup>
RD "%~1" /S /Q >nul
::*********************************************************************************

**hackoofr** · 25/01/2017, 14h40

Voici un autre exemple que je viens d'écrire c'est un script batch pour télécharger l'outil de VirusTotal Uploader pour uploader et scanner les fichiers suspects. l'installation est silencieuse

Code BAT :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
@echo off
Color 9B & Mode con cols=90 lines=5
Title "%~nx0" for Multi-files VirusTotal Uploader by Hackoo 2017
:::::::::::::::::::::::::::::::::::::::::
:: Automatically check & get admin rights
:::::::::::::::::::::::::::::::::::::::::
Set TmpLogFile=%tmp%\TmpLog.txt
If Exist %TmpLogFile% Del %TmpLogFile%
REM  --> Check for permissions
Reg query "HKU\S-1-5-19\Environment" >%TmpLogFile% 2>&1
REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
Echo.
ECHO                      **************************************
ECHO                       Running Admin shell... Please wait...
ECHO                      **************************************
 
    goto UACPrompt
) else ( goto gotAdmin )
 
:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params = %*:"=""
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"
 
    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B
 
:gotAdmin
::::::::::::::::::::::::::::
::START
::::::::::::::::::::::::::::
Title "%~nx0" for Multi-files VirusTotal Uploader by Hackoo 2017
:Main
Mode con cols=90 lines=3 & color 9E
Set "VirusTotalUploaderTool=%ProgramFiles%\VirusTotalUploader2\VirusTotalUploader2.2.exe"
If Not Exist "%VirusTotalUploaderTool%" ( Call:Downloading )
Set "Files_List2Upload=%~dp0ListFiles.txt"
echo(
echo           Creating a list of all *.exe files located on your temporary folder ...
Timeout /t 4 /NoBreak>nul
Dir /b /s /A:-D  "%Temp%\*.exe" > "%Files_List2Upload%"
If Not Exist "%Files_List2Upload%" ( Goto :Error )
For /f "delims=" %%f in ('Type "%Files_List2Upload%"') Do (
    Call:Upload2VirusTotal "%%~f"
)
Taskkill /im "VirusTotalUploader2.2.exe" /f >nul 2>&1
Exit
::*********************************************************************************
:Upload2VirusTotal <File>
Title "%~nx0" for Multi-files VirusTotal Uploader by Hackoo 2017
Cls
Set "File2Upload=%~1"
echo(
echo     Please wait a while ! Uploading file "%~nx1" to VirusTotal is in progress ...
Start "" "%VirusTotalUploaderTool%" "%File2Upload%"
Timeout /t 10 /nobreak>nul
exit /b
::*********************************************************************************
:Downloading
Title Downloading VirusTotal Uploader Tool v2.2 by Hackoo 2017
Set "URL=https://www.virustotal.com/static/bin/vtuploader2.2.exe"
Rem Create "MyDownload" folder in the temporary folder
set "MyDownload_Folder=%temp%\MyDownload"
If Not Exist "%MyDownload_Folder%" MD "%MyDownload_Folder%"
Set "Setup_File=%MyDownload_Folder%\vtuploader2.2.exe"
echo(
echo       Please wait a while ! downloading "vtuploader2.2.exe" is in progress ...
Rem Downloading vtuploader2.2.exe to the temporary folder
Call :Download "%URL%" "%Setup_File%"
cls
Color 9A 
Title Installing "vtuploader2.2.exe" is in progress ...
echo(
echo                 Installing "vtuploader2.2.exe" is in progress ...
Rem Silent installation of vtuploader2.2.exe the uploading tool
Call :Install_Silently %Setup_File% 
Rem Removing the download folder
Call :Clean %MyDownload_Folder%
Goto Main
::*********************************************************************************
:Download <url> <File>
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::*********************************************************************************
:Install_Silently <Setup_File>
"%~1" /S
exit /b
::*********************************************************************************
:Clean <Folder_Setup>
RD "%~1" /S /Q >nul
exit /b
::*********************************************************************************
:Error
cls & Color 4C
echo(
echo   The file "%Files_List2Upload%" dos not exist !
Pause>nul
exit /b
::*********************************************************************************

**zitoune31** · 13/09/2017, 22h35

Envoyé par hackoofr

Tester ce

Code BAT :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
@echo off
Title Downloading python-2.7.6.msi ...
Mode con cols=80 lines=3 & color 9E
Set "URL=https://www.python.org/ftp/python/2.7.6/python-2.7.6.msi"
Rem on crée un dossier "MyDownload" dans le dossier temporaire
set "MyDownload_Folder=%temp%\MyDownload"
If Not Exist "%MyDownload_Folder%" MD "%MyDownload_Folder%"
Set "Setup_File=%MyDownload_Folder%\python-2.7.6.msi"
Set "Log=%~dp0Log_Setup_Python-2.7.6.log"
echo(
echo     Please wait a while ! downloading "python-2.7.6.msi" is in progress ...
Rem Téléchargement du produit python-2.7.6.msi dans le dossier temporaire
Call :Download "%URL%" "%Setup_File%"
cls
Color 9A 
Title Installing "python-2.7.6.msi" is in progress ...
echo(
echo                 Installing "python-2.7.6.msi" is in progress ...
Rem Installation silencieuse de notre produit python-2.7.6.msi avec un fichier Log d'installation
Call :Install_Silently %Setup_File% %Log%
Rem On supprime totalement notre dossier du téléchargement
Call :Clean %MyDownload_Folder%
Exit
::*********************************************************************************
:Download <url> <File>
Powershell.exe -command "(New-Object System.Net.WebClient).DownloadFile('%1','%2')"
exit /b
::*********************************************************************************
:Install_Silently <Setup_File> <Log>
msiexec.exe /i "%~1" /qn /L "%~2"
exit /b
::*********************************************************************************
:Clean <Folder_Setup>
RD "%~1" /S /Q >nul
::*********************************************************************************

Salut désoler de ressortir ce poste datant de début d'année mais, grand merci à toi pour ce merveilleux code, je suis en train de tenter de faire un script d'installation de Python, Ruby avec certaines autres dépendance j'ai commencer a vouloir utiliser wget qui après quelque recherche ma renvoyer vers curl car je rencontrait des erreurs surement du au httpS car en http sa se déroulait bien et en cherchant un simple .bat pour faire le téléchargement de curl en évitant le simple start [url] je suis tomber sur ta merveille qui va me donner envie de me pencher sur Powershell ^^ . Difficile de toujours bien comprendre les scripts mais je trouve çà trop beau et je kiff bien perdre mon temps à tester tout pleins de chose pour les accommoder à e que je suis pas capable de créer tout seul ^^ bref Merci pour le script et je regarderai si pour le virus scan il est également toujours d'actualité sa peu être intéressant .

**hackoofr** · 14/09/2017, 08h52

Voici un script tout récent pour télécharger et installer la dernière version de Adobe Flash Player

Quelqu'un d'entre vous peut rencontrer une telle erreur ou bien il l'a déjà rencontré (une connexion échouée ou une erreur d'initialisation de l'application) alors qu'il veut installer le lecteur flash à partir de son installateur en ligne, cela m'arrivé plusieurs fois et il m'a énervé, alors j'ai décidé de créer un fichier batch pour corriger de telles erreurs en téléchargeant le désinstalleur et désinstaller toute version précédente et télécharger la dernière version Adobe Flash Player avec une installation complète (installateurs hors ligne) et installer-le silencieusement et en arrière-plan.

Download_Install_Latest_Adobe_Flash_Player

**zitoune31** · 14/09/2017, 11h38

Envoyé par hackoofr

Voici un script tout récent pour télécharger et installer la dernière version de Adobe Flash Player

Merci du partage

Un peu plus complexe ( long ) à priori a décrypter par rapport aux précédent script sur lequel je vais commencer par me concentrer ^^

Je ne suis pas familier avec les type de commande

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

%~dp0 / ('%1','%2') / "%~1" / "%~2"

j'ai commencer hier à faire quelque recherche pour bien les assimiler je vais continuer sur cette voix car je voix en gros mais c'est pas réellement très clair mais si je ne me trompe pas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
%~dp0  répertoire d'où à été lancer le script
%1 fait référence au programme
%2 fait référence au fichier log

D'autre part si j'ai bien compris exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

:Clean <Folder_Setup>

ce qui ce situe entre les <> le nom à pas réel importance sa pourrai en revenir à un "commentaire" rem ?

J'en viens à cette conclusion du faite que <Folder_Setup> ne fait référence à aucune déclaration précédente.

**newtonne** · 28/02/2020, 00h47

Bonjour,

J'aurais une petite question concernant le téléchargement d'un logiciel pour éviter de modifier à chaque fois le scripte lorsqu'une nouvelle version sort.
prenons l'exemple pour le logiciel "python-2.7.6.msi", puis "python-2.7.8.msi", etc...
Existe-t-il une commande pour qu'il prenne en compte le téléchargement sans avoir besoin de taper la version du/de la (future) version du logiciel:
exemple = Set "URL=http://....../python*.msi"
En gros, par quoi, peut-on remplacer (commande) l' * , pour que le téléchargement se fasse.
Un grand Merci

Créer un script bat pour télécharger et installation automatique

Scripts/Batch

Discussions similaires

Partager

Partager