Discussion :

[Devnbi]

Bonjour à tous,

Je voudrais rajouter une condition au script ci-dessous pour qu'il vérifie si le dossier de destination, en plus d'exister, est bien accessible en lecture/écriture avant de démarrer la copie des données.

Voici mon code :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
 
set BackupDest=D:\backup
 
for /f "tokens=*" %%I in ('dir /a:d-h /b "%HomeDrive%\users\*" ^| findstr /b /e /i /l /v /g:"%~dp0exclude_users.txt"') do if exist "%BackupDest%\%%~nI\" (
 
echo -----------------------------------------
echo      Sauvegarde du profil : %%~nXI
echo -----------------------------------------
echo
 
xcopy "%%~nXI\Desktop" "%BackupDest%\%%~nXI\Desktop\" /e /i /y
xcopy "%%~nXI\Documents" "%BackupDest%\%%~nXI\Documents\" /e /i /y
 
)
 
pause
exit

Existe-t-il un moyen simple de faire cela en essayant de conserver le code actuel dans la mesure du possible ?

Merci d'avance pour votre précieuse aide.

[barnabe0057]

Bonjour,

Tu peux vérifier les permissions avec la commande ICACLS, voilà ce que ça pourrait donner :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

for /f "tokens=1,2 delims=:" %%A in ('icacls %BackupDest% ^| find "%USERNAME%"') do echo %%B | findstr "F M" && echo Droits de lecture-écriture : OK"

[Devnbi]

Comment puis-je intégrer cela dans mon script et faire en sorte que si des dossiers ne sont pas accessible en lecture+écriture, afficher un message ?

[barnabe0057]

Le script est à exécuter avec le clic-droit (exécuter en tant qu'administrateur) :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
chcp 28591 >nul
 
set BackupDest=D:\backup
set "exclude=Default Administrateur Public Users"
 
cd /d %HomeDrive%\Users || exit /b 1
 
for /f "delims=" %%I in ('2^>nul dir /ad /b ^| findstr /i /v "%exclude%"') do (
 
	set backup=0
	if exist "%BackupDest%\%%~I" (
 
		for /f "tokens=1,2,* delims=:\" %%A in ('2^>nul icacls "%BackupDest%\%%~I" ^| find /i "%COMPUTERNAME%"') do (
 
			if /i "%%B"=="%USERNAME%" (echo %%C | findstr "F M" >nul && call :sauvegarde "%%~I")
		)
 
	if !backup! NEQ 1 (call :permission "%%~I")
 
	)
 
)
 
echo. & pause
exit /b 0
 
rem
 
:sauvegarde
 
echo.
echo -----------------------------------------
echo      Sauvegarde du profil : %~1
echo -----------------------------------------
echo.
 
xcopy "%~1\Desktop" "%BackupDest%\%~1\Desktop\" /e /i /y
xcopy "%~1\Documents" "%BackupDest%\%~1\Documents\" /e /i /y
 
set backup=1
 
goto :eof
 
rem
 
:permission
 
echo. & echo ##### L'utilisateur actuel [%USERNAME%] ne possède pas de permission sur le dossier "%BackupDest%\%~1"
echo. & echo ##### Continuer la sauvegarde ?
echo. & pause
 
call :sauvegarde "%~1"
 
goto :eof