Discussion :

[horemheb]

Bonjour,
Je souhaite programmer des commentaires. Pour cela j'ai créé une macro pour récupérer les instructions correspondantes.
- Je pars d'une cellule sans commentaire (B2)
- Clic droit Insérer un commentaire
- Effacement du commentaire par défaut, frappe du nouveau commentaire "Toto"
- Redimensionnement de la fenêtre.
Ce qui donne la macro suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Range("B2").Select
Range("B2").AddComment
Range("B2").Comment.Visible = False
Range("B2").Comment.Text Text:="Toto"
Selection.ShapeRange.ScaleWidth 0.37, msoFalse, msoScaleFromTopLeft
Selection.ShapeRange.ScaleHeight 0.3, msoFalse, msoScaleFromTopLeft
Range("B4").Select

Quand j'exécute cette macro ça fonctionne, sauf pour le redimensionnement de la fenêtre (les 2 instructions Selection.ShapeRange. . . .) qui m'affiche un message d'erreur : Propriété ou méthode non gérée par cet objet.

Comment dois-procéder pour redimensionner la fenêtre du commentaire ?
Merci

[Patrice740]

Bonjour,

Utiliser .Select est déconseillé en VBA (et donc Selection aussi).

Essaies ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Option Explicit
Sub Test()
Dim c As Range
  Set c = Worksheets("Feuil1").Range("B2")
  With c
    .ClearComments
    .AddComment
    With .Comment
      .Visible = False
      .Text Text:="Toto"
      With .Shape
        .Width = 32.25
        .Height = 21.75
      End With
    End With
  End With
End Sub

Pour l'essayer tu peux faire un copier / coller dans un module standard,
Mais je te conseille vivement de le saisir manuellement, tu comprendra l’intérêt de l'autocomplétion en particulier quand tu commence par définir l'objet du délit (dans ce cas la cellule c qui recevra le commentaire).

[horemheb]

Merci Patrice740
Ça répond à ma question.

Mais tu m'as intrigué en précisant que le .Select est déconseillé. Pourquoi ?

Merci

[Patrice740]

Mais tu m'as intrigué en précisant que le .Select est déconseillé. Pourquoi ?

Parce qu'il est inutile de sélectionner un objet (cellule, feuille, forme, etc...) pour agir dessus.
C'est pas à proprement dit .Select qui pose problème mais ce qui en découle : l'utilisation des objets actifs (Selection, ActiveCell, ActiveSheet, ....) au lieu d'objets clairement définis.
C'est la cause de nombreux et fréquents problèmes (comme celui qui t'a amené à ouvrir ce fil), car on pense agir sur un objet et c'est un autre qui est actif.
Il est toujours préférable de définir explicitement l'objet sur lequel on veut agir.
Dans l'exemple du code précédent, on agit sur :
- la cellule c

- le commentaire qu'on vient d'y ajouter

- la visibilité du commentaire
- son texte
- sa forme

- la largeur de la forme
- sa hauteur

Sans jamais sélectionner quoi que ce soit.

[horemheb]

Merci pour vos conseils
Joyeuses fêtes de fin d'année

[OrDonc]

Bonsoir...

...
Comment dois-procéder pour redimensionner la fenêtre du commentaire ?

En une seule instruction pour éviter la recherche approximative des dimensions :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

LaCellule.Comment.Shape.TextFrame.AutoSize = 1

C’est un redimensionnement ponctuel : chaque commentaire ajouté ou changé sera dimensionné en fonction du texte, multilignes comprises.

C'est l'abus (comme de toute chose) de son utilisation qu'il faut essayer d'éviter (ici, écriture plus lourde, durée d'exécution augmentée ...)