Discussion :

[Gex-88]

Bonjour,

Je débute sur Excel aussi bien qu'en Visual basic mais je cherche à extraire les données de plusieurs lignes d'un tableau sur une autre feuille.

J'ai un tableau à 4 colonnes avec respectivement : des marques de voitures, leurs modèles, la ville et leurs plaques d'immatriculation.
En passant par une macro VBA, mon but est de récupérer toutes les Peugeot et Citroën immatriculées dans le 05. Je veux donc que sur ma feuille 2, ma première colonne soit la marque du véhicule et la deuxième sa plaque d'immatriculation (uniquement en 05).
L'idéal pour moi serait de créer une condition de recherche sur la colonne "Marque" pour identifier les "Peugeot" et "Citroën" et de les afficher dans une nouvelle feuille avec uniquement la colonne plaque d’immatriculation associée (mais imposer une recherche sur le critère "05" de cette colonne).
Pour finir, l'autre difficulté que j'ai et que ma macro doit être adaptable à n'importe quel tableau de n'importe quelle taille (il n'y aurait que les noms de colonnes identiques).

Est-ce possible et si oui, quelqu'un aurait-il une solution pour m'aider ?

En vous remerciant par avance.

PS : - Vous trouverez en pièce jointe un fichier avec le tableau en question.
- J'ai adapté mon tableau pour le forum mais ce sur quoi je travaille est bien plus complexe. C'est pour ça qu'il faudrait que je passe obligatoirement par une macro avec appui sur un bouton pour transférer automatiquement les infos qui m’intéresse sur une autre feuille (avoir une syntaxe VBA que je pourrais adapter).

[EricDgn]

Bonjour,

Voici un début de solution en considérant que les données de base sont dans un tableau dynamique nommé 'Tableau1' et que divers boutons exécutent les filtrages avant de recopier cela. Pour faire le filtre par département, une colonne supplémentaire a été ajoutée, colonne qui contient le n° du département.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Option Explicit
 
Sub Supprim_filtre()
   ActiveSheet.ListObjects("Tableau1").Range.AutoFilter
End Sub
 
Sub Filtre_05()
    ActiveSheet.ListObjects("Tableau1").Range.AutoFilter Field:=5, Criteria1:="5"
End Sub
 
Sub Filtre_Peugeot()
    ActiveSheet.ListObjects("Tableau1").Range.AutoFilter Field:=1, Criteria1:="Peugeot"
End Sub
 
Sub Filtre_Citroën()
    ActiveSheet.ListObjects("Tableau1").Range.AutoFilter Field:=1, Criteria1:="Citroën"
End Sub
 
Sub Copier()
   Dim sMarque As String, wsMarque As Worksheet, tMarque As ListObject
   With Range("Tableau1")
      sMarque = Range("A" & .Offset(1, 0).SpecialCells(xlCellTypeVisible)(1).Row).Value
   End With
   If sMarque = "" Then
      MsgBox "Pas de marque !", , "Anomalie"
      Exit Sub
   End If
   Set tMarque = Sheets("Tout").ListObjects("Tableau1")
   On Error Resume Next
   Sheets(sMarque).Select
   If Err.Number > 0 Then
      Err.Clear
      If MsgBox("Créer une feuille pour " & sMarque & "?", vbYesNo, "Nouvelle feuille ?") = vbNo Then
         Exit Sub
      Else
         Set wsMarque = Sheets.Add(After:=Sheets(Sheets.Count))
         wsMarque.Name = sMarque
      End If
   End If
   On Error GoTo 0
   Sheets(sMarque).Cells.Clear
   tMarque.Range.SpecialCells(xlCellTypeVisible).Copy Destination:=Sheets(sMarque).Range("A1")
   Range("A1").Select
End Sub

Bonne continuation.

[Gex-88]

Bonjour EricDgn et merci de ta réponse.

Comment fonctionne la ligne suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.ListObjects("Tableau1").Range.AutoFilter Field:=5, Criteria1:="5"

A quoi correspond le champ "Field" et comment savoir quelle valeur lui assigner ?

Merci d'avance pour la réponse.

[EricDgn]

Field:=5 ... cela concerne la 5e colonne du tableau, càd le Département
Criteria:="5" ... 5 est la valeur recherchée (le département étant converti en nombre, 05 est devenu 5)

Cordialement.

[Gex-88]

Super, merci de ta réponse.