Discussion :

[aiglelibre]

Bonjour

Je souhaite faire un .bat avec la commande sqlcmd qui doit exécuter tous les fichiers .sql dans un répertoire
Avez-vous des exemples SVP ?

Merci par avance
Aigle

[Invité]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
set instance=MonInstanceDeProd
set SelectedDatabase="DatabaseName"
 
set CurrentFileNameWithoutExtension=%~n0
set LogFile="%CurrentFileNameWithoutExtension%.log"
 
echo .>> %LogFile% 2>&1
echo *************************************************************************************>> %LogFile% 2>&1
echo ************* START -- %CurrentFileNameWithoutExtension%.BAT *********************>> %LogFile% 2>&1
echo *************************************************************************************>> %LogFile% 2>&1
echo .>> %LogFile% 2>&1
echo ******* %date% - %time% *******>> %LogFile% 2>&1
 
set SousRepertoire=step1
FOR /f %%i IN ('DIR %SousRepertoire%\*.sql /b ^| sort') do call :RunScript %%i
 
set SousRepertoire=step2
FOR /f %%i IN ('DIR %SousRepertoire%\*.sql /b ^| sort') do call :RunScript %%i
 
set SousRepertoire=step3
FOR /f %%i IN ('DIR %SousRepertoire%\*.sql /b ^| sort') do call :RunScript %%i
 
echo ******* %date% - %time% *******>> %LogFile% 2>&1
echo .>> %LogFile% 2>&1
echo *************************************************************************************>> %LogFile% 2>&1
echo ************* END -- %CurrentFileNameWithoutExtension%.BAT *********************>> %LogFile% 2>&1
echo *************************************************************************************>> %LogFile% 2>&1
echo .>> %LogFile% 2>&1
 
GOTO :END
 
 
:RunScript
 
echo ******* %SousRepertoire%\%1 = %date% - %time% *******>> %LogFile% 2>&1
sqlcmd -S %Instance% -d %SelectedDatabase% -i %SousRepertoire%\%1 >> %LogFile% 2>&1
 
:END

[aiglelibre]

Merci beaucoup