Discussion :

[Eric_MGN]

Bonjour à tous
je me suis lancé dans le batch pensant que la chose serait "simple", mais ce n'est visiblement pas le cas.
Mon but :
dans le cadre professionnel nous avons un logiciel (CAO) qui nous génère x sous-répertoires, puis il place dans chacun de ces sous-répertoires y fichiers qui ont le même nom pour chaque sous-répertoire ... Impossible de rapatrier tous les fichiers au même endroit sans perdre des fichiers donc !
Note 1 : le nombre de sous-répertoire x est variable et leur nom n'a pas de format "standard"
Note 2 : le nombre de fichiers y ainsi que leur nom est variable en fonction des options choisies dans le logiciel de CAO

L'idée est donc de copier dans le répertoire racine les fichiers des sous-répertoires en les renommant " 'nom sous-répertoire'_'nom fichier d'origine' "

J'ai réalisé le code suivant, mais ma problématique est d'arriver à mettre dans la variable 'prefix' le nom du sous-répertoire.
Sinon le reste marche
J'ai essayé pas mal de chose avec les expansions retardées, avec les caractères d'échappement, mais là franchement, cela fait 2 jours que je sèche
Je pense que le loup est autour de set PREFIX=%PREFIX:%cd%\\=% mais .... où ?

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
cls
::@echo off
 
 
setlocal enabledelayedexpansion
 
for /d %%r in ("%cd%\*") do (
	::ligne suivante pour debug
	echo ### main ### %%r
	call :listFic %%r
	::ligne suivante   supprimmer echo en fin de debug
	echo rd /S /Q %%r 
)
 
endlocal
 
echo.
pause
exit /b
 
 
 
::---------------------------- procedure qui boucle sur un repertoire ------------
:listFic
::ligne suivante pour debug
echo func0 %~1
for /r "%~1" %%f in ("*.*") do (
	:: but : mettre dans prefix la chaine de carateres : %1 (chemin complet du fichier) dans laquelle la chaine %cd% a ete supprimee
	set "PREFIX=%~1"
	::ligne suivante pour debug
	echo func1 %PREFIX%
	set PREFIX=%PREFIX:%cd%\\=%
	::ligne suivante pour debug
	echo func2 %PREFIX%
	::ligne suivante pour debug : a supprimer, actuellement pour test fonction copy
	set prefix=dos1
	::ligne suivante   supprimmer echo en fin de debug
	echo copy /Y %~1\%%~nf%%~xf %cd%\%prefix%_%%~nf%%~xf
)
goto :eof

Merci d'avance pour votre aide

Maintenant si quelqu'un pense qu'en Powershell c'est plus simple (voire plus pérenne dans le temps ?) je suis preneur aussi, tous nos postes étant en win 7 ou win X. Mais de ce coté je ne connais rien !

Eric_MGN

[ericlm128]

Je te propose ceci

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
@echo off
cls
 
set dossier=%~dp0
for /f "usebackq delims=" %%a in (`dir /ad /b "%dossier%*"`) do (
	for /f "usebackq delims=" %%b in (`dir /a-d "%dossier%%%~a" /b`) do MOVE "%dossier%%%~a\%%~b" "%dossier%%%~a_%%~b" >nul
	RD "%dossier%%%~a" /Q
)
 
pause

Ps : j'ai volontairement retiré le /S au RD, puisque après déplacement+renommage les dossiers doivent être vide

[Eric_MGN]

bonsoir ericlm128,
Je n'ai qu'une seule réponse : Merci, c'est une tuerie le truc, et en plus super rapidement répondu !
Et vachement plus concis que ce que j'avais fait.
Y a du niveau là ! J'en suis très loin

Il va falloir que je reprenne les tutos du site pour comprendre les fonctions utilisées.
Parce que j'aime bien comprendre, même quand on me l’amène tout cuit comme là!

J'ai testé sur un bout de répertoire local, çà marche nickel, demain je testerais "grandeur nature"
éventuellement avec quelques évolutions pour supprimer qq caractères inutiles des fichiers générés par la CAO.
Mais à la maison je n'ai pas assez de débit adsl (0.6mbits/s ) pour pouvoir le faire.

encore :

Pour le /S du RD, c'est normal puisque vide !

Eric_MGN

[Eric_MGN]

Bonjour ericlm128,
Bon je crois que j'ai tout compris avec l'aide des tutos du forum
Mais je pense que je n'aurais pas réussi à le sortir sans votre aide.
Pourtant je fais régulièrement du VBA Excel pour le boulot (et j'utilise pas mal les résultats de votre forum pour cela. Que tous ceux qui y participent en soient remercié ici.).
Mais la philosophie me semble différente de la programmation que l'on retrouve sur les langages "évolués"
J'aurais sûrement pu le faire depuis une macro Excel, mais cela me paraissait plus intuitif pour l'utilisateur via un batch

Il me reste cependant 2 questions sur le code fourni par ericlm128 :
- 1) Pourquoi la redirection vers nul >nul à la fin du move ?
- 2) Quand j'ai inséré mes commentaires (pour pouvoir dépanner plus tard si besoin) j'ai eu des erreurs en fonction de la position des commentaires. Avez-vous des explications ?
par exemple si je fais

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
		MOVE /Y "%dossier%%%~a\%%~b" "%dossier%%%~a%Separ%!NomFic!%%~xb" >nul
		:: ajout du /y si on refait la manip plusieurs fois sans avoir supprime les fichiers, pourquoi la redirection de sortie du move vers nul
	)
	echo ------------------------------------------------------------------------

au lieu de

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
		MOVE /Y "%dossier%%%~a\%%~b" "%dossier%%%~a%Separ%!NomFic!%%~xb" >nul
	)
		:: ajout du /y si on refait la manip plusieurs fois sans avoir supprime les fichiers, pourquoi la redirection de sortie du move vers nul
	echo ------------------------------------------------------------------------

j'ai un retour ") était inattendu." et le script se termine

Ci-dessous le code final qui semble convenir à mes collègues avec :
- les commentaires correspondant à ma compréhension du code
- la customisation annoncée
- la cosmétique pour l'utilisateur
Concernant ce dernier point, je note les pièges de compatibilité entre les commandes ECHO contenant des ! et l'option setlocal enabledelayedexpansion

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
@echo off
chcp 850
:: defini le type de page de caracteres utilisee, ici OEM850 ou CP-850
cls
::efface l affichage
color 4F
:: afiichage en blanc brillant sur rouge
 
::defini le separateur a mettre entre le nom de repertoire et le nom de fichier
set "Separ="
 
echo       ^^
echo      / \
echo     / ! \              IMPORTANT
echo    /_____\
echo.
echo Pour fonctionner correctement, ce fichier doit être placé et exécuté
echo depuis le répertoire où sont situés les fichiers SEE sources
echo.
echo        ^^
echo       /^^\
echo      // \\
echo     // ! \\            ATTENION
echo    //_____\\
echo   /---------\
echo.
echo Tous les fichiers dans les sous-répertoires seront supprimés,
echo ainsi que les sous-répertoires, y compris ceux sans rapport avec SEEBATCH
echo.
set /p "Traiter=Souhaitez-vous continuer [O/N] : "
 
color 07
::affichage en blanc sur noir (affichage standard)
 
if /i "%traiter%" NEQ "O" goto :nontrait
echo ========================================================================
echo === debut de traitement pour renommer les fichiers issus de SEEBATCH ===
echo ========================================================================
echo.
 
setlocal enabledelayedexpansion
:: permet l'expansion retardee des variable mais interdit l'utilisation des points d'exclamation dans les commandes echo
 
set dossier=%~dp0
:: renvoi la lettre "~d" et le chemin "~p" du parametre 0 du module en cours d execution (0 est le nom du script)    equivalent a dossier=%cd%\
 
for /f "usebackq delims=" %%a in (`dir /ad /b "%dossier%*"`) do (
::balaye tous les sous repertoires dans le repertoire courant, le nom du sous repertoire est dans %%a
	echo ========================================================================
	echo === dossier en cours : %dossier%%%~a
	echo === dossier en cours : %%~a
	echo ------------------------------------------------------------------------
	for /f "usebackq delims=" %%b in (`dir /a-d "%dossier%%%~a\*.xl*" /b`) do (
	:: balaye tous les fichiers de type different de repertoire,  ajout de \*.xl* apres %%~a permet de ne traiter que les excel
		set NomFic=%%~nb
		:: renvoi "~n" le nom du fichier sans l'extention
		set Nomfic=!NomFic:~0,-5!
		:: pour supprimer la partie "_0001" à la fin du nom de chaque fichier
		echo ---    Fichier   %%~a\%%~b   ---^>   %%~a%Separ%!NomFic!%%~xb
		:: renvoi "~x" l extention du fichier inclus le point
		echo MOVE /Y "%dossier%%%~a\%%~b" "%dossier%%%~a%Separ%!NomFic!%%~xb" >nul
	)
		:: ajout du /y si on refait la manip plusieurs fois sans avoir supprime les fichiers, pourquoi la redirection de sortie du move vers nul
	echo ------------------------------------------------------------------------
	echo === suppression dossier "%%~a" en cours
	echo RD "%dossier%%%~a" /Q /S
	:: ajout du /S si d autres fichiers non traites sont dans le repertoire type thumbnail
	echo ========================================================================
	echo.
)
endlocal
 
echo ========================================================================
echo ==== fin de traitement pour renommer les fichiers issus de SEEBATCH ====
echo ========================================================================
echo.
goto :fin
 
:nontrait
echo.
echo !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
echo !!!   traitement non effectué   !!!
echo !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
echo.
 
:fin
pause
 
exit /b

Encore

Eric_MGN

[morback]

bonjour pout tes commentaires tu dois mettre
REM en debut de ligne

essaye déjà ca


REM ---- Commentaire
REM : Commentaire
REM # Commentaire
REM Commentaire

Cordialement

[morback]

Au temps pour moi le :: semble fonctionné

peux tu préciser quels commentaires tu as ajouter afin de t'aider au mieux
avec le code autour

[Eric_MGN]

Bonjour morback,
si j'ai tout bien compris il y a une petite nuance entre REM et ::
REM est une remarque qui s'affiche quand echo est à ON, mais :: est un commentaire qui ne s'affiche jamais à l'exécution

J'ai trouvé une solution, mais je voulais comprendre pourquoi par moment un commentaire peut générer des erreurs d’exécution.
J'ai le sentiment que cela peut être lié à l'échappement de certains caractères.

Eric_MGN

[Eric_MGN]

peux tu préciser quels commentaires tu as ajouter afin de t'aider au mieux
avec le code autour

comme indiqué dans mon post il y en a un au niveau d'une parenthèse fermante.
S'il est avant la parenthèse çà plante,
s'il est après çà marche

[ericlm128]

1) Pour éviter les messages : 1 fichier(s) déplacé(s).


2) J'ai fait quelques tests, il serait préférable d'ajouter 2^>nul pour limiter les erreurs à l’affichage (notamment dossier vide)

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

for /f "usebackq delims=" %%a in (`dir /ad /b "%dossier%*" 2^>nul`) do (

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

for /f "usebackq delims=" %%b in (`dir /a-d "%dossier%%%~a" /b 2^>nul`)

Mais ceci ne devrait pas expliquer le ") était inattendu.", je vois que tu joue avec l'affichage et peut être encodage. Vérifie que tu as les "fins de ligne + retour ligne" correcte (\r\n ou CR+LF).
Bref que ton fichier à un encodage cohérent.
Voir aussi exemple du 4)

Je n'ai pas constaté d'erreur avec ce code :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
@echo off
cls
 
set dossier=%~dp0
for /f "usebackq delims=" %%a in (`dir /ad /b "%dossier%*" 2^>nul`) do (
	:: ajout du /y si on refait la manip plusieurs fois sans avoir supprime les fichiers, pourquoi la redirection de sortie du move vers nul
	for /f "usebackq delims=" %%b in (`dir /a-d "%dossier%%%~a" /b 2^>nul`) do echo 1 - "%dossier%%%~a"
	:: ajout du /y si on refait la manip plusieurs fois sans avoir supprime les fichiers, pourquoi la redirection de sortie du move vers nul
	echo 2 - "%dossier%%%~a"
)
:: ajout du /y si on refait la manip plusieurs fois sans avoir supprime les fichiers, pourquoi la redirection de sortie du move vers nul
pause

3)

si j'ai tout bien compris il y a une petite nuance entre REM et ::
REM est une remarque qui s'affiche quand echo est à ON, mais :: est un commentaire qui ne s'affiche jamais à l'exécution

Oui


4)

Mais la philosophie me semble différente de la programmation que l'on retrouve sur les langages "évolués"

Le langage batch est archaïque.
Tu passe beaucoup de temps à débuger des problèmes liés au fonctionnement interne de ce langage.
Exemple : Si tu a un nom de dossier avec des ) il va considérer que c'est la fin de ton for et planter

Je te déconseille de passer trop de temps dessus, tu devrait t’orienter vers le Powershell.

[Eric_MGN]

OK je comprends maintenant la redirection >nul
merci

pour les commentaires je ne sais pas trop, mais je l'avais avant de jouer avec les couleurs ou avec la table de caractères
mais en effet j'ai des parenthèses (ouvrante puis fermante) dans les noms des fichiers qui sont déplacés ...
J'édite avec notepad++ avec les caractères de contrôle affichés donc les crlf sont bien là !

Et grâce à ce que tu m'as fait, j'en ai compris la philosophie et compte-tenu de la façon dont les répertoires sont générés, j'ai traité la première boucle différemment et ajouté un if exist <path> dans la boucle

Çà marche nickel

En effet je ne vais pas passer trop de temps la-dessus car c'est déjà plus ou moins pas officiellement autorisé par la hiérarchie ...
Et en effet je pense que le batch est un peu obsolète.
Mais j'ai fait un peu de dos dans mon vieux temps (début des années 90 au lycée) avec du Turbo Pascal à l'époque, et sur des machines sans disque dur !
Je me sentais donc plus à l'aise avec le batch qu'avec le powershell

Et le peu que j'ai vu en powershell ne me semble pas intuitif du tout à moins d'y passer pas mal de temps (que je n'ai pas) pour tout comprendre.
SI une âme charitable se sens de le traduit je ne dirais évidemment pas non. Mais il ne faut pas abuser non plus. Une formation pro pourrais être sympa mais je rêve là !

Donc merci
Sujet je clôture.

Encore merci à vous pour ce topic, et à developpez pour la mine d'info dont elle regorge.
Eric

[ericlm128]

Pour l'exemple. J'ai placé des -WhatIf pour que les commandes ne s'appliquent pas mais qu'il nous informe de ce qu'il ferait

Code powershell :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
function Fin {
    Write-Host "`nAppuyer sur une Entrer pour quitter"
    Read-Host
    exit
}
 
$scriptPath = split-path -parent $MyInvocation.MyCommand.Definition
 
[console]::ForegroundColor = [consolecolor]::White
[console]::BackgroundColor = [consolecolor]::DarkRed
Clear-Host
 
Write-Host @"
       ^
      / \
     / ! \              IMPORTANT
    /_____\
 
Pour fonctionner correctement, ce fichier doit être placé et exécuté
depuis le répertoire où sont situés les fichiers SEE sources
 
        ^
       /^\
      // \\
     // ! \\            ATTENION
    //_____\\
   /---------\
 
Tous les fichiers dans les sous-répertoires seront supprimés,
ainsi que les sous-répertoires, y compris ceux sans rapport avec SEEBATCH
Dossier ciblé : $scriptPath
 
"@
 
$readkey = Read-Host -Prompt "Souhaitez-vous continuer [O/N]"
 
[console]::ForegroundColor = [consolecolor]::White
[console]::BackgroundColor = [consolecolor]::Black
Clear-Host
 
if ($readkey -ne "o")
{
    Write-Host @"
    !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
    !!!   traitement non effectué   !!!
    !!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
    
 
"@
 
    fin
 
}
 
Write-Host @"
========================================================================
=== debut de traitement pour renommer les fichiers issus de SEEBATCH ===
========================================================================
 
"@
 
 
Get-ChildItem -Path $scriptPath -Directory | ForEach-Object {
    Write-Host @"
========================================================================
	=== dossier en cours : $($_.FullName)
	=== dossier en cours : $($_.Name)
"@
 
    Get-ChildItem -Path "$($_.FullName)\*???.xls*" -File | ForEach-Object {$_ | Move-Item -Destination ($_.Directory.Parent.FullName + "\" + $_.Directory.Name + "_" + $_.BaseName.Substring(0, $_.BaseName.Length -3) + $_.Extension) -WhatIf}
    Write-Host "	=== suppression dossier ""$($_.Name)"" en cours"
    $_ | Remove-Item -Force -Recurse -WhatIf
    Write-Host "========================================================================"
}
 
Write-Host @"
 
========================================================================
==== fin de traitement pour renommer les fichiers issus de SEEBATCH ====
========================================================================
 
"@
 
 
fin

[Eric_MGN]

Bonjour ericlm128
monsieur est bien urbain
Je vais regarder cela pour vivre avec mon temps !
Merci
Eric_mgn