Discussion :

[speedozrx]

Bonjour à vous tous,
Suite à la création d'un batch revu et corrigé par (Ericlm128) ci dessous, j'aimerais peaufiner ce dernier car j'ai été confronté à des users copiant leurs données à la racine de leur profil et sur le c:
Je ne parviens pas à exclure lors de la copie les dossiers présents à la racine du c: via la commande /XD associée à la création du fichier "exclu.txt" présent dans le même répertoire même en lançant un cmd (pour ex :
robocopy "C:\" "F:\123" /E /TS /XD exclu.txt)

Les dossiers à exclure du c:\ + %Profil%

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

"C:\Windows" "C:\Users" "C:\Program Files" "C:\Program Files (x86)" "C:\PerfLogs" "C:\MININT" "C:\Util" "C:\Intel"

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
@echo off
title= ---- Sauvegarde Profile Windows ---- 
color 0A
cls
echo  ****************************************************** 
echo  *********   SAUVEGARDE PROFIL  ********* 
echo  ****************************************************** 
echo  ****** Ne Pas Oubllier de Recuperer le Disque ********** 
echo  ******************************************************  
set /p profil= Bonjour Saisie du Matricule : 
if not exist "C:\Users\%profil%\" goto fin
if "%profil%" == "" goto fin
 
call :saveprofil "c:\Users\%profil%\Desktop" "e:\%profil%\Desktop"
call :saveprofil "c:\Users\%profil%\Favorites" "e:\%profil%\Favorites"
call :saveprofil "c:\Users\%profil%\Music" "e:\%profil%\Music"
call :saveprofil "c:\Users\%profil%\Documents" "e:\%profil%\Documents"
call :saveprofil "c:\Users\%profil%\Pictures" "e:\%profil%\Pictures"
call :saveprofil "c:\Users\%profil%\Downloads" "e:\%profil%\Downloads"
call :saveprofil "c:\Users\%profil%\AppData\Roaming\Microsoft\Signatures" "e:\%profil%\Signatures"
call :saveprofil "c:\Users\%profil%\Videos" "e:\%profil%\Videos"
call :saveprofil "c:\Users\%profil%\AppData\Roaming\Mozilla" "e:\%profil%\Firefox"
call :saveprofil "d:" "e:\%profil%\Disk"
call :saveprofil "c:\Users\%profil%\AppData\Roaming\Microsoft\Windows\Themes" "e:\%profil%\Theme"
 
goto fin
 
:saveprofil
if not exist "%~1" goto :eof
md "%~2"
robocopy "%~1" "%~2" /E /A-:H /COPYALL /DCOPY:T /R:1 /W:1 /ETA 
goto :eof
 
:fin
echo.

Merci à vous !!

[ericlm128]

Je ne suis pas spécialiste de robocopy, mais je dirais comme ceci :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

robocopy "C:\" "F:\123" /E /TS /XD "C:\Windows" "C:\Users" "C:\Program Files" "C:\Program Files (x86)" "C:\PerfLogs" "C:\MININT" "C:\Util" "C:\Intel"

https://pureinfotech.com/exclude-fil...py-windows-10/

[speedozrx]

Je ne suis pas spécialiste de robocopy, mais je dirais comme ceci :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

robocopy "C:\" "F:\123" /E /TS /XD "C:\Windows" "C:\Users" "C:\Program Files" "C:\Program Files (x86)" "C:\PerfLogs" "C:\MININT" "C:\Util" "C:\Intel"

https://pureinfotech.com/exclude-fil...py-windows-10/

Hello ericlm128;
Merci pour ta réponse, j'ai réussi à faire ce que je veux en respectant cette syntaxe car entre temps, j'avais visité ce lien...
La difficulté est d'intégrer cette nouvelle commande dans le batch initial puisque je dois également faire la même chose concernant les éléments copiés à la racine du profil.
C'est largement mieux si tout devait s'exécuter depuis le même batch avec ces 2 ajouts. Merci pour ton intervention

[ericlm128]

Oui pas de problème je te propose quelque chose quand je peux.

[speedozrx]

Oui pas de problème je te propose quelque chose quand je peux.

Ton batch est une petite merveille qui fait très bien le Job, c'est une bonne base, je dois simplement réussir à compiler 2 copies supplémentaires pour qu'elles se fassent toujours à l'intérieur du profil. (utilisateurs bordéliques..)
Je te souhaite un bon week end !!

[ericlm128]

Je te propose ceci, ça te permettra de spécifier les exclusions.

NB : J'ai modifié quelques petites choses comme le set /p

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
@echo off
title= ---- Sauvegarde Profile Windows ----
color 0A
cls
echo ******************************************************
echo ********* SAUVEGARDE PROFIL *********
echo ******************************************************
echo ****** Ne Pas Oublier de Recuperer le Disque **********
echo ******************************************************
set /p "profil=Bonjour Saisie du Matricule : "
if not exist "C:\Users\%profil%\" goto fin
if "%profil%" == "" goto fin
 
call :saveprofil "c:" "e:\%profil%\AutreC" "c:\Windows|c:\Users|c:\Program Files|c:\Program Files (x86)|c:\PerfLogs|c:\MININT|c:\Util|c:\Intel"
call :saveprofil "c:\Users\%profil%" "e:\%profil%\AutreProfil" "Desktop|Favorites|Music|Documents|Pictures|Downloads|Videos|AppData\Roaming\Microsoft\Signatures|AppData\Roaming\Mozilla|AppData\Roaming\Microsoft\Windows\Themes"
call :saveprofil "c:\Users\%profil%\Desktop" "e:\%profil%\Desktop"
call :saveprofil "c:\Users\%profil%\Favorites" "e:\%profil%\Favorites"
call :saveprofil "c:\Users\%profil%\Music" "e:\%profil%\Music"
call :saveprofil "c:\Users\%profil%\Documents" "e:\%profil%\Documents"
call :saveprofil "c:\Users\%profil%\Pictures" "e:\%profil%\Pictures"
call :saveprofil "c:\Users\%profil%\Downloads" "e:\%profil%\Downloads"
call :saveprofil "c:\Users\%profil%\Videos" "e:\%profil%\Videos"
call :saveprofil "c:\Users\%profil%\AppData\Roaming\Microsoft\Signatures" "e:\%profil%\Signatures"
call :saveprofil "c:\Users\%profil%\AppData\Roaming\Mozilla" "e:\%profil%\Firefox"
call :saveprofil "c:\Users\%profil%\AppData\Roaming\Microsoft\Windows\Themes" "e:\%profil%\Theme"
call :saveprofil "d:" "e:\%profil%\Disk"
 
goto fin
 
:saveprofil
if not exist "%~1" goto :eof
 
set "XD=%~3"
if defined XD set "XD=/XD "%XD:|=" "%""
if not defined XD set "XD= "
 
md "%~2"
robocopy "%~1" "%~2" /E /A-:H /COPYALL /DCOPY:T /R:1 /W:1 /ETA %XD%
goto :eof
 
:fin
echo.