Discussion :

[_benjamin_]

Bonjour,

Je voudrais supprimer ces fichiers et dossiers:

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
RMDIR /s /q %userprofile%\FCCCache
RMDIR /s /q %userprofile%\Siemens
RMDIR /s /q %userprofile%\Teamcenter
ERASE /F /Q %userprofile%\*.lck
ERASE /f /q %userprofile%\*.log
RMDIR /s /q %appdata%\Siemens
RMDIR /s /q "%appdata%\Tc2007 External Interface"

Cependant quand je lance mon .bat avec ces lignes il ne supprime les fichiers/dossiers que pour le user qui lance le bat. Comment le faire pour tous les users present dans C:\users ?? sachant que je ne connais pas par avance les nom des users.

Merci par avance de votre aide

Cordialement,

[barnabe0057]

Bonjour,

Il suffit de boucler sur la liste des dossiers présents dans C:\Users :

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
cd /d %HomeDrive%\Users || exit /b 1
for /f "delims=" %%A in ('dir /b /ad ^| findstr /v "Public Default Administrateur"') do (
if exist "%%A\FCCCache" (RMDIR /s /q "%%A\FCCCache")
if exist "%%A\Siemens" (RMDIR /s /q "%%A\Siemens")
if exist "%%A\Teamcenter" (RMDIR /s /q "%%A\Teamcenter")
if exist "%%A\*.lck" (ERASE /f /q "%%A\*.lck")
if exist "%%A\*.log" (ERASE /f /q "%%A\*.log")
if exist "%%A\AppData\Roaming\Siemens" (RMDIR /s /q "%%A\AppData\Roaming\Siemens")
if exist "%%A\AppData\Roaming\Tc2007 External Interface" (RMDIR /s /q "%%A\AppData\Roaming\Tc2007 External Interface")
)

[_benjamin_]

Merci @barnabe0057,

Dans le ligne 2 je dois lister les users préset dans C:\users ?

Dans mon cas je ne les connais pas, y a t'il moyen de lui demander de regarder dans tous les sous dossier de C:\users sans lui préciser les noms des sous dossier ?

Cordialement,

[barnabe0057]

C'est bien ce que fait le code proposé, il regarde dans les sous-dossiers de C:\Users pour déterminer les noms des utilisateurs.

[_benjamin_]

Hello,

Merci @barnabe0057

Ca fonctionne super.
Pour ma comprehension, Ligne 2:

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

for /f "delims=" %%A in ('dir /b /ad ^| findstr /v "Public Default Administrateur"') do (

Tu lui dis de ne pas regarder dans Public, Default et Administrateur c'est bien ça ?

Cordialement,

[barnabe0057]

Oui c'est ça, j'exclus les profils qui ne me semblent pas concernés.