Discussion :

[Agnès31700]

Bonjour,

Dans le fichier joint, je voudrais filtrer la colonne A en excluant les valeurs contenues dans la colonne F.
Dans le code du Module1, je ne sais faire qu'en incluant les valeurs contenues dans la colonne F.

D'avance, Merci pour votre aide

Agnès

[gFZT82]

Bonjour,

Une proposition ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Option Base 1
Sub Filtrer()
Dim Cel As Range
Dim T() As String
    With Worksheets("Feuil1")
        If Not .AutoFilterMode Then .Range("A1").AutoFilter
        For Each Cel In .Range("A2:A" & .Range("A" & Rows.Count).End(xlUp).Row)
            If Application.CountIf(.Range("F1:F" & .Range("F" & Rows.Count).End(xlUp).Row), Cel.Value) = 0 Then
                x = x + 1
                ReDim Preserve T(x)
                T(x) = Cel
            End If
        Next Cel
        .Range("A1:A" & .Range("A" & Rows.Count).End(xlUp).Row).AutoFilter 1, T, xlFilterValues
    End With
End Sub

Cordialement.

[boisgontierjacques]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub FiltreInverseListe()
  Set f1 = Sheets("feuil1")
  Set d = CreateObject("scripting.dictionary")     ' Liste à ne pas sélectionner
  d.CompareMode = vbTextCompare
  For Each c In f1.Range("E2:E" & f1.[E65000].End(xlUp).Row)
    d(c.Value) = ""
  Next c
  Set f2 = Sheets("feuil1")
  Set d2 = CreateObject("scripting.dictionary")    ' liste complémentaire
  d2.CompareMode = vbTextCompare
  For Each c In f2.Range("A2:A" & f2.[A65000].End(xlUp).Row)
   If Not d.exists(c.Value) Then d2(c.Value) = ""
  Next c
  ActiveSheet.Range("$A$1:$A$10000").AutoFilter Field:=1, Criteria1:=d2.keys, Operator:=xlFilterValues
End Sub

Boisgontier

[Agnès31700]

Merci beaucoup gFZT82 et Jacques,
En plus de répondre à ma demande, vos propositions m'apprennent plein de choses :-)
Encore Merci pour votre contribution,
Agnès