Discussion :

[tahaji]

Bonjour chers membres,

Afin de faciliter la saisie de données, j'ai crée un formulaire de saisie en VBA. Cependant deux listes à multicritères de ce dernier ne renvoient pas les valeurs sélectionnées vers le tableau concerné contrairement aux autres cases de saisie.

Ci-joint le fichier en question , le formulaire s'affiche en cliquant sur le bouton "Nouveau Prospect" se situant dans la feuille "Base". Les deux listes sont " projets" et "Type de bien".

Je vous remercie d'avance,
Taha.

[ARTURO83]

Bonjour,

Comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub CommandButton1_Click()
    Dim Ctrl As Control
    Dim Colonne As Integer
    Dim DerLigne As Integer
 
    DerLigne = Sheets("Base").Range("A65000").End(xlUp).Row + 1
    For Each Ctrl In UserForm1.Controls
        Colonne = Val(Ctrl.Tag)
        If Colonne = 11 Then
            Sheets("Base").Cells(DerLigne, Colonne) = ListBox1.List(ListBox1.ListIndex)
        ElseIf Colonne = 12 Then
            Sheets("Base").Cells(DerLigne, Colonne) = ListBox2.List(ListBox2.ListIndex)
        ElseIf Colonne > 0 Then
            Sheets("Base").Cells(DerLigne, Colonne) = Ctrl
        End If
    Next
End Sub

Cdlt

[tahaji]

Merci beaucoup ARTURO83

Actuellement la valeur est renvoyée cependant le formulaire ne renvoie qu'une seule valeur tandis que j'en ai sélectionner 3.

Il y a-t-il une solution pour ceci ?

Merci d'avance

[ARTURO83]

Vous n'aviez pas précisé que vous vouliez sélectionner plusieurs valeurs.
Donc, si plusieurs valeurs sont sélectionnées, ces dernières sont ajoutées dans la même cellule.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
    For Each Ctrl In UserForm1.Controls
        Colonne = Val(Ctrl.Tag)
        If Colonne = 11 Then
            For i = 0 To ListBox1.ListCount - 1
              If ListBox1.Selected(i) = True Then Sheets("Base").Cells(DerLigne, Colonne) = Sheets("Base").Cells(DerLigne, Colonne) & "-" & ListBox1.List(i)
            Next
        ElseIf Colonne = 12 Then
            For i = 0 To ListBox2.ListCount - 1
                If ListBox1.List(i) <> "" Then Sheets("Base").Cells(DerLigne, Colonne) = Sheets("Base").Cells(DerLigne, Colonne) & "-" & ListBox2.List(i)
            Next
        ElseIf Colonne > 0 Then
            Sheets("Base").Cells(DerLigne, Colonne) = Ctrl
        End If
    Next

Cdlt

[tahaji]

Je m'excuse pour mon manque de précision. Par ailleurs quand j’exécute le dernier code une erreur s'affiche : "Erreur de compilation : Projet ou bibliothèque introuvable"

Merci d'avance ARTURO83

[ARTURO83]

Petite rectification, suite à un mauvais copier-coller,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub CommandButton1_Click()
    Dim Ctrl As Control
    Dim Colonne As Integer
    Dim DerLigne As Integer
    Dim i As Long
 
    DerLigne = Sheets("Base").Range("A65000").End(xlUp).Row + 1
    For Each Ctrl In UserForm1.Controls
        Colonne = Val(Ctrl.Tag)
        If Colonne = 11 Then
            For i = 0 To ListBox1.ListCount - 1
                If ListBox1.Selected(i) = True Then Sheets("Base").Cells(DerLigne, Colonne) = Sheets("Base").Cells(DerLigne, Colonne) & "-" & ListBox1.List(i)
            Next
        ElseIf Colonne = 12 Then
            For i = 0 To ListBox2.ListCount - 1
                If ListBox2.Selected(i) = True Then Sheets("Base").Cells(DerLigne, Colonne) = Sheets("Base").Cells(DerLigne, Colonne) & "-" & ListBox2.List(i)
            Next
        ElseIf Colonne > 0 Then
            Sheets("Base").Cells(DerLigne, Colonne) = Ctrl
        End If
    Next
End Sub

"
Pour votre problème, dans le module visual basic, faire " Outils", "Références", Décochez toutes les lignes affichant: "MANQUANT:....."

Cdlt