Discussion :

[marot_r]

Bonjour à tous et merci de votre aide et de votre temps.

J'ai un truc que je n'arrive pas à faire et je ne comprend pas où est mon erreur.

Dans une feuille j'ai une zone nommée SourceDirectoryListdont l'adresse est B8:C11.
J'aimerai accéder aux cellules B9:B11 (donc les n lignes moins la 1ère ligne la 1ère colonne) sans évidement préciser les adresses en dur.
J'essaye donc de définir une range par rapport à ma range.

Mon code actuel est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
    Dim area As Range
 
    Set area = Me.Range("SourceDirectoryList").Range( _
                        Me.Range("SourceDirectoryList").Cells(2, 1), _
                        Me.Range("SourceDirectoryList").Cells(Me.Range("SourceDirectoryList").Rows.Count, 1))

et il me donne comme zone C16:C18.

J'ai fait une recherche sur Google et je ne trouve que des exemples de range se référant à une feuille.

Si je fais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
    Set area = Me.Range( _
                        Me.Range("SourceDirectoryList").Cells(2, 1), _
                        Me.Range("SourceDirectoryList").Cells(Me.Range("SourceDirectoryList").Rows.Count, 1))

Cela me donne la zone que je veux mais je ne comprend pas pourquoi je ne peux pas définir une range dans une range en précisant les cellules en haut à gauche et en bas à droite.

Quelqu'un sait-il ?

A+

[unparia]

Bonjour
sur la base de ton exemple (et donc en exemple) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim rangetout As Range, rangedans As Range
  Set rangetout = Range("B8:C11")
  Set rangedans = rangetout.Offset(1).Resize(rangetout.Rows.Count - 1, rangetout.Columns.Count - 1)
  rangedans.Select

EDIT : et il y aurait du plus rigolo à faire avec appication.intersect.

[anasecu]

Bonjour,

Je limite le code écrit par paresse

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
    Dim area As Range
    With Me.Range("SourceDirectoryList")
        Set area = .Cells(2, 1).Resize(.Rows.Count - 1, 1)
        area.Select
    End With

[Algoplus]

Bonjour marot_r, unparia,

Me.Range("SourceDirectoryList").Cells(2, 1) à pour adresse B9
Me.Range("SourceDirectoryList").Cells(Me.Range("SourceDirectoryList").Rows.Count, 1)) a pour adresse B11

Un range de ces deux range . select va sélectionner la plage B9:B11 (normal, c'est ce qu'on attend)

Mais... , appliqué à Me.Range("SourceDirectoryList") on aura toujours cette plage B9:B11 mais non plus par rapport à la feuille, mais par rapport à la zone nommée SourceDirectoryList. donc avec un décalage de 1 colonne et 9 lignes.

Bonne soirée

EDIT : bonsoir anasecu

[unparia]

Il est également possible de garder l'idée de départ de Marot. En en corrigeant toutefois l'écriture, selon ce principe/exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim rangetout As Range, rangedans As Range
  Set rangetout = Range("B8:C11")
  MsgBox Range(rangetout(2, 1), rangetout(rangetout.Rows.Count, 1)).Address

[RyuAutodidacte]

Salut Jacques,

tu es passé avant par 2 fois sur les exemples que je voulais donner
Bon exemples , ma préférences allant sur le 2è ex.
je l'avais écrit ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Exemple()
Dim MyNewRange As Range
    With Range("SourceDirectoryList")
        Set MyNewRange = Range(.Cells(2, 1), .Cells(.Rows.Count, 1))
    End With
    MyNewRange.Select
    MsgBox MyNewRange.Address
End Sub

[mercatog]

Bonsoir à tous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Me.Range("SourceDirectoryList")
    .Range("A2").Resize(.Rows.Count - 1).Select
End With