Discussion :

[Vba14]

Bonjour à tous,

Je bloque sur une formule de calcul Vba. Voici mon problème :

Comment écrire, si Cmb_NumArt est égal à une valeur de la colonne B de la feuille(2) et que la valeur de Txt_Nbre de mon formulaire est supérieure à la valeur de la cellule dans colonne H de la feuille(2) correspondant à la ligne où ce trouve la valeur de Cmb_NumArt, alors message "Vous dépassez le stock disponible", et ensuite Txt_Nbre = "".

Pour le moment mon code ressemble à ça mais je pense qu'il faut passer par AfterUpDate.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Private Sub Txt_Nbre_Change()
'Uniquement des chiffres
If Not IsNumeric(Txt_Nbre) And Txt_Nbre <> "" Then
    MsgBox "Vous ne devez entrer que des chiffres !"
    Txt_Nbre = ""
    End If
End Sub

Pouvez-vous m'apporter votre aide s'il vous plait ?
Je vous en remercie par avance

[mercatog]

Bonjour

Exemple utilisant l'événement Exit

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub Txt_Nbre_Exit(ByVal Cancel As MSForms.ReturnBoolean)
Dim c As Range
Dim Q As Double
 
If Me.Cmb_NumArt.ListIndex > -1 Then
    Q = Val(Replace(Me.Txt_Nbre, ",", "."))
    If Q > 0 Then
        With Worksheets("Feuil1")    'A adapter
            Set c = .Range("B:B").Find(Me.Cmb_NumArt.Value, LookIn:=xlValues, lookat:=xlWhole)
            If Not c Is Nothing Then
                If c.Offset(, 6).Value < Q Then
                    Cancel = True
                    Me.Txt_Nbre = ""
                    MsgBox "Vous dépassez le stock disponible"
                End If
                Set c = Nothing
            End If
        End With
    Else
        MsgBox "Veuillez saisir la quantité"
    End If
Else
    MsgBox "Veuillez saisir l'article"
End If
End Sub

[Vba14]

Merci beaucoup Mercatog, ça fonctionne très bien.
Bonne fin de journée
Amicalement