Discussion :

[mouftie]

Bonjour,
Je voudrais faire un premier filtre sur la colonne2 pour masquer les valeurs égale à 1 ou 2 et un sur la colonne 3 pour masquer les valeurs vide.
j'ai essayé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Activesheet.ListObjects("TbSaisies").Range.AutoFilter Field:=2, Criteria1:<>"1", Criteria2:<>2", Operator:=xlOr, Field:=3, Criteria1:=""

Mais cela ne fonctionne pas, après Criteria, Excel veut "=" et non "<>"
Est-ce que quelqu'un peut m'aider ?

J'ai trouvé un code de Jacques Boisgontier qui permet le filtre inverse multicritères, mais sur une seule colonne et je n'arrive pas à déclarer la variable liste (j'ai essayé liste as object, as variant, as string rien ne fonctionne)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub FiltreInverseListe()
Dim f1 As Object, f2 As Object, d As Object, d2 As Object, c As Range, liste as ???
  Set f1 = Sheets("feuil1")
  Set d = CreateObject("scripting.dictionary")
  d.CompareMode = vbTextCompare
  liste = Array("paris", "lyon", "bordeaux")            ' Liste à ne pas sélectionner
  For Each c In liste: d(c) = "": Next c
  Set f2 = Sheets("feuil1")
  Set d2 = CreateObject("scripting.dictionary")     ' liste complémentaire
  d2.CompareMode = vbTextCompare
  For Each c In f2.Range("B2:B" & f2.[B65000].End(xlUp).Row)
   If Not d.exists(c.Value) Then d2(c.Value) = ""
  Next c
  ActiveSheet.Range("$A$1:$B$100").AutoFilter Field:=2, Criteria1:=d2.keys, Operator:=xlFilterValues
End Sub

Merci de votre aide

[boisgontierjacques]

Bonjour,

Méthode générale. S'il n'y a que 2 valeurs à exclure, on peut utiliser Criteria1 et Criteria2.
J'ai supposé que la colonne 2 était numérique.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub FiltreInverseListe()
  Set d = CreateObject("scripting.dictionary")
  d.CompareMode = vbTextCompare
  Liste = Array(1, 2)           ' Liste à ne pas sélectionner
  For Each c In Liste: d(CStr(c)) = "": Next c
  Set d2 = CreateObject("scripting.dictionary")     ' liste complémentaire
  d2.CompareMode = vbTextCompare
  For Each c In [Tbsaisies[Num]]
    If Not d.exists(CStr(c.Value)) Then d2(CStr(c.Value)) = ""
  Next c
[Tbsaisies].AutoFilter Field:=2, Criteria1:=d2.keys, Operator:=xlFilterValues
[Tbsaisies].AutoFilter Field:=3, Criteria1:="<>"
End Sub
 
Sub supFiltre()
   [Tbsaisies].AutoFilter
End Sub

[OrDonc]

Bonsoir…

avec un Tableau structuré nommé TbSaisies et un bouton bascule (ToggleButton) nommé Tg

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Tg_Click()
    Application.ScreenUpdating = 0
    With [TbSaisies]
        .AutoFilter
        If Tg Then .AutoFilter 2, Criteria1:="<>1", Criteria2:="<>2": .AutoFilter 3, "<>"
    End With
End Sub

[mouftie]

Bonsoir…
avec un Tableau structuré nommé TbSaisies et un bouton bascule (ToggleButton) nommé Tg

Bonsoir OrDonc,
Merci pour ta réponse, mais il n'y a pas de bouton à bascule, c'est une base de données dont je veux supprimer des enregistrements.

[OrDonc]

bonsoir ...

un exemple avec le dernier fichier de Jacques (merci)

[boisgontierjacques]

Bonjour,


>c'est une base de données dont je veux supprimer des enregistrements.


Je suppose qu'il faut conserver les codes 1 et 2

Suppression de lignes rapide d'un tableau structuré

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub supLignesRapide()
  Application.ScreenUpdating = False
  codes = Array(1, 2, 6) ' codes à conserver
  a = [TbSaisies]
  ReDim b(1 To UBound(a), 1 To 1)
  For i = LBound(a) To UBound(a)
    If IsError(Application.Match(a(i, 2), codes, 0)) Then b(i, 1) = "sup" Else b(i, 1) = 0
  Next i
  Range("TbSaisies[#all]").Columns(2).Insert Shift:=xlToRight
  [TBSaisies[colonne1]].Resize(UBound(b)) = b
  [TbSaisies].Sort Key1:=[TBSaisies[colonne1]], Order1:=xlAscending, Header:=xlYes
  On Error Resume Next
  [TBSaisies[colonne1]].SpecialCells(xlCellTypeConstants, 2).EntireRow.Delete
  [TBSaisies[colonne1]].Delete Shift:=xlToLeft
End Sub

Boisgontier

[mouftie]

Bonjour Monsieur,

Merci beaucoup pour votre réponse, c'est super rapide.

Pourriez-vous me dire comment je dois déclarer la variable "liste", svp ?
Merci