Discussion :

[Tif72]

Bonjour tout le monde,

Je suis tout nouveau sur le forum et ceci est mon premier post. Je suis en train de développer un outil pour mon entreprise et j'utilise notamment des filtres via VBA. J'ai réalisé un filtre via une variable "object" dont voici le code (partiel) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
  Set jx = CreateObject("Scripting.dictionary")
  With WSCG600
    For j = 8 To .Range("p" & Rows.Count).End(xlUp).Row
      jx(.Range("p" & j).Value) = ""
    Next j
  End With
 
    Rows("2:2").AutoFilter Field:=1, Criteria1:=jx.keys, Operator:=xlFilterValues

Dans ma feuille WSCG600 j'ai une liste de termes dont le nombre est variable. Jusque là je n'ai pas de problème, le code fonctionne parfaitement.

Cependant je voudrais faire exactement la même manipulation mais avec le critère "différent de", j'ai donc codé de cette façon :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
  Set jx = CreateObject("Scripting.dictionary")
  With WSCG600
    For j = 8 To .Range("p" & Rows.Count).End(xlUp).Row
      jx(.Range("p" & j).Value) = ""
    Next j
  End With

    Rows("2:2").AutoFilter Field:=1, Criteria1:="<>" & jx.keys, Operator:=xlFilterValues

Et là, le code ne fonctionne plus. Est-ce que quelqu'un pourrait m'aider??

Je vous remercie !

[boisgontierjacques]

Bonjour,

Pour faire <>, il faut une table avec la liste complémentaire:

Exemple: On veut filtrer ceux qui ne sont pas dans une liste en colonne E.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub FiltreInverseListe()
  Set f1 = Sheets("feuil1")
  Set d = CreateObject("scripting.dictionary")     ' Liste à ne pas sélectionner
  d.CompareMode = vbTextCompare
  For Each c In f1.Range("E2:E" & f1.[E65000].End(xlUp).Row)
    d(c.Value) = ""
  Next c
  Set f2 = Sheets("feuil1")
  Set d2 = CreateObject("scripting.dictionary")    ' liste complémentaire
  d2.CompareMode = vbTextCompare
  For Each c In f2.Range("B2:B" & f2.[B65000].End(xlUp).Row)
   If Not d.exists(c.Value) Then d2(c.Value) = ""
  Next c
  ActiveSheet.Range("$A$1:$B$100").AutoFilter Field:=2, Criteria1:=d2.keys, Operator:=xlFilterValues
End Sub

Exemple en PJ

Boisgontier

[Tif72]

Merci beaucoup pour la réponse ! ça fonctionne bien !

A bientôt