Discussion :

[Ramone1]

Bonsoir à tous,

J'ai besoin de votre aide svp!
Je veux récupérer le résultat d'une boucle (plusieurs lignes) dans une liste déroulante. Je m'explique: Je teste sur les valeurs d'un tableau et j'ai réussi à afficher les lignes sur plusieurs cellules mais pas dans une liste déroulante.

D'avance, je vous remercie pour votre aide!

[Thautheme]

Bonjour Ramone, bonjour le forum,

Sans plus de précision et si j'ai bien compris, un code à adapter à tes besoins :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub Macro1()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim COL As Integer 'déclare la variable COL (COLonne)
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)
Dim L As String 'déclare la variable L (Liste)
Dim I As Integer 'déclare la variable I (Incrément)
Dim CVD As Range 'déclare la variable CVD (Cellule à Validation de Données)
 
Set O = Worksheets("Feuil1") 'définit l'onglet O (à adapter)
COL = 1 'définit la colonne COL (à adapter)
DL = O.Cells(Application.Rows.Count, COL).End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne COL de l'onglet O
For I = 1 To DL 'boucle des ligne 1 à DL
    If O.Cells(I, COL).Value > 10 Then 'condition : si la cellule ligne I colonne COL est supérieure à 10 (test à adapter)
        L = IIf(L = "", O.Cells(I, COL), L & "," & O.Cells(I, COL)) 'définit la liste L
    End If 'fin de la condition
Next I 'prochaine ligne de la boucle
Set CVD = O.Range("C1") 'définit la cellule qui va recevoir la validation de données (à adapter)
With CVD.Validation 'prend en compte la validation de données de la cellule CVD
    .Delete 'supprime une éventuelle validation de données existante
    .Add xlValidateList, Formula1:=L 'ajoute la liste L comme validation de données
End With 'fin de la prise en compte de la validation de données de la cellule CVD
End Sub

Tu nous aurais fourni plus de détails, le code aurait été plus simple et plus court...

[Ramone1]

Super! Merci beaucoup Thautheme