Discussion :

[jcsoram]

Bonjour,

Je viens vers vous car je suis bloqué, ce script fonctionne bien sous Windows 10 Pro mais ne fonctionne pas sous Windows Serveur 2012 R2.
Le blocage ce fait après le 1er "for" la console reste ouverte(un bouclage) sous 2012 alors que Windows 10 il se termine.

- Le principe du scripte doit aller dans le dossier "C:\E_DOC\DOC_INOTE_A_REPRENDRE\PDF" prendre x fichier (ici pour mes tests 4).
- Copier dans "C:\DESTINATION" ces x fichier (ici pour mes tests 4).
- Puis retournée dans "C:\E_DOC\DOC_INOTE_A_REPRENDRE\PDF" prendre x fichier (ici pour mes tests 4 pour les déplacer dans "C:\E_DOC\DOC_INOTE_A_REPRENDRE\PDF\REPRIS".

Si quelqu'un a une solution car je ne voit ou je me suis tromper et pourquoi cela bloque.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
@echo off
rem - Le dossier Source ou ce trouve les fichiers
set SourceDir=C:\E_DOC\DOC_INOTE_A_REPRENDRE\PDF
rem - Le dossier destination
set DestDir=C:\DESTINATION
rem - Le dossier destination de control
set DestDir2=C:\E_DOC\DOC_INOTE_A_REPRENDRE\PDF\REPRIS
rem - Le nombre de fichier que l'on veux copier
set /A nb_max_files=4

rem - Déplacer les fichiers de SourceDir avec un type de fichier ici les .pdf
set /A nb_files_move=0
set /A nb_files_xcopy=0
rem - xcopy copie les fichier dans un dossier
for %%f in ("%SourceDir%\*.pdf") do (call :xcopy_one_file "%%f")
rem - move coupe et colle dans un dossier
for %%g in ("%SourceDir%\*.pdf") do (call :move_one_file "%%g")
goto :eof

:xcopy_one_file
rem - Routine déplaçant un fichier si maximum non atteint
rem - %1 contient le fichier à déplacer
if /I %nb_files_xcopy% GEQ %nb_max_files% goto :eof
COPY  /Y "%~1" "%DestDir%" 1>nul 2>nul
set /A nb_files_xcopy+=1
goto :eof

:move_one_file
rem - Routine coupe et colle un fichier si maximum non atteint
rem - %1 contient le fichier à déplacer
if /I %nb_files_move% GEQ %nb_max_files% goto :eof
move /Y "%~1" "%DestDir2%" 1>nul 2>nul
set /A nb_files_move+=1
goto :eof

Cordialement,
Merci

[barnabe0057]

Bonjour,

Je ne vois pas de problème majeur, je n'ai pas de windows server 2012 pour tester. J'ai juste corrigé quelques détails :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
@echo off

rem - Le dossier Source ou ce trouve les fichiers
set SourceDir=C:\E_DOC\DOC_INOTE_A_REPRENDRE\PDF

rem - Le dossier destination
set DestDir=C:\DESTINATION

rem - Le dossier destination de control
set DestDir2=C:\E_DOC\DOC_INOTE_A_REPRENDRE\PDF\REPRIS

rem - Le nombre de fichier que l'on veux copier
set nb_max_files=4

rem - Déplacer les fichiers de SourceDir avec un type de fichier ici les .pdf
set nb_files_move=0
set nb_files_xcopy=0

rem - xcopy copie les fichier dans un dossier
for %%f in ("%SourceDir%\*.pdf") do (call :xcopy_one_file "%%~f")

rem - move coupe et colle dans un dossier
for %%g in ("%SourceDir%\*.pdf") do (call :move_one_file "%%~g")

exit /b 0

:xcopy_one_file
rem - Routine déplaçant un fichier si maximum non atteint
rem - %1 contient le fichier à déplacer
if %nb_files_xcopy% GEQ %nb_max_files% goto :eof
COPY /Y "%~1" "%DestDir%" >nul 2>&1
set /A nb_files_xcopy+=1
goto :eof

:move_one_file
rem - Routine coupe et colle un fichier si maximum non atteint
rem - %1 contient le fichier à déplacer
if %nb_files_move% GEQ %nb_max_files% goto :eof
move /Y "%~1" "%DestDir2%" >nul 2>&1
set /A nb_files_move+=1
goto :eof

[jcsoram]

Bonjour,

Merci barnabe0057 pour tes corrections.
Mais cela ne fonctionne pas toujours pas sous Windows serveur 2012 il ne veut pas faire l’enchainement sur la 2ème fonction.
La console reste ouverte(un bouclage).

J'ai aussi découper le scripte en 3 fichiers .bat, même problème.
- 1 qui fait l'appel de for copy et move
- 1 fichier bat copy
- 1 fichier bat move

Cordialement
Bonne journée

[sachadee]

quel est le nom de tes fichiers .bat ?

copy.bat
move.bat

???

Si oui change de nom ! par mon_copy et mon_move.bat

[jcsoram]

Merci sachadee pour ton aide.

Cela n'a rien changer toujours le même problème. Il copie bien les fichier en fonction du compteur mais le move.

Par contre je viens de m'a percevoir que la copie de fait bien mais il ne sort pas du 1er for "copy" pour aller dans le for "move".
C'est comme s'il parcoure tout le dossier "140 000 fichiers" avant de passé au suivant for.

Cordialement
Bonne journée

[CTJayce]

la copie de fait bien mais il ne sort pas du 1er for "copy" pour aller dans le for "move".
C'est comme s'il parcoure tout le dossier "140 000 fichiers" avant de passé au suivant for.

Après que ton nombre max de fichiers a été atteint, tu ne fais rien pour
sortir de ta boucle, alors le parcours du dossier continu tant qu'il y a des fichiers.

Par ailleurs, tu ne vérifies à aucun moment la réussite des opérations, le "copy"
peut échouer, le "move" peut échouer et indépendamment l'un de l'autre.

Enfin, rien ne garantit que ta deuxième boucle traite les mêmes fichiers que ta
première, sans compter le gaspillage de ressources, forcément inutile, mais ça,
c'est une autre histoire.