Utilisation de la position courante d'un curseur dans une PS

**Christophe Charron** · 11/11/2018, 18h01

Bonjour,

je souhaite utiliser la position courante d'un curseur dans une procédure stockée dans laquelle je construis dynamiquement mes requêtes car elles font référence à une colonne que je crée, puis supprime dans cette même procédure stockée.

Mais j'ai une erreur, qui ne m'étonne pas trop, car j'utilise une sp_executesql qui ne connait pas mon curseur.
Ai-je la possibilité de m'en soritr? Et si oui, comment.

D'avance, merci pour vos pistes et éclairages.

Voici la procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO
-- =============================================
-- Auteur:		<XOF>
-- Date de création: <11 Novembre 2018>
-- Description:	<Supprime les doublons de la table [1L_Portail_Profils_Utilisateur]>
-- =============================================
ALTER PROCEDURE [1Lsp_Verification_Doublons_PK_1L_Portail_Profils_Utilisateurs_1L_Portail_Profils] 
AS
BEGIN
	SET NOCOUNT ON;
	DECLARE @i INT
	DECLARE @IDFugace INT
	DECLARE @NomColonne nvarchar(100)
	DECLARE @SRequeteSQLLecture nvarchar(4000)
	DECLARE @SRequeteSQLUpdate nvarchar(4000)
	set @NomColonne='[1L_IDFugace]'
    IF EXISTS (
		SELECT COUNT(*) AS Nombre, idProfil,IDUtilisateur
			FROM   [1L_Portail_Profils_Utilisateur]
			GROUP  BY idProfil,IDUtilisateur
			HAVING COUNT(*) > 1
			)
		BEGIN
			--*****************************************--
			-- Il y a des doublons à supprimer...
			--*****************************************--
			-- On ajoute une colonne que l'on supprimera en fin de procédure
			ALTER TABLE [1L_Portail_Profils_Utilisateur] ADD [1L_IDFugace] INT;
			--	On parcours toute la table pour l'ID
			--	On construit dynamiquement le cuseur car la colonne n'est pas connue dans le MCD
			--	On vient juste de la créer fugacement
			set @SRequeteSQLLecture=N'SET @CURSEUR_DOUBLON = CURSOR FOR SELECT '+@NomColonne+N' FROM [1L_Portail_Profils_Utilisateur] OPEN @CURSEUR_DOUBLON'
 
			SET @i = 1
 
			DECLARE @CURSEUR_DOUBLON CURSOR
			EXEC sp_executesql @SRequeteSQLLecture, N'@CURSEUR_DOUBLON cursor OUTPUT', @CURSEUR_DOUBLON OUTPUT
 
			FETCH NEXT FROM @CURSEUR_DOUBLON INTO @IDFugace
 
			WHILE @@FETCH_STATUS = 0
			BEGIN
				set @SRequeteSQLUpdate= N'UPDATE [1L_Portail_Profils_Utilisateur] SET [1L_IDFugace] = '+cast(@i as varchar(10))+N' WHERE  CURRENT OF @CURSEUR_DOUBLON'
				print @SRequeteSQLUpdate
				EXEC sp_executesql @SRequeteSQLUpdate
			   SET @i = @i + 1
 
			   FETCH NEXT FROM @CURSEUR_DOUBLON INTO @IDFugace  
 
			END
 
			CLOSE @CURSEUR_DOUBLON
 
			DEALLOCATE @CURSEUR_DOUBLON
			-- On supprime les doublons-triplons etc ...
 
 
			-- Suppression de la colonne fugace
			--ALTER TABLE [1L_Portail_Profils_Utilisateur] DROP COLUMN [1L_IDFugace];
		END
	ELSE
	BEGIN 
		-- Il n'y a pas de doublon à traiter ...
		PRINT 'Faut rien faire '
	END
END
GO

ainsi que l'erreur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
UPDATE [1L_Portail_Profils_Utilisateur] SET [1L_IDFugace] = 1 WHERE  CURRENT OF @CURSEUR_DOUBLON
Msg 137, Level 15, State 2, Line 1
Must declare the scalar variable "@CURSEUR_DOUBLON".

Invité · 13/11/2018, 14h29

Tu cherches à faire quoi avec cette usine à gaz.
J'ai l'impression que tu cumules les mauvaises pratiques pour faire quelque chose de simple...

**Christophe Charron** · 13/11/2018, 20h57

Merci d'avoir pris le temps de me lire.
J'essaie de déterminer l'utilisabilité, dans un cas très simple, d'un curseur avec deux requêtes dynamiques.

**SQLpro** · 14/11/2018, 11h15

La solution ensembliste suivante sera mille fois plus rapide pour éradiquer vos doublons que l'utilisation de cur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
CREATE SEQUENCE SEQ_DOUBLONS;
 
ALTER TABLE [1L_Portail_Profils_Utilisateur] ADD [1L_IDFugace] BIGINT;
 
UPDATE [1L_Portail_Profils_Utilisateur]
SET [1L_IDFugace] = NEXT VALUE FOR SEQ_DOUBLONS;
 
DELETE FROM T 
FROM [1L_Portail_Profils_Utilisateur] AS T
WHERE  EXISTS(SELECT *
              FROM   [1L_Portail_Profils_Utilisateur] AS TT
              WHERE  T.idProfil = TT.idProfil AND T.IDUtilisateur = TT.IDUtilisateur
              HAVING T.[1L_IDFugace] > MIN(TT.[1L_IDFugace]));
 
DROP SEQUENCE SEQ_DOUBLONS;

Bien entendu il faudrait faire cela dans une procédure stockées transactionnée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
CREATE PROCEDURE P_DELETE_DOUBLONS
AS
 
SET NOCOUNT ON;
 
BEGIN TRANSACTION;
 
BEGIN TRY
 
   CREATE SEQUENCE SEQ_DOUBLONS;
 
   EXEC ('ALTER TABLE [1L_Portail_Profils_Utilisateur] ADD [1L_IDFugace] BIGINT;');
 
   EXEC ('UPDATE [1L_Portail_Profils_Utilisateur] SET [1L_IDFugace] = NEXT VALUE FOR SEQ_DOUBLONS;')
 
   EXEC ('DELETE FROM T 
          FROM [1L_Portail_Profils_Utilisateur] AS T
          WHERE  EXISTS(SELECT *
                        FROM   [1L_Portail_Profils_Utilisateur] AS TT
                        WHERE  T.idProfil = TT.idProfil AND T.IDUtilisateur = TT.IDUtilisateur
                        HAVING T.[1L_IDFugace] > MIN(TT.[1L_IDFugace]));');
   EXEC ('ALTER TABLE [1L_Portail_Profils_Utilisateur] DROP COLUMN [1L_IDFugace]');
 
   DROP SEQUENCE SEQ_DOUBLONS;
 
   COMMIT;
 
END TRY
BEGIN CATCH
   IF XACT_STATE() <> 0
      ROLLBACK;
   THROW;
END CATCH
 
GO

la lancer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
EXEC P_DELETE_DOUBLONS

A +

PS - pour vous former à SQL Server :
https://www.amazon.fr/SQL-Server-201...dp/2212135920/
Nom : Couverture livre SQL server Eyrolles.jpg
Affichages : 111
Taille : 105,0 Ko

Nom : Couverture livre SQL server Eyrolles.jpg
Affichages : 111
Taille : 105,0 Ko

**Christophe Charron** · 14/11/2018, 17h22

Merci Frédéric, pour votre réponse.
La suppression des doublons n'était qu'un prétexte pour explorer la position courante du curseur.
J'avais bien lu votre article sur les doublons https://sqlpro.developpez.com/cours/doublons/ et procédé en fonction.

Mais il n'empêche que j'aimerais bien savoir s'il est envisageable d'imbriquer l'exécution d'une requête "dynamique" qui puisse utiliser la position de curseur courante

**SQLpro** · 14/11/2018, 23h07

Dans ce cas il faut tout faire en SQL dynamique y compris l'implémentation du curseur.

Bon courage

A +

**Christophe Charron** · 15/11/2018, 07h35

Bonjour,

le "Bon courage", de votre part m'incline à remettre à un peu plus tard cette expérimentation que je pressens ardue, en l'état actuel de mes capacités.

Merci d'avoir pris le temps de répondre.

**SQLpro** · 16/11/2018, 12h31

Et oui, l'utilisation de curseur en mode SQL dynamique est possible. Comme l'utilisation des curseurs est généralement une grosse merde, let le SQL dynamique une deuxième grosse merde, le tout est une grosse merde ²... !!!

A +

**aieeeuuuuu** · 16/11/2018, 17h37

Bonjour,

Cela dit, il y a bien plus simple pour supprimer les doublons :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
WITH CTE AS (
SELECT ROW_NUMBER() OVER(PARTITION BY [critère de détection de doublon] ORDER BY [critère de sélection de doublon à supprimer]) AS RN
FROM LaTable
)
DELETE FROM CTE 
WHERE RN > 1

**SQLpro** · 19/11/2018, 13h53

Justement c'est cela qu'il n'a pas : "critère de détection de doublon" !

A +

Utilisation de la position courante d'un curseur dans une PS [2008R2]

Développement SQL Server

Discussions similaires

Partager

Partager