Discussion :

[papyxy]

Bonjour
En VBA, je souhaiterai déclencher un événement lorsqu'une cellule d'un document externe est sélectionnée.
Sachant que le classeur ouvert est du type XLS sans macro.
J'ai bien vu quelque chose approchant la solution sur ce forum, proposée par un rédacteur (withevents) , mais je n'ai pas compris le principe.

https://www.developpez.net/forums/d6...ment-classeur/
Merci d'avance si une idée est proposée.

[PMO2017]

Bonjour,

Essayez la démarche suivante :
1) Créez un module de classe et renommez-le cls_AppEvents puis insérez le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Public WithEvents Appl As Application
 
Private Sub Appl_SheetChange(ByVal Sh As Object, ByVal Target As Range)
Dim C As Range
'---
If Sh.Parent Is ThisWorkbook Then Exit Sub
Set S_result = ThisWorkbook.Sheets("Results") ' nom "Results" à adapter selon votre usage
For Each C In Target
  S_result.Range(C.Address) = C
Next C
End Sub

2) Dans un module standard, copiez le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
Public myApp As New cls_AppEvents
Public S_result As Worksheet

3) Dans la fenêtre de code de ThisWorkbook, copiez le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Private Sub Workbook_Open()
Set myApp.Appl = Application
End Sub
 
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Set myApp.Appl = Nothing
End Sub

4) Dans votre classeur maître (ThisWorkbook), insérez une feuille et nommez-la Results (en accord avec le paragraphe 1 )


Ouvrez d'abord le classeur maître puis un autre classeur (nouveau ou existant). Toutes les modifications en valeur de ce dernier seront reportées dans la feuille "Results"

[papyxy]

Bonjour
je viens d' essayer le programme; cela correspond a mes souhait.
Merci pour l' aide, je n' aurai pas trouve mieux.