Discussion :

[GALOY]

j'ai crée un classeurs que j'ai nommé projet 2, qui comporte 3 feuilles (SAISIE, HISTORIQUE_ORDO ET DONNEE)
en cliquant sur le bouton valider certaines cellules de ma feuille saisie doivent etre copier sur la feuille historique_ordo.
mon problème, je veux copier, les lignes de ma feuille saisie vers la veuille Historique.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub VALIDER()
Dim i As Integer
tableau = Split(ActiveSheet.Range("G14").Value, "-")
For i = 0 To UBound(tableau)
Next i
ActiveSheet.Range("G14").Value = tableau(0) & "-" & tableau(1) + 1
 
ligne = Sheets("HISTORIQUE_ORDO").Range("A2").End(xlDown).Row + 1
'MsgBox (ligne)
Sheets("HISTORIQUE_ORDO").Range("A" & ligne).Value = Sheets("SAISIE").Range("G14").Value
Sheets("HISTORIQUE_ORDO").Range("B" & ligne).Value = Sheets("SAISIE").Range("B14").Value
Sheets("HISTORIQUE_ORDO").Range("C" & ligne).Value = Sheets("SAISIE").Range("D19:D38").Value
Sheets("HISTORIQUE_ORDO").Range("D" & ligne).Value = Sheets("SAISIE").Range("E19:E38").Value
Sheets("HISTORIQUE_ORDO").Range("E" & ligne).Value = Sheets("SAISIE").Range("F19:F38").Value
Sheets("HISTORIQUE_ORDO").Range("F" & ligne).Value = Sheets("SAISIE").Range("G19:G38").Value
Sheets("SAISIE").Range("D19:D38").ClearContents
Sheets("SAISIE").Range("E19:E38").ClearContents
Sheets("SAISIE").Range("F19:F38").ClearContents
 
On Error Resume Next
Range("G19:G38").SpecialCells(xlcelltypeconstant, 23).ClearContents
On Error GoTo 0
 
End Sub

ils ne copie que la 1ère ligne de mon tableau.
je suis novice en vba, des recherche mon permis de résoudre quelques problèmes

[sogedic]

C'est normal non ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
tableau = Split(ActiveSheet.Range("G14").Value, "-")
For i = 0 To UBound(tableau)
Next i
ActiveSheet.Range("G14").Value = tableau(0) & "-" & tableau(1) + 1

essaye

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
tableau = Split(ActiveSheet.Range("G14").Value, "-")
For i = 0 To UBound(tableau,1)
ActiveSheet.Range("h" & i ).Value = tableau(i) 
Next i

Enfin a modifier selon ce que tu souhaites … mais dans la boucle

[GALOY]

sogegic, je n'ai pas de problème avec incrémentation du numéro, mon problème est la copie des cellules de ma feuille SAISIE vers ma feuille Historique, je vais le mettre en piece jointe

[sogedic]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ligne = Sheets("HISTORIQUE_ORDO").Range("A2").End(xlDown).Row + 1

si "ligne" a une valeur unique il ne peut y avoir qu'une ligne de copie
il faut
- soit faire une boucle
- soit copier une range

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("HISTORIQUE_ORDO").Range("D" & ligne & ":D"& 19+ligne).Value = Sheets("SAISIE").Range("E19:E38").Value

[GALOY]

Mais malheureusement, ils y a un autre problème qui survient.
Quand on clique sur le bouton "valider et nouvelle ordonnance" la date s'affiche qu'une fois et en plus quand on saisie une autre ordonnance, la nouvelle validation efface les précédentes lignes ou il n'y a pas de date.
Merci d'avance pour ton aide

[sogedic]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub VALIDER()
 
    Dim ddate As String, numOrd As String
    Dim tableau As Variant, i As Integer
    Dim ligne As Long
 
 
    With Sheets("SAISIE")
        ddate = .Range("B14")
        numOrd = .Range("G14")
        tableau = .Range("D19:G38").Value
    End With
 
    With Sheets("HISTORIQUE_ORDO")
        ligne = .Range("A2").End(xlDown).Row
        For i = 1 To UBound(tableau, 1)
            If tableau(i, 1) <> "" Then
                ligne = ligne + 1
                '---
                .Cells(ligne, 1) = numOrd
                .Cells(ligne, 2) = ddate
                '---
                .Cells(ligne, 3) = tableau(i, 1)    'medicament
                .Cells(ligne, 4) = tableau(i, 2)    ' PU
                .Cells(ligne, 5) = tableau(i, 3)    'Qte
                .Cells(ligne, 6) = tableau(i, 4)    'MT
            End If
        Next i
    End With
 
    With Sheets("SAISIE")
        .Range("G14").Value = Split(numOrd, "-")(0) & "-" & Split(numOrd, "-")(1) + 1
        .Range("C19:G38").ClearContents
    End With
 
End Sub