Discussion :

[Snowmax86]

Bonjour,

Je n'arrive pas a écrire le code nécessaire pour faire fonctionner une macro qui me permettrait d'afficher seulement les colonnes possédant le NO.SEMAINE() qui ce situe entre le NO.SEMAINE(AUJOURDHUI())>=-1 et NO.SEMAINE(AUJOURDHUI())>=+2

Je m'explique:
la date d'aujourd'hui s'affiche en F3
j'ai une plage allant de P3 à BN3 contenant dans chaque cellule le no.semaine (allant de 2 a 52)

Je veux que lorsque j'active cette macro, toute les colonnes entières dans la plage P:BN soit masquée excepté celle qui ont la valeur entre le no.semaine-1 et no.semaine+2 par rapport a la date d'aujourdhui
(# semaine débutant le dimanche)

J'espère avoir été assez clair

Merci beaucoup d'avance de votre aide

[Invité]

Bonjour,

Vous pourriez cacher vos colonnes avec une boucle décrémentant de votre dernière cellule BN3 à P3 et en testant la semaine en cours à l'aide d'un Select Case pour traiter les différents cas suivants :
Cas où la semaine en cours = 1 : Un message vous avertit que la date doit être au moins la semaine 2
Cas où la semaine en cours est comprise entre 2 et 5. Toutes les colonnes dont la semaine de la date testée est > 5 sont cachées.
Cas où la semaine en cours est comprise entre 49 et 52. Toutes les colonnes dont la semaine de la date testée est < 49 sont cachées.
Cas autres : Les colonnes pour le cas semaine date < semaine en cours -1 ou semaine date > semaine en cours + 2 sont cachées.

[sogedic]

Bonjour Snowmax86,

Semaine debutant le dimanche https://support.office.com/fr-fr/art...rs=fr-FR&ad=FRhttps://support.office.com/fr-fr/art...rs=fr-FR&ad=FR

Proposition de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Option Explicit
 
Sub masquerColonnes()
 
    Dim noSem As Integer, noSemi As Integer
    Dim rg As Range, rgMasq As Range, celli As Range
 
    With ActiveSheet
        'Init
        noSem = Application.WorksheetFunction.WeekNum(.Range("F3").Value, 1) ' debut de semaine = dimanche
        Set rg = .Range("P3:BN3")
 
        'R?afficher toutes les colonnes
        rg.EntireColumn.Hidden = False
 
        'Boucler sur les colonnes
        For Each celli In rg
            noSemi = celli.Value
            If noSemi < noSem - 1 Or noSem > noSem + 2 Then
                If rgMasq Is Nothing Then
                    Set rgMasq = .Cells(1, celli.Column)
                Else
                    Set rgMasq = Union(rgMasq, .Cells(1, celli.Column))
                End If
            End If
        Next celli
 
        'Masquer
        If Not rgMasq Is Nothing Then rgMasq.EntireColumn.Hidden = True
    End With
 
End Sub

[Snowmax86]

Wow, un gros merci sogedic. ça fonctionne #1. je ne pouvais demander mieux !!!