Discussion :

[Ellimc]

Bonjour
J'ai trouvé un programme de tri qui marchait très bien jusqu'à ce que.... Mon problème c'est que j'aimerai trier les ligne selon l'ordre suivant : " , IFA,IFC,ABS,IFI". Autrement dit j'aimerai que les premières lignes de mon tableau soient celle dont la Colonne D est vide. Et la le programme ne marche plus. Ou plutot il marche pour les IFA IFC ASB et IFI mais les ligne dont la colonne D est vide n'apparaissent qu'après... Comment faire SVP?


Voila le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
    Dim nbligne As Long
    With Sheets("Suivie De Société")
        nbligne = .Range("B" & Rows.Count).End(xlUp).Row
        chaine = ","",IFAR,IFA,IFCR,IFC,ASB,IFI"
        MsgBox chaine
        With .Sort
            .SortFields.Clear
            .SortFields.Add Key:=Range("D14:D" & nbligne), SortOn:=xlSortOnValues, Order:=xlAscending, CustomOrder:=",IFAR,IFA,IFCR,IFC,ASB,IFI", DataOption:=xlSortNormal
            .SetRange Range("A14:AK" & nbligne)
            .Header = xlGuess
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
    End With

[Theze]

Bonjour,

Tu ne peux rien y changer, le tri fonctionne comme ça, les cellules vides sont repoussées vers le bas.
Tu peux par contre leurrer en inscrivant dans les cellules vides de la colonne D un caractère comme par exemple # que tu positionnes en début de chaîne et une fois le tri effectué, tu supprime le caractère :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Sub Test()
 
    Dim nbligne As Long
 
    With Sheets("Feuil1")
 
        nbligne = .Range("B" & Rows.Count).End(xlUp).Row
 
        .Range("D14:D" & nbligne).Cells.SpecialCells(xlCellTypeBlanks).Value = "#"
 
        With .Sort
 
            .SortFields.Clear
            .SortFields.Add Key:=Range("D14:D" & nbligne), _
                            SortOn:=xlSortOnValues, _
                            Order:=xlAscending, _
                            CustomOrder:=",#,IFAR,IFA,IFCR,IFC,ASB,IFI", _
                            DataOption:=xlSortNormal
            .SetRange Range("A14:AK" & nbligne)
            .Header = xlGuess
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
 
        End With
 
        .Range("D14:D" & nbligne).Replace "#", ""
 
    End With
 
End Sub

[eriiic]

Bonjour,

j'ai répondu ici : https://www.developpez.net/forums/d1.../#post10416465
eric

[Ellimc]

Merci pour votre efficacité!! Le coup des 5"" ne fonctionne pas. J'ai donc opté pour la solution de Theze qui fonctionne parfaitement.
Merci Beaucoup

[RyuAutodidacte]

Bonjour,

Il est toujours intéressant de voir d'autres méthodes afin d'apprendre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub Demo_TRi()
Dim DL As Long, Plage As Range
    With Sheets(1)
        DL = .Cells(Rows.Count, 2).End(xlUp).Row
        Set Plage = .Range("A14:AK" & DL).Resize(, Columns("AK").Column + 1) 'Plage de tri - on ajoute une colonne supp à la fin pour y mettre la formule ci-dessous
            'Plage.Columns.Item(Plage.Columns.Count).Formula = "=ISBLANK(D14)" ' Formule afin de vérifier les cellules vide en Colonne D
            Plage.Columns.Item(Plage.Columns.Count).Formula = "=D14=""""" ' Formule afin de vérifier les cellules vide en Colonne D - autres façon de marquer la formule comme suggéré par @eriiic post #6
            Application.ScreenUpdating = False
        With .Sort
            .SortFields.Clear
            .SortFields.Add Key:=Plage.Columns.Item(Plage.Columns.Count), Order:=xlDescending ' Tri sur la colonne des formules
            .SortFields.Add Key:=Plage.Columns.Item(4), SortOn:=xlSortOnValues, Order:=xlAscending, CustomOrder:="IFAR,IFA,IFCR,IFC,ASB,IFI", DataOption:=xlSortNormal ' Tri Col D (4 ici car la plage commence en colonne A)
            .SetRange Plage: .Header = xlNo: .MatchCase = False: .Orientation = xlTopToBottom: .SortMethod = xlPinYin: .Apply
        End With
            Plage.Columns.Item(Plage.Columns.Count).ClearContents ' on efface les formules
            Application.ScreenUpdating = True
            Set Plage = Nothing
    End With
End Sub

@Theze ,@eriiic

Edit : Ajout/Corr. du code

[eriiic]

Bonjour ryu,

Intéressant, merci.
J'aurais juste une petit restriction sur .Formula = "=isblank(D14)"
Si tu as dans la cellule ' ou une formule du type ="" pour Estvide() ce n'est pas vide, même si visuellement ça l'est.
Je préfére le classique =""
eric