Discussion :

[morpheuss]

Bonjour,

Y a-t-il moyen de lire, écrire, modifier des bases SQL avec le VBA dans Excel ?

C'est une base SQL sur un serveur local dont voici les caractéristiques:

Serveur : Localhost via UNIX socket
Type de serveur : MariaDB
Version du serveur : 5.5.51-MariaDB - MariaDB Server
Version du protocole : 10

Est-ce possible ?
Si oui, avez-vous un lien ou un tuto d'exemple d'application ?

D'avance merci,

Steph

[Mr Poulpe]

Bonjour,

En effet, c'est possible, via un connecteur ADODB qui permet d'effectuer des requêtes SQL ou d'appeler des procédures stockées.

Je te réfère au tutoriel suivant concernant plutôt le VBA access mais applicable pour Excel.

https://vb.developpez.com/bidou/recordset-ado/

Par contre, il te faudra un connecteur pour ta base de données. Il me semble que tu peux en trouver ici :

https://mariadb.com/kb/en/library/ab...onnector-odbc/

Bien cordialement,

Edit : Petit exemple de fonction permettant d'exécuter une requête SQL (J'ai fait quelques simplifications et je ne l'ai pas testé, mais ça devrait te permettre de voir le principe) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Sub RunQuery(Query As String, Connection_string As String)
    Dim CON As Object 'ADODB.CONNECTION
    Dim RST As Object 'ADODB.RECORDSET
    Dim i As Integer 'Itérateur de boucle
    Dim CurCalc As XlCalculation 'Mode de calcul actuellement actif
    Dim Wb As Workbook
    Dim Wks As Worksheet
    Dim StartTime As Variant
 
On Error GoTo Err_hANdler_2:
 
    Set CON = CreateObject("ADODB.Connection")
    Set RST = CreateObject("ADODB.recordset")
    Set Wb = ActiveWorkbook
 
    'Ouverture de la connexion
    CON.Open Connection_string
 
    'Exécution de la requête
    Set RST = CON.Execute(Query)
 
 
    'Vérfie si le jeu d'enregistrement contient des données ou non
    If RST.EOF And RST.BOF Then
        Call MsgBox("Aucune donnée correspondant aux critères spécifiés n'a pu être trouvée", vbOKOnly, "Aucune donnée")
        Exit Sub
    End If
    Set Wks = Wb.Worksheets.Add
    CurCalc = Application.Calculation
    Application.Calculation = xlCalculationManual
    Wks.Range("A2").CopyFromRecordset RST
 
    'Inscription des noms de champs dans l'onglet
    For i = 1 To RST.Fields.Count
        Wks.Cells(1, i) = RST.Fields(i - 1).Name
    Next i
    CON.Close
    Application.Calculation = CurCalc
    Set CON = Nothing
    Set RST = Nothing
    MsgBox "Fin d'exécution. Aucune erreur détectée", vbInformation + vbOKOnly, "Fin d'exécution"
Exit Sub
 
Err_hANdler_2:
    Call MsgBox(err.Number & " : " & err.Description, vbCritical, "Erreur survenue pendant l'exécution")
End Sub

[morpheuss]

Merci, je vais tester ça.