Discussion :

[chouchouboy]

Bonjour,
Je souhaiterai récupérer la première adresse IP d'une carte réseau (qui est l'IP LAN de la machine). Les autres IP sont celles utilisées par VMWare et VPN...
Quand je fais un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ipconfig | find "IPv4"

j'obtiens :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Adresse IPv4. . . . . . . . . . . . . .: 10.0.1.2
Adresse IPv4. . . . . . . . . . . . . .: 192.168.116.1
Adresse IPv4. . . . . . . . . . . . . .: 192.168.136.1

En ce qui me concerne, je ne voudrais garder que 10.0.1.2.
Pourriez-vous me dire comment faire ?
Merci

[sachadee]

Salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
@echo off & cls

for /f "tokens=2 delims=:" %%a in ('ipconfig ^| find /i "IPv4"') do (
  set "$Ip=%%a"
  goto:next)

:next
echo IP ==^> %$Ip%

[zigouiik]

et si on avait voulu récupérer la 2ème ou la 3ème comment faut-il faire ?

[ericlm128]

En suivant le principe proposé par Sachadee, tu peux faire ceci

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
@echo off & cls
 
for /f "tokens=2 delims=:" %%a in ('ipconfig ^| find /i "IPv4" ^| more +1') do (
  set "$Ip=%%a"
  goto:next)
 
:next
echo IP ==^> %$Ip%

[zigouiik]

Merci beaucoup ericlm128, je vais étudier cela de près.
Le principe fonctionne effectivement.

[hackoofr]

et si on avait voulu récupérer la 2ème ou la 3ème comment faut-il faire ?

Dans ce cas on peut les stocker dans un tableau (array)

Code BAT :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
@echo off & cls
SetLocal EnableDelayedExpansion
for /f "tokens=2 delims=:" %%a in ('ipconfig ^| find /i "IPv4"') do (
Rem incrémenter la variable count de +1 dans la boucle for
    set /a count+=1
Rem On remplit notre tableau avec la variable count incrémenté
    set "IP[!count!]=%%a"
)
for /L %%i in (1,1,%count%) do (
Rem Pour supprimer les espaces dans la variable
    set "IP=!IP[%%i]: =!" 
Rem Afficher les adresses IP
    echo IP[%%i] = !IP!    
)
pause>nul & exit