Discussion :

[Vba14]

Bonjour à tous,

Dans une feuille Excel j'ai inséré une liste déroulante via "Données - Validation".
Cette liste a pour référence des données d'une autre feuille. Ces données sont une suite de commandes avec un N° de bon de commande. Dans cette suite apparaît plusieurs fois le même N° et ce qui est normal.
Mais dans ma liste déroulante je souhaiterais que n'apparaisse qu'un seule fois les N° présents.
Est-il possible de réaliser cela avec VBA ?
Merci par avance pour vos réponses.

[Thautheme]

Bonjour Vba, bonjour le forum,

Peut-être comme ça (à adapter) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub Macro1()
Dim OL As Worksheet 'déclare la variable OL (Onglet de la Liste)
Dim OV As Worksheet 'déclare la variable OV (Onglet de la Validation)
Dim CV As Range 'déclare la variable CV (Cellule de la Validation)
Dim TL As Variant 'déclare la variable TL (Tableau de la liste)
Dim D As Object 'déclare la variable D (Dictionnaire)
Dim LST As Variant 'déclare la variable LST (LiSTe)
 
Set OL = Worksheets("Feuil2") 'définit l'onglet OL (à adapter)
TL = OL.Range("A1").CurrentRegion 'définit le tableau de la liste TL (à adapter)
Set OV = Worksheets("Feuil1") 'définit l'onglet OV (à adapter)
Set CV = OV.Range("A1") 'définit la cellule de la validation CV (à adapter)
Set D = CreateObject("Scripting.Dictionary") 'définit le dictionnaire D
For I = 1 To UBound(TL, 1) 'boucle sur toutes les lignes I du tableu de la liste TL
    D(TL(I, 1)) = "" 'alimente le dictionnaire D
Next I 'prochaine ligne de la boucle
LST = Join(D.keys, ",") 'définit la liste LST avec les données du dictionnaire D sans doublons
CV.Validation.Delete 'efface une éventuelle ancienne validation de données dans la cellule CV
CV.Validation.Add xlValidateList, Formula1:=LST 'définit la validation de données de la cellule CV avec la liste LST
End Sub

[Vba14]

Bonjour Thautheme,

Merci beaucoup ça marche très bien.
Voici mon code finalisé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Private Sub Worksheet_Activate()
Dim OL As Worksheet 'déclare la variable OL (Onglet de la Liste)
Dim OV As Worksheet 'déclare la variable OV (Onglet de la Validation)
Dim CV As Range 'déclare la variable CV (Cellule de la Validation)
Dim TL As Variant 'déclare la variable TL (Tableau de la liste)
Dim D As Object 'déclare la variable D (Dictionnaire)
Dim LST As Variant 'déclare la variable LST (Liste)
 
Set OL = Worksheets("Commandes") 'définit l'onglet OL (à adapter)
TL = OL.Range("B6").CurrentRegion 'définit le tableau de la liste TL (à adapter)
Set OV = Worksheets("BCommandes") 'définit l'onglet OV (à adapter)
Set CV = OV.Range("C11") 'définit la cellule de la validation CV (à adapter)
Set D = CreateObject("Scripting.Dictionary") 'définit le dictionnaire D
For I = 1 To UBound(TL, 1) 'boucle sur toutes les lignes I du tableau de la liste TL
    D(TL(I, 1)) = "" 'alimente le dictionnaire D
Next I 'prochaine ligne de la boucle
LST = Join(D.keys, ",") 'définit la liste LST avec les données du dictionnaire D sans doublons
CV.Validation.Delete 'efface une éventuelle ancienne validation de données dans la cellule CV
CV.Validation.Add xlValidateList, Formula1:=LST 'définit la validation de données de la cellule CV avec la liste LST
End Sub

Bonjour Ryu,
Merci pour ta réponse, mais je ne souhaite pas supprimer les doublons dans le tableau mais uniquement dans la liste.
Amicalement
Vba14

[RyuAutodidacte]

Re,

Pas de soucis, je pensais que tu transférais ta liste dans une colonne et que tu utilisais une plage nommée dynamique via la petite formule bien connue avec DECALER et NBVAL …
D’ailleurs ta liste pourrait se faire avec un filtre avancé sans doublons si celle-ci est transféré dans une colonne …

[Vba14]

Non les données ne servent qu'à alimenter la Combo.
Merci toutefois pour ta contribution

[RyuAutodidacte]

Re,

Dans une feuille Excel j'ai inséré une liste déroulante via "Données - Validation".
…

Pas évident à 1ère vue qu’on parle de Combobox, bon le principal c’est que le pb soit solutionné

PS: Marcel - j’utilise aussi de temps à autres le site de Jacques si besoin - très bon site

[RyuAutodidacte]

Bonjour,

Je ne sais pas comment sont insérés tes N• mais tu peux faire une chose une fois que tu les as,
un RemoveDullicates : https://docs.microsoft.com/fr-fr/off...moveduplicates
Une seule ligne de code suffit …

Sinon il faut le faire en amont …