Discussion :

[samuelsmn]

Bonjour à tous,

Je suis en train de créer un fichier excel avec des macro pour automatiser ma procédure et je bloque sur un point.

Je souhaite pouvoir filtrer la colonne semaine de manière à obtenir mon besoin de S à S+2 (exemple : On est en semaine 23, je voudrais sélectionner les semaines 23, 24 et 25)

En enregistrant la macro et retravaillant le code voici ce que j'ai obtenu :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Filtre()
 
Dim S As Integer
 
'On demande à l'utilisateur d'indiquer à partir de quelle semaine il veut analyser son besoin
S = Application.InputBox("A partir de quelle semaine voulez vous analyser les besoins ?", "Saisie semaine", Type:=1)
 
'On filtre la colonne semaine de S à S+2
ActiveSheet.Range("A7:I350").AutoFilter Field:=1, Criteria1:=Array(S, S + 1, S + 2)
 
End Sub

Mais quand je lance la macro il ne sélectionne que S+2, alors que cela fonctionne très bien quand je lance la macro que j'ai enregistré :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveSheet.Range("A7:I350").AutoFilter Field:=1, Criteria1:=Array("24", "25", "26")

Est ce que vous auriez des pistes pour pallier à mon problème ?

Merci d'avance !

[joe.levrai]

Bonjour,

il faut :

- utiliser du type String dans ton array
- renseigner le paramètre Operator en xlFilterValues

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Filtre()
Dim S As Integer
    'On demande à l'utilisateur d'indiquer à partir de quelle semaine il veut analyser son besoin
    S = Application.InputBox("A partir de quelle semaine voulez vous analyser les besoins ?", "Saisie semaine", Type:=1)
 
    'On filtre la colonne semaine de S à S+2
    ActiveSheet.Range("A7:I350").AutoFilter Field:=1, Criteria1:=Array(CStr(S), CStr(S + 1), CStr(S + 2)), Operator:=xlFilterValues
End Sub

[samuelsmn]

La solution fonctionne.

Merci beaucoup !